[dragonfly.git] / lib / libm / arch / i386 / e_exp.S

/*	$NetBSD: e_exp.S,v 1.14 2008/06/23 10:24:13 drochner Exp $	*/

/*
 * Copyright (c) 1993,94 Winning Strategies, Inc.
 * All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 * 3. All advertising materials mentioning features or use of this software
 *    must display the following acknowledgement:
 *      This product includes software developed by Winning Strategies, Inc.
 * 4. The name of the author may not be used to endorse or promote products
 *    derived from this software without specific prior written permission.
 *
 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
 * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
 * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
 * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
 * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
 * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
 * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
 * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
 * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
 * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
 */

/*
 * Written by:
 *	J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
 */

#include <machine/asm.h>

#include "abi.h"


/* e^x = 2^(x * log2(e)) */
ENTRY(exp)
	XMM_ONE_ARG_DOUBLE_PROLOGUE
	/*
	 * If x is +-Inf, then the subtraction would give Inf-Inf = NaN.
	 * Avoid this.  Also avoid it if x is NaN for convenience.
	 */
	movl	ARG_DOUBLE_ONE_MSW, %eax
	andl	$0x7fffffff, %eax
	cmpl	$0x7ff00000, %eax
	jae	x_Inf_or_NaN

	fldl	ARG_DOUBLE_ONE

	/*
	 * Ensure that the rounding mode is to nearest (to give the smallest
	 * possible fraction) and that the precision is as high as possible.
	 * We may as well mask interrupts if we switch the mode.
	 */
#define CWSTORE_SAV ARG_DOUBLE_ONE_LSW /* XXX overwrites the argument */
#define CWSTORE_TMP ARG_DOUBLE_ONE_MSW
	fstcw	CWSTORE_SAV
	movl	CWSTORE_SAV, %eax
	andl	$0x0f00, %eax
	cmpl	$0x0300, %eax		/* RC == 0 && PC == 3? */
	je	1f			/* jump if mode is good */
	movl	$0x137f, CWSTORE_TMP
	fldcw	CWSTORE_TMP
1:
	fldl2e
	fmulp				/* x * log2(e) */
	fst	%st(1)
	frndint				/* int(x * log2(e)) */
	fst	%st(2)
	fsubrp				/* fract(x * log2(e)) */
	f2xm1				/* 2^(fract(x * log2(e))) - 1 */ 
	fld1
	faddp				/* 2^(fract(x * log2(e))) */
	fscale				/* e^x */
	fstp	%st(1)
	je	1f
	fldcw	CWSTORE_SAV
1:
	XMM_DOUBLE_EPILOGUE
	ret
x_Inf_or_NaN:
	/*
	 * Return 0 if x is -Inf.  Otherwise just return x, although the
	 * C version would return (x + x) (Real Indefinite) if x is a NaN.
	 */
	cmpl	$0xfff00000, ARG_DOUBLE_ONE_MSW
	jne	x_not_minus_Inf
	cmpl	$0, ARG_DOUBLE_ONE_LSW
	jne	x_not_minus_Inf
	fldz
	XMM_DOUBLE_EPILOGUE
	ret

x_not_minus_Inf:
	fldl	ARG_DOUBLE_ONE
	XMM_DOUBLE_EPILOGUE
	ret
END(exp)

	.section .note.GNU-stack,"",%progbits
Commit	Line	Data
74dfd0cf JM	1	/* $NetBSD: e_exp.S,v 1.14 2008/06/23 10:24:13 drochner Exp $ */
74dfd0cf JM	2
b34b60bc JS	3	/*
	4	* Copyright (c) 1993,94 Winning Strategies, Inc.
	5	* All rights reserved.
	6	*
	7	* Redistribution and use in source and binary forms, with or without
	8	* modification, are permitted provided that the following conditions
	9	* are met:
	10	* 1. Redistributions of source code must retain the above copyright
	11	* notice, this list of conditions and the following disclaimer.
	12	* 2. Redistributions in binary form must reproduce the above copyright
	13	* notice, this list of conditions and the following disclaimer in the
	14	* documentation and/or other materials provided with the distribution.
	15	* 3. All advertising materials mentioning features or use of this software
	16	* must display the following acknowledgement:
	17	* This product includes software developed by Winning Strategies, Inc.
	18	* 4. The name of the author may not be used to endorse or promote products
	19	* derived from this software without specific prior written permission.
	20	*
	21	* THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
	22	* IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
	23	* OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
	24	* IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
	25	* INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
	26	* NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
	27	* DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
	28	* THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
	29	* (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
	30	* THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
b34b60bc JS	31	*/
	32
	33	/*
	34	* Written by:
	35	* J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
	36	*/
	37
	38	#include <machine/asm.h>
	39
	40	#include "abi.h"
	41
	42
	43	/* e^x = 2^(x * log2(e)) */
	44	ENTRY(exp)
74dfd0cf	45	XMM_ONE_ARG_DOUBLE_PROLOGUE
b34b60bc JS	46	/*
	47	* If x is +-Inf, then the subtraction would give Inf-Inf = NaN.
	48	* Avoid this. Also avoid it if x is NaN for convenience.
	49	*/
74dfd0cf JM	50	movl ARG_DOUBLE_ONE_MSW, %eax
	51	andl $0x7fffffff, %eax
	52	cmpl $0x7ff00000, %eax
b34b60bc JS	53	jae x_Inf_or_NaN
b34b60bc JS	54
74dfd0cf	55	fldl ARG_DOUBLE_ONE
b34b60bc JS	56
	57	/*
	58	* Ensure that the rounding mode is to nearest (to give the smallest
	59	* possible fraction) and that the precision is as high as possible.
	60	* We may as well mask interrupts if we switch the mode.
	61	*/
74dfd0cf JM	62	#define CWSTORE_SAV ARG_DOUBLE_ONE_LSW /* XXX overwrites the argument */
	63	#define CWSTORE_TMP ARG_DOUBLE_ONE_MSW
	64	fstcw CWSTORE_SAV
	65	movl CWSTORE_SAV, %eax
	66	andl $0x0f00, %eax
	67	cmpl $0x0300, %eax /* RC == 0 && PC == 3? */
b34b60bc	68	je 1f /* jump if mode is good */
74dfd0cf JM	69	movl $0x137f, CWSTORE_TMP
74dfd0cf JM	70	fldcw CWSTORE_TMP
b34b60bc JS	71	1:
	72	fldl2e
	73	fmulp /* x * log2(e) */
	74	fst %st(1)
	75	frndint /* int(x * log2(e)) */
	76	fst %st(2)
	77	fsubrp /* fract(x * log2(e)) */
	78	f2xm1 /* 2^(fract(x * log2(e))) - 1 */
	79	fld1
	80	faddp /* 2^(fract(x * log2(e))) */
	81	fscale /* e^x */
	82	fstp %st(1)
	83	je 1f
74dfd0cf	84	fldcw CWSTORE_SAV
b34b60bc	85	1:
74dfd0cf	86	XMM_DOUBLE_EPILOGUE
b34b60bc	87	ret
b34b60bc JS	88	x_Inf_or_NaN:
	89	/*
	90	* Return 0 if x is -Inf. Otherwise just return x, although the
	91	* C version would return (x + x) (Real Indefinite) if x is a NaN.
	92	*/
74dfd0cf	93	cmpl $0xfff00000, ARG_DOUBLE_ONE_MSW
b34b60bc	94	jne x_not_minus_Inf
74dfd0cf	95	cmpl $0, ARG_DOUBLE_ONE_LSW
b34b60bc JS	96	jne x_not_minus_Inf
b34b60bc JS	97	fldz
74dfd0cf	98	XMM_DOUBLE_EPILOGUE
b34b60bc JS	99	ret
	100
	101	x_not_minus_Inf:
74dfd0cf JM	102	fldl ARG_DOUBLE_ONE
74dfd0cf JM	103	XMM_DOUBLE_EPILOGUE
b34b60bc	104	ret
d04e8698	105	END(exp)
70e34eb2 JM	106
70e34eb2 JM	107	.section .note.GNU-stack,"",%progbits