sys/kern/makesyscalls.sh

   1 #! /bin/sh -
   2 #       @(#)makesyscalls.sh     8.1 (Berkeley) 6/10/93
   3 # $FreeBSD: src/sys/kern/makesyscalls.sh,v 1.39.2.4 2001/10/20 09:01:24 marcel Exp $
   4 # $DragonFly: src/sys/kern/makesyscalls.sh,v 1.3 2003/06/17 05:21:46 dillon Exp $
   5
   6 set -e
   7
   8 # name of compat option:
   9 compat=COMPAT_43
  10
  11 # output files:
  12 sysnames="syscalls.c"
  13 sysproto="../sys/sysproto.h"
  14 sysproto_h=_SYS_SYSPROTO_H_
  15 syshdr="../sys/syscall.h"
  16 sysmk="../sys/syscall.mk"
  17 syssw="init_sysent.c"
  18 syshide="../sys/syscall-hide.h"
  19 syscallprefix="SYS_"
  20 switchname="sysent"
  21 namesname="syscallnames"
  22
  23 # tmp files:
  24 sysdcl="sysent.dcl.$$"
  25 syscompat="sysent.compat.$$"
  26 syscompatdcl="sysent.compatdcl.$$"
  27 sysent="sysent.switch.$$"
  28 sysinc="sysinc.switch.$$"
  29 sysarg="sysarg.switch.$$"
  30
  31 trap "rm $sysdcl $syscompat $syscompatdcl $sysent $sysinc $sysarg" 0
  32
  33 touch $sysdcl $syscompat $syscompatdcl $sysent $sysinc $sysarg
  34
  35 case $# in
  36     0)  echo "Usage: $0 input-file <config-file>" 1>&2
  37         exit 1
  38         ;;
  39 esac
  40
  41 if [ -n "$2" -a -f "$2" ]; then
  42         . $2
  43 fi
  44
  45 sed -e '
  46 s/\$//g
  47 :join
  48         /\\$/{a\
  49
  50         N
  51         s/\\\n//
  52         b join
  53         }
  54 2,${
  55         /^#/!s/\([{}()*,]\)/ \1 /g
  56 }
  57 ' < $1 | awk "
  58         BEGIN {
  59                 sysdcl = \"$sysdcl\"
  60                 sysproto = \"$sysproto\"
  61                 sysproto_h = \"$sysproto_h\"
  62                 syscompat = \"$syscompat\"
  63                 syscompatdcl = \"$syscompatdcl\"
  64                 sysent = \"$sysent\"
  65                 syssw = \"$syssw\"
  66                 sysinc = \"$sysinc\"
  67                 sysarg = \"$sysarg\"
  68                 sysnames = \"$sysnames\"
  69                 syshdr = \"$syshdr\"
  70                 sysmk = \"$sysmk\"
  71                 compat = \"$compat\"
  72                 syshide = \"$syshide\"
  73                 syscallprefix = \"$syscallprefix\"
  74                 switchname = \"$switchname\"
  75                 namesname = \"$namesname\"
  76                 infile = \"$1\"
  77                 "'
  78
  79                 printf "/*\n * System call switch table.\n *\n" > syssw
  80                 printf " * DO NOT EDIT-- this file is automatically generated.\n" > syssw
  81                 printf " * \$\TurtleBSD\$\n" > syssw
  82
  83                 printf "/*\n * System call prototypes.\n *\n" > sysarg
  84                 printf " * DO NOT EDIT-- this file is automatically generated.\n" > sysarg
  85                 printf " * \$\TurtleBSD\$\n" > sysarg
  86
  87                 printf "\n#ifdef %s\n\n", compat > syscompat
  88
  89                 printf "/*\n * System call names.\n *\n" > sysnames
  90                 printf " * DO NOT EDIT-- this file is automatically generated.\n" > sysnames
  91                 printf " * \$\TurtleBSD\$\n" > sysnames
  92
  93                 printf "/*\n * System call numbers.\n *\n" > syshdr
  94                 printf " * DO NOT EDIT-- this file is automatically generated.\n" > syshdr
  95                 printf " * \$\TurtleBSD\$\n" > syshdr
  96                 printf "# TurtleBSD system call names.\n" > sysmk
  97                 printf "# DO NOT EDIT-- this file is automatically generated.\n" > sysmk
  98                 printf "# \$\TurtleBSD\$\n" > sysmk
  99                 printf "/*\n * System call hiders.\n *\n" > syshide
 100                 printf " * DO NOT EDIT-- this file is automatically generated.\n" > syshide
 101                 printf " * \$\TurtleBSD\$\n" > syshide
 102         }
 103         NR == 1 {
 104                 gsub("[$]TurtleBSD: ", "", $0)
 105                 gsub(" [$]", "", $0)
 106
 107                 printf " * created from%s\n */\n\n", $0 > syssw
 108
 109                 printf "\n/* The casts are bogus but will do for now. */\n" > sysent
 110                 printf "struct sysent %s[] = {\n",switchname > sysent
 111
 112                 printf " * created from%s\n */\n\n", $0 > sysarg
 113                 printf "#ifndef %s\n", sysproto_h > sysarg
 114                 printf "#define\t%s\n\n", sysproto_h > sysarg
 115                 printf "#include <sys/signal.h>\n\n" > sysarg
 116                 printf "#include <sys/acl.h>\n\n" > sysarg
 117                 printf "struct proc;\n\n" > sysarg
 118                 printf "#define\tPAD_(t)\t(sizeof(register_t) <= sizeof(t) ? \\\n" > sysarg
 119                 printf "\t\t0 : sizeof(register_t) - sizeof(t))\n\n" > sysarg
 120
 121                 printf " * created from%s\n */\n\n", $0 > sysnames
 122                 printf "char *%s[] = {\n", namesname > sysnames
 123
 124                 printf " * created from%s\n */\n\n", $0 > syshdr
 125
 126                 printf "# created from%s\nMIASM = ", $0 > sysmk
 127
 128                 printf " * created from%s\n */\n\n", $0 > syshide
 129                 next
 130         }
 131         NF == 0 || $1 ~ /^;/ {
 132                 next
 133         }
 134         $1 ~ /^#[       ]*include/ {
 135                 print > sysinc
 136                 next
 137         }
 138         $1 ~ /^#[       ]*if/ {
 139                 print > sysent
 140                 print > sysdcl
 141                 print > sysarg
 142                 print > syscompat
 143                 print > sysnames
 144                 print > syshide
 145                 savesyscall = syscall
 146                 next
 147         }
 148         $1 ~ /^#[       ]*else/ {
 149                 print > sysent
 150                 print > sysdcl
 151                 print > sysarg
 152                 print > syscompat
 153                 print > sysnames
 154                 print > syshide
 155                 syscall = savesyscall
 156                 next
 157         }
 158         $1 ~ /^#/ {
 159                 print > sysent
 160                 print > sysdcl
 161                 print > sysarg
 162                 print > syscompat
 163                 print > sysnames
 164                 print > syshide
 165                 next
 166         }
 167         syscall != $1 {
 168                 printf "%s: line %d: syscall number out of sync at %d\n",
 169                     infile, NR, syscall
 170                 printf "line is:\n"
 171                 print
 172                 exit 1
 173         }
 174         function align_sysent_comment(column) {
 175                 printf("\t") > sysent
 176                 column = column + 8 - column % 8
 177                 while (column < 56) {
 178                         printf("\t") > sysent
 179                         column = column + 8
 180                 }
 181         }
 182         function parserr(was, wanted) {
 183                 printf "%s: line %d: unexpected %s (expected %s)\n",
 184                     infile, NR, was, wanted
 185                 exit 1
 186         }
 187         function parseline() {
 188                 f=4                     # toss number and type
 189                 argc= 0;
 190                 argssize = "0"
 191                 if ($NF != "}") {
 192                         funcalias=$(NF-2)
 193                         argalias=$(NF-1)
 194                         rettype=$NF
 195                         end=NF-3
 196                 } else {
 197                         funcalias=""
 198                         argalias=""
 199                         rettype="int"
 200                         end=NF
 201                 }
 202                 if ($2 == "NODEF") {
 203                         funcname=$4
 204                         argssize = "AS(" $6 ")"
 205                         return
 206                 }
 207                 if ($f != "{")
 208                         parserr($f, "{")
 209                 f++
 210                 if ($end != "}")
 211                         parserr($end, "}")
 212                 end--
 213                 if ($end != ";")
 214                         parserr($end, ";")
 215                 end--
 216                 if ($end != ")")
 217                         parserr($end, ")")
 218                 end--
 219
 220                 f++     #function return type
 221
 222                 funcname=$f
 223                 if (funcalias == "")
 224                         funcalias = funcname
 225                 if (argalias == "") {
 226                         argalias = funcname "_args"
 227                         if ($2 == "COMPAT")
 228                                 argalias = "o" argalias
 229                 }
 230                 f++
 231
 232                 if ($f != "(")
 233                         parserr($f, ")")
 234                 f++
 235
 236                 if (f == end) {
 237                         if ($f != "void")
 238                                 parserr($f, "argument definition")
 239                         return
 240                 }
 241
 242                 while (f <= end) {
 243                         argc++
 244                         argtype[argc]=""
 245                         oldf=""
 246                         while (f < end && $(f+1) != ",") {
 247                                 if (argtype[argc] != "" && oldf != "*")
 248                                         argtype[argc] = argtype[argc]" ";
 249                                 argtype[argc] = argtype[argc]$f;
 250                                 oldf = $f;
 251                                 f++
 252                         }
 253                         if (argtype[argc] == "")
 254                                 parserr($f, "argument definition")
 255                         argname[argc]=$f;
 256                         f += 2;                 # skip name, and any comma
 257                 }
 258                 if (argc != 0)
 259                         argssize = "AS(" argalias ")"
 260         }
 261         {       comment = $4
 262                 if (NF < 7)
 263                         for (i = 5; i <= NF; i++)
 264                                 comment = comment " " $i
 265         }
 266         # if the "MPSAFE" keyword is found, note it and shift the line
 267         mpsafe = ""
 268         $2 == "MPSAFE" {
 269                 for (i = 2; i <= NF; i++)
 270                         $i = $(i + 1);
 271                 NF -= 1;
 272                 mpsafe = "SYF_MPSAFE | "
 273         }
 274         $2 == "STD" || $2 == "NODEF" || $2 == "NOARGS"  || $2 == "NOPROTO" \
 275             || $2 == "NOIMPL" {
 276                 parseline()
 277                 if ((!nosys || funcname != "nosys") && \
 278                     (funcname != "lkmnosys")) {
 279                         if (argc != 0 && $2 != "NOARGS" && $2 != "NOPROTO") {
 280                                 printf("struct\t%s {\n", argalias) > sysarg
 281                                 for (i = 1; i <= argc; i++)
 282                                         printf("\t%s\t%s;\tchar %s_[PAD_(%s)];\n",
 283                                             argtype[i], argname[i],
 284                                             argname[i], argtype[i]) > sysarg
 285                                 printf("};\n") > sysarg
 286                         }
 287                         else if ($2 != "NOARGS" && $2 != "NOPROTO" && \
 288                             $2 != "NODEF")
 289                                 printf("struct\t%s {\n\tregister_t dummy;\n};\n",
 290                                     argalias) > sysarg
 291                 }
 292                 if (($2 != "NOPROTO" && $2 != "NODEF" && \
 293                     (funcname != "nosys" || !nosys)) || \
 294                     (funcname == "lkmnosys" && !lkmnosys) || \
 295                     funcname == "lkmressys") {
 296                         printf("%s\t%s __P((struct proc *, struct %s *))",
 297                             rettype, funcname, argalias) > sysdcl
 298                         printf(";\n") > sysdcl
 299                 }
 300                 if (funcname == "nosys")
 301                         nosys = 1
 302                 if (funcname == "lkmnosys")
 303                         lkmnosys = 1
 304                 printf("\t{ %s%s, (sy_call_t *)", mpsafe, argssize) > sysent
 305                 column = 8 + 2 + length(mpsafe) + length(argssize) + 15
 306                 if ($2 != "NOIMPL") {
 307                         printf("%s },", funcname) > sysent
 308                         column = column + length(funcname) + 3
 309                 } else {
 310                         printf("%s },", "nosys") > sysent
 311                         column = column + length("nosys") + 3
 312                 }
 313                 align_sysent_comment(column)
 314                 printf("/* %d = %s */\n", syscall, funcalias) > sysent
 315                 printf("\t\"%s\",\t\t\t/* %d = %s */\n",
 316                     funcalias, syscall, funcalias) > sysnames
 317                 if ($2 != "NODEF") {
 318                         printf("#define\t%s%s\t%d\n", syscallprefix,
 319                             funcalias, syscall) > syshdr
 320                         printf(" \\\n\t%s.o", funcalias) > sysmk
 321                 }
 322                 if ($3 != "NOHIDE")
 323                         printf("HIDE_%s(%s)\n", $3, funcname) > syshide
 324                 syscall++
 325                 next
 326         }
 327         $2 == "COMPAT" || $2 == "CPT_NOA" {
 328                 ncompat++
 329                 parseline()
 330                 if (argc != 0 && $2 != "CPT_NOA") {
 331                         printf("struct\t%s {\n", argalias) > syscompat
 332                         for (i = 1; i <= argc; i++)
 333                                 printf("\t%s\t%s;\tchar %s_[PAD_(%s)];\n",
 334                                     argtype[i], argname[i],
 335                                     argname[i], argtype[i]) > syscompat
 336                         printf("};\n") > syscompat
 337                 }
 338                 else if($2 != "CPT_NOA")
 339                         printf("struct\t%s {\n\tregister_t dummy;\n};\n",
 340                             argalias) > sysarg
 341                 printf("%s\to%s __P((struct proc *, struct %s *));\n",
 342                     rettype, funcname, argalias) > syscompatdcl
 343                 printf("\t{ compat(%s%s,%s) },",
 344                     mpsafe, argssize, funcname) > sysent
 345                 align_sysent_comment(8 + 9 + length(mpsafe) + \
 346                     length(argssize) + 1 + length(funcname) + 4)
 347                 printf("/* %d = old %s */\n", syscall, funcalias) > sysent
 348                 printf("\t\"old.%s\",\t\t/* %d = old %s */\n",
 349                     funcalias, syscall, funcalias) > sysnames
 350                 printf("\t\t\t\t/* %d is old %s */\n",
 351                     syscall, funcalias) > syshdr
 352                 if ($3 != "NOHIDE")
 353                         printf("HIDE_%s(%s)\n", $3, funcname) > syshide
 354                 syscall++
 355                 next
 356         }
 357         $2 == "LIBCOMPAT" {
 358                 ncompat++
 359                 parseline()
 360                 printf("%s\to%s();\n", rettype, funcname) > syscompatdcl
 361                 printf("\t{ compat(%s%s,%s) },",
 362                     mpsafe, argssize, funcname) > sysent
 363                 align_sysent_comment(8 + 9 + length(mpsafe) + \
 364                     length(argssize) + 1 + length(funcname) + 4)
 365                 printf("/* %d = old %s */\n", syscall, funcalias) > sysent
 366                 printf("\t\"old.%s\",\t\t/* %d = old %s */\n",
 367                     funcalias, syscall, funcalias) > sysnames
 368                 printf("#define\t%s%s\t%d\t/* compatibility; still used by libc */\n",
 369                     syscallprefix, funcalias, syscall) > syshdr
 370                 printf(" \\\n\t%s.o", funcalias) > sysmk
 371                 if ($3 != "NOHIDE")
 372                         printf("HIDE_%s(%s)\n", $3, funcname) > syshide
 373                 syscall++
 374                 next
 375         }
 376         $2 == "OBSOL" {
 377                 printf("\t{ 0, (sy_call_t *)nosys },") > sysent
 378                 align_sysent_comment(34)
 379                 printf("/* %d = obsolete %s */\n", syscall, comment) > sysent
 380                 printf("\t\"obs_%s\",\t\t\t/* %d = obsolete %s */\n",
 381                     $4, syscall, comment) > sysnames
 382                 printf("\t\t\t\t/* %d is obsolete %s */\n",
 383                     syscall, comment) > syshdr
 384                 if ($3 != "NOHIDE")
 385                         printf("HIDE_%s(%s)\n", $3, $4) > syshide
 386                 syscall++
 387                 next
 388         }
 389         $2 == "UNIMPL" {
 390                 printf("\t{ 0, (sy_call_t *)nosys },\t\t\t/* %d = %s */\n",
 391                     syscall, comment) > sysent
 392                 printf("\t\"#%d\",\t\t\t/* %d = %s */\n",
 393                     syscall, syscall, comment) > sysnames
 394                 if ($3 != "NOHIDE")
 395                         printf("HIDE_%s(%s)\n", $3, $4) > syshide
 396                 syscall++
 397                 next
 398         }
 399         {
 400                 printf "%s: line %d: unrecognized keyword %s\n", infile, NR, $2
 401                 exit 1
 402         }
 403         END {
 404                 printf "\n#define AS(name) (sizeof(struct name) / sizeof(register_t))\n" > sysinc
 405                 if (ncompat != 0) {
 406                         printf "#include \"opt_compat.h\"\n\n" > syssw
 407                         printf "\n#ifdef %s\n", compat > sysinc
 408                         printf "#define compat(n, name) n, (sy_call_t *)__CONCAT(o,name)\n" > sysinc
 409                         printf "#else\n" > sysinc
 410                         printf "#define compat(n, name) 0, (sy_call_t *)nosys\n" > sysinc
 411                         printf "#endif\n" > sysinc
 412                 }
 413
 414                 printf("\n#endif /* %s */\n\n", compat) > syscompatdcl
 415                 printf("#undef PAD_\n") > syscompatdcl
 416                 printf("\n#endif /* !%s */\n", sysproto_h) > syscompatdcl
 417
 418                 printf("\n") > sysmk
 419                 printf("};\n") > sysent
 420                 printf("};\n") > sysnames
 421                 printf("#define\t%sMAXSYSCALL\t%d\n", syscallprefix, syscall) \
 422                     > syshdr
 423         } '
 424
 425 cat $sysinc $sysent >> $syssw
 426 cat $sysarg $sysdcl $syscompat $syscompatdcl > $sysproto