[dragonfly.git] / sys / boot / pc32 / libi386 / x86_64_tramp.S

/*-
 * Copyright (c) 2003  Peter Wemm <peter@FreeBSD.org>
 * All rights reserved.
 *
 * Redistribution and use in source and binary forms, with or without
 * modification, are permitted provided that the following conditions
 * are met:
 * 1. Redistributions of source code must retain the above copyright
 *    notice, this list of conditions and the following disclaimer.
 * 2. Redistributions in binary form must reproduce the above copyright
 *    notice, this list of conditions and the following disclaimer in the
 *    documentation and/or other materials provided with the distribution.
 *
 * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
 * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
 * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
 * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
 * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
 * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
 * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
 * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
 * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
 * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
 * SUCH DAMAGE.
 *
 * $FreeBSD: src/sys/boot/i386/libi386/amd64_tramp.S,v 1.2 2003/05/17 00:30:51 peter Exp $
 */

#include "../bootasm.h"

/*
 * Quick and dirty trampoline to get into 64 bit (long) mode and running
 * with paging enabled so that we enter the kernel at its linked address.
 */
#define MSR_EFER	0xc0000080
#define EFER_LME	0x00000100
#define CR4_PAE		0x00000020
#define CR4_PSE		0x00000010
#define CR0_PG		0x80000000

/* GRRR. Deal with BTX that links us for a non-zero location */
#define VTOP(x)	((x) + MEM_BTX_USR)

	.data

	.p2align 12,0x40

	.globl	PT4
PT4:
	.space	0x1000
	.globl	PT3
PT3:
	.space	0x1000
	.globl	PT2
PT2:
	.space	0x1000

gdtdesc:
	.word	gdtend - gdt
	.long	VTOP(gdt)		# low
	.long	0			# high

gdt:
	.long	0			# null descriptor
	.long	0
	.long	0x00000000		# %cs
	.long	0x00209800
	.long	0x00000000		# %ds
	.long	0x00008000
gdtend:
	
	.text
	.code32

	.globl	x86_64_tramp
x86_64_tramp:
	/* Be sure that interrupts are disabled */
	cli

	/* Turn on EFER.LME */
	movl	$MSR_EFER, %ecx
	rdmsr
	orl	$EFER_LME, %eax
	wrmsr

	/* Turn on PAE */
	movl	%cr4, %eax
	orl	$(CR4_PAE | CR4_PSE), %eax
	movl	%eax, %cr4

	/* Set %cr3 for PT4 */
	movl	$VTOP(PT4), %eax
	movl	%eax, %cr3

	/* Turn on paging (implicitly sets EFER.LMA) */
	movl	%cr0, %eax
	orl	$CR0_PG, %eax
	movl	%eax, %cr0
	
	/* Now we're in compatibility mode. set %cs for long mode */
	movl	$VTOP(gdtdesc), %eax
	movl	VTOP(entry_hi), %esi
	movl	VTOP(entry_lo), %edi
	lgdt	(%eax)
	ljmp	$0x8, $VTOP(longmode)

	.code64
longmode:
	/* We're still running V=P, jump to entry point */
	movl	%esi, %eax
	salq	$32, %rax
	orq	%rdi, %rax
	pushq	%rax
	ret
Commit	Line	Data
5ee58eed MD	1	/*-
	2	* Copyright (c) 2003 Peter Wemm <peter@FreeBSD.org>
	3	* All rights reserved.
	4	*
	5	* Redistribution and use in source and binary forms, with or without
	6	* modification, are permitted provided that the following conditions
	7	* are met:
	8	* 1. Redistributions of source code must retain the above copyright
	9	* notice, this list of conditions and the following disclaimer.
	10	* 2. Redistributions in binary form must reproduce the above copyright
	11	* notice, this list of conditions and the following disclaimer in the
	12	* documentation and/or other materials provided with the distribution.
	13	*
	14	* THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
	15	* ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
	16	* IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
	17	* ARE DISCLAIMED. IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
	18	* FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
	19	* DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
	20	* OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
	21	* HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
	22	* LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
	23	* OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
	24	* SUCH DAMAGE.
	25	*
	26	* $FreeBSD: src/sys/boot/i386/libi386/amd64_tramp.S,v 1.2 2003/05/17 00:30:51 peter Exp $
5ee58eed MD	27	*/
5ee58eed MD	28
cacaceec MD	29	#include "../bootasm.h"
cacaceec MD	30
5ee58eed MD	31	/*
	32	* Quick and dirty trampoline to get into 64 bit (long) mode and running
	33	* with paging enabled so that we enter the kernel at its linked address.
	34	*/
	35	#define MSR_EFER 0xc0000080
	36	#define EFER_LME 0x00000100
	37	#define CR4_PAE 0x00000020
	38	#define CR4_PSE 0x00000010
	39	#define CR0_PG 0x80000000
	40
	41	/* GRRR. Deal with BTX that links us for a non-zero location */
cacaceec	42	#define VTOP(x) ((x) + MEM_BTX_USR)
5ee58eed MD	43
	44	.data
	45
	46	.p2align 12,0x40
	47
	48	.globl PT4
	49	PT4:
	50	.space 0x1000
	51	.globl PT3
	52	PT3:
	53	.space 0x1000
	54	.globl PT2
	55	PT2:
	56	.space 0x1000
	57
	58	gdtdesc:
	59	.word gdtend - gdt
	60	.long VTOP(gdt) # low
	61	.long 0 # high
	62
	63	gdt:
	64	.long 0 # null descriptor
	65	.long 0
	66	.long 0x00000000 # %cs
	67	.long 0x00209800
	68	.long 0x00000000 # %ds
	69	.long 0x00008000
	70	gdtend:
	71
	72	.text
	73	.code32
	74
c1543a89 SS	75	.globl x86_64_tramp
c1543a89 SS	76	x86_64_tramp:
5ee58eed MD	77	/* Be sure that interrupts are disabled */
	78	cli
	79
	80	/* Turn on EFER.LME */
	81	movl $MSR_EFER, %ecx
	82	rdmsr
	83	orl $EFER_LME, %eax
	84	wrmsr
	85
	86	/* Turn on PAE */
	87	movl %cr4, %eax
	88	orl $(CR4_PAE \| CR4_PSE), %eax
	89	movl %eax, %cr4
	90
	91	/* Set %cr3 for PT4 */
	92	movl $VTOP(PT4), %eax
	93	movl %eax, %cr3
	94
	95	/* Turn on paging (implicitly sets EFER.LMA) */
	96	movl %cr0, %eax
	97	orl $CR0_PG, %eax
	98	movl %eax, %cr0
	99
9a7c6212	100	/* Now we're in compatibility mode. set %cs for long mode */
5ee58eed MD	101	movl $VTOP(gdtdesc), %eax
	102	movl VTOP(entry_hi), %esi
	103	movl VTOP(entry_lo), %edi
	104	lgdt (%eax)
	105	ljmp $0x8, $VTOP(longmode)
	106
	107	.code64
	108	longmode:
	109	/* We're still running V=P, jump to entry point */
	110	movl %esi, %eax
	111	salq $32, %rax
	112	orq %rdi, %rax
	113	pushq %rax
	114	ret