| | 1 | /* $NetBSD: e_exp.S,v 1.14 2008/06/23 10:24:13 drochner Exp $ */ |
| | 2 | |
| | 3 | /* |
| | 4 | * Copyright (c) 1993,94 Winning Strategies, Inc. |
| | 5 | * All rights reserved. |
| | 6 | * |
| | 7 | * Redistribution and use in source and binary forms, with or without |
| | 8 | * modification, are permitted provided that the following conditions |
| | 9 | * are met: |
| | 10 | * 1. Redistributions of source code must retain the above copyright |
| | 11 | * notice, this list of conditions and the following disclaimer. |
| | 12 | * 2. Redistributions in binary form must reproduce the above copyright |
| | 13 | * notice, this list of conditions and the following disclaimer in the |
| | 14 | * documentation and/or other materials provided with the distribution. |
| | 15 | * 3. All advertising materials mentioning features or use of this software |
| | 16 | * must display the following acknowledgement: |
| | 17 | * This product includes software developed by Winning Strategies, Inc. |
| | 18 | * 4. The name of the author may not be used to endorse or promote products |
| | 19 | * derived from this software without specific prior written permission. |
| | 20 | * |
| | 21 | * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR |
| | 22 | * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES |
| | 23 | * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED. |
| | 24 | * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT, |
| | 25 | * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT |
| | 26 | * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, |
| | 27 | * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY |
| | 28 | * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT |
| | 29 | * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF |
| | 30 | * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE. |
| | 31 | */ |
| | 32 | |
| | 33 | /* |
| | 34 | * Written by: |
| | 35 | * J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc. |
| | 36 | */ |
| | 37 | |
| | 38 | #include <machine/asm.h> |
| | 39 | |
| | 40 | #include "abi.h" |
| | 41 | |
| | 42 | |
| | 43 | /* e^x = 2^(x * log2(e)) */ |
| | 44 | ENTRY(exp) |
| | 45 | XMM_ONE_ARG_DOUBLE_PROLOGUE |
| | 46 | /* |
| | 47 | * If x is +-Inf, then the subtraction would give Inf-Inf = NaN. |
| | 48 | * Avoid this. Also avoid it if x is NaN for convenience. |
| | 49 | */ |
| | 50 | movl ARG_DOUBLE_ONE_MSW, %eax |
| | 51 | andl $0x7fffffff, %eax |
| | 52 | cmpl $0x7ff00000, %eax |
| | 53 | jae x_Inf_or_NaN |
| | 54 | |
| | 55 | fldl ARG_DOUBLE_ONE |
| | 56 | |
| | 57 | /* |
| | 58 | * Ensure that the rounding mode is to nearest (to give the smallest |
| | 59 | * possible fraction) and that the precision is as high as possible. |
| | 60 | * We may as well mask interrupts if we switch the mode. |
| | 61 | */ |
| | 62 | #define CWSTORE_SAV ARG_DOUBLE_ONE_LSW /* XXX overwrites the argument */ |
| | 63 | #define CWSTORE_TMP ARG_DOUBLE_ONE_MSW |
| | 64 | fstcw CWSTORE_SAV |
| | 65 | movl CWSTORE_SAV, %eax |
| | 66 | andl $0x0f00, %eax |
| | 67 | cmpl $0x0300, %eax /* RC == 0 && PC == 3? */ |
| | 68 | je 1f /* jump if mode is good */ |
| | 69 | movl $0x137f, CWSTORE_TMP |
| | 70 | fldcw CWSTORE_TMP |
| | 71 | 1: |
| | 72 | fldl2e |
| | 73 | fmulp /* x * log2(e) */ |
| | 74 | fst %st(1) |
| | 75 | frndint /* int(x * log2(e)) */ |
| | 76 | fst %st(2) |
| | 77 | fsubrp /* fract(x * log2(e)) */ |
| | 78 | f2xm1 /* 2^(fract(x * log2(e))) - 1 */ |
| | 79 | fld1 |
| | 80 | faddp /* 2^(fract(x * log2(e))) */ |
| | 81 | fscale /* e^x */ |
| | 82 | fstp %st(1) |
| | 83 | je 1f |
| | 84 | fldcw CWSTORE_SAV |
| | 85 | 1: |
| | 86 | XMM_DOUBLE_EPILOGUE |
| | 87 | ret |
| | 88 | x_Inf_or_NaN: |
| | 89 | /* |
| | 90 | * Return 0 if x is -Inf. Otherwise just return x, although the |
| | 91 | * C version would return (x + x) (Real Indefinite) if x is a NaN. |
| | 92 | */ |
| | 93 | cmpl $0xfff00000, ARG_DOUBLE_ONE_MSW |
| | 94 | jne x_not_minus_Inf |
| | 95 | cmpl $0, ARG_DOUBLE_ONE_LSW |
| | 96 | jne x_not_minus_Inf |
| | 97 | fldz |
| | 98 | XMM_DOUBLE_EPILOGUE |
| | 99 | ret |
| | 100 | |
| | 101 | x_not_minus_Inf: |
| | 102 | fldl ARG_DOUBLE_ONE |
| | 103 | XMM_DOUBLE_EPILOGUE |
| | 104 | ret |
| | 105 | END(exp) |
| | 106 | |
| | 107 | .section .note.GNU-stack,"",%progbits |
projects / dragonfly.git / blame_incremental