sys/platform/pc64/amd64/swtch.s

   1 /*
   2  * Copyright (c) 2003,2004,2008 The DragonFly Project.  All rights reserved.
   3  * Copyright (c) 2008 Jordan Gordeev.
   4  *
   5  * This code is derived from software contributed to The DragonFly Project
   6  * by Matthew Dillon <dillon@backplane.com>
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  *
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in
  16  *    the documentation and/or other materials provided with the
  17  *    distribution.
  18  * 3. Neither the name of The DragonFly Project nor the names of its
  19  *    contributors may be used to endorse or promote products derived
  20  *    from this software without specific, prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  23  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  24  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  25  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  26  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  27  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  28  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  29  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  30  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  31  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  32  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  *
  35  * Copyright (c) 1990 The Regents of the University of California.
  36  * All rights reserved.
  37  *
  38  * This code is derived from software contributed to Berkeley by
  39  * William Jolitz.
  40  *
  41  * Redistribution and use in source and binary forms, with or without
  42  * modification, are permitted provided that the following conditions
  43  * are met:
  44  * 1. Redistributions of source code must retain the above copyright
  45  *    notice, this list of conditions and the following disclaimer.
  46  * 2. Redistributions in binary form must reproduce the above copyright
  47  *    notice, this list of conditions and the following disclaimer in the
  48  *    documentation and/or other materials provided with the distribution.
  49  * 3. All advertising materials mentioning features or use of this software
  50  *    must display the following acknowledgement:
  51  *      This product includes software developed by the University of
  52  *      California, Berkeley and its contributors.
  53  * 4. Neither the name of the University nor the names of its contributors
  54  *    may be used to endorse or promote products derived from this software
  55  *    without specific prior written permission.
  56  *
  57  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  58  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  59  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  60  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  61  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  62  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  63  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  64  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  65  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  66  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  67  * SUCH DAMAGE.
  68  *
  69  * $FreeBSD: src/sys/i386/i386/swtch.s,v 1.89.2.10 2003/01/23 03:36:24 ps Exp $
  70  * $DragonFly: src/sys/platform/pc64/amd64/swtch.s,v 1.3 2008/08/29 17:07:10 dillon Exp $
  71  */
  72
  73 //#include "use_npx.h"
  74
  75 #include <sys/rtprio.h>
  76
  77 #include <machine/asmacros.h>
  78 #include <machine/segments.h>
  79
  80 #include <machine/pmap.h>
  81 #if JG
  82 #include <machine_base/apic/apicreg.h>
  83 #endif
  84 #include <machine/lock.h>
  85
  86 #define CHECKNZ(expr, scratch_reg) \
  87         movq expr, scratch_reg; testq scratch_reg, scratch_reg; jnz 7f; int $3; 7:
  88
  89 #include "assym.s"
  90
  91 #if defined(SMP)
  92 #define MPLOCKED        lock ;
  93 #else
  94 #define MPLOCKED
  95 #endif
  96
  97         .data
  98
  99         .globl  panic
 100
 101 #if defined(SWTCH_OPTIM_STATS)
 102         .globl  swtch_optim_stats, tlb_flush_count
 103 swtch_optim_stats:      .long   0               /* number of _swtch_optims */
 104 tlb_flush_count:        .long   0
 105 #endif
 106
 107         .text
 108
 109
 110 /*
 111  * cpu_heavy_switch(struct thread *next_thread)
 112  *
 113  *      Switch from the current thread to a new thread.  This entry
 114  *      is normally called via the thread->td_switch function, and will
 115  *      only be called when the current thread is a heavy weight process.
 116  *
 117  *      Some instructions have been reordered to reduce pipeline stalls.
 118  *
 119  *      YYY disable interrupts once giant is removed.
 120  */
 121 ENTRY(cpu_heavy_switch)
 122         /*
 123          * Save RIP, RSP and callee-saved registers (RBX, RBP, R12-R15).
 124          */
 125         movq    PCPU(curthread),%rcx
 126         /* On top of the stack is the return adress. */
 127         movq    (%rsp),%rax                     /* (reorder optimization) */
 128         movq    TD_PCB(%rcx),%rdx               /* RDX = PCB */
 129         movq    %rax,PCB_RIP(%rdx)              /* return PC may be modified */
 130         movq    %rbx,PCB_RBX(%rdx)
 131         movq    %rsp,PCB_RSP(%rdx)
 132         movq    %rbp,PCB_RBP(%rdx)
 133         movq    %r12,PCB_R12(%rdx)
 134         movq    %r13,PCB_R13(%rdx)
 135         movq    %r14,PCB_R14(%rdx)
 136         movq    %r15,PCB_R15(%rdx)
 137
 138         movq    %rcx,%rbx                       /* RBX = curthread */
 139         movq    TD_LWP(%rcx),%rcx
 140         movl    PCPU(cpuid), %eax
 141         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 142         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%rcx)
 143
 144         /*
 145          * Push the LWKT switch restore function, which resumes a heavy
 146          * weight process.  Note that the LWKT switcher is based on
 147          * TD_SP, while the heavy weight process switcher is based on
 148          * PCB_RSP.  TD_SP is usually two ints pushed relative to
 149          * PCB_RSP.  We push the flags for later restore by cpu_heavy_restore.
 150          */
 151         pushfq
 152         movq    $cpu_heavy_restore, %rax
 153         pushq   %rax
 154         movq    %rsp,TD_SP(%rbx)
 155
 156         /*
 157          * Save debug regs if necessary
 158          */
 159         movq    PCB_FLAGS(%rdx),%rax
 160         andq    $PCB_DBREGS,%rax
 161         jz      1f                              /* no, skip over */
 162         movq    %dr7,%rax                       /* yes, do the save */
 163         movq    %rax,PCB_DR7(%rdx)
 164         /* JG correct value? */
 165         andq    $0x0000fc00, %rax               /* disable all watchpoints */
 166         movq    %rax,%dr7
 167         movq    %dr6,%rax
 168         movq    %rax,PCB_DR6(%rdx)
 169         movq    %dr3,%rax
 170         movq    %rax,PCB_DR3(%rdx)
 171         movq    %dr2,%rax
 172         movq    %rax,PCB_DR2(%rdx)
 173         movq    %dr1,%rax
 174         movq    %rax,PCB_DR1(%rdx)
 175         movq    %dr0,%rax
 176         movq    %rax,PCB_DR0(%rdx)
 177 1:
 178
 179 #if 1
 180         /*
 181          * Save the FP state if we have used the FP.  Note that calling
 182          * npxsave will NULL out PCPU(npxthread).
 183          */
 184         cmpq    %rbx,PCPU(npxthread)
 185         jne     1f
 186         movq    %rdi,%r12               /* save %rdi. %r12 is callee-saved */
 187         movq    TD_SAVEFPU(%rbx),%rdi
 188         call    npxsave                 /* do it in a big C function */
 189         movq    %r12,%rdi               /* restore %rdi */
 190 1:
 191 #endif
 192
 193         /*
 194          * Switch to the next thread, which was passed as an argument
 195          * to cpu_heavy_switch().  The argument is in %rdi.
 196          * Set the current thread, load the stack pointer,
 197          * and 'ret' into the switch-restore function.
 198          *
 199          * The switch restore function expects the new thread to be in %rax
 200          * and the old one to be in %rbx.
 201          *
 202          * There is a one-instruction window where curthread is the new
 203          * thread but %rsp still points to the old thread's stack, but
 204          * we are protected by a critical section so it is ok.
 205          */
 206         movq    %rdi,%rax               /* RAX = newtd, RBX = oldtd */
 207         movq    %rax,PCPU(curthread)
 208         movq    TD_SP(%rax),%rsp
 209         CHECKNZ((%rsp), %r9)
 210         ret
 211
 212 /*
 213  *  cpu_exit_switch(struct thread *next)
 214  *
 215  *      The switch function is changed to this when a thread is going away
 216  *      for good.  We have to ensure that the MMU state is not cached, and
 217  *      we don't bother saving the existing thread state before switching.
 218  *
 219  *      At this point we are in a critical section and this cpu owns the
 220  *      thread's token, which serves as an interlock until the switchout is
 221  *      complete.
 222  */
 223 ENTRY(cpu_exit_switch)
 224         /*
 225          * Get us out of the vmspace
 226          */
 227         movq    KPML4phys,%rcx
 228         movq    %cr3,%rax
 229         cmpq    %rcx,%rax
 230         je      1f
 231         /* JG no increment of statistics counters? see cpu_heavy_restore */
 232         movq    %rcx,%cr3
 233 1:
 234         movq    PCPU(curthread),%rbx
 235
 236         /*
 237          * If this is a process/lwp, deactivate the pmap after we've
 238          * switched it out.
 239          */
 240         movq    TD_LWP(%rbx),%rcx
 241         testq   %rcx,%rcx
 242         jz      2f
 243         movl    PCPU(cpuid), %eax
 244         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 245         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%rcx)
 246 2:
 247         /*
 248          * Switch to the next thread.  RET into the restore function, which
 249          * expects the new thread in RAX and the old in RBX.
 250          *
 251          * There is a one-instruction window where curthread is the new
 252          * thread but %rsp still points to the old thread's stack, but
 253          * we are protected by a critical section so it is ok.
 254          */
 255         movq    %rdi,%rax
 256         movq    %rax,PCPU(curthread)
 257         movq    TD_SP(%rax),%rsp
 258         CHECKNZ((%rsp), %r9)
 259         ret
 260
 261 /*
 262  * cpu_heavy_restore()  (current thread in %rax on entry)
 263  *
 264  *      Restore the thread after an LWKT switch.  This entry is normally
 265  *      called via the LWKT switch restore function, which was pulled
 266  *      off the thread stack and jumped to.
 267  *
 268  *      This entry is only called if the thread was previously saved
 269  *      using cpu_heavy_switch() (the heavy weight process thread switcher),
 270  *      or when a new process is initially scheduled.  The first thing we
 271  *      do is clear the TDF_RUNNING bit in the old thread and set it in the
 272  *      new thread.
 273  *
 274  *      NOTE: The lwp may be in any state, not necessarily LSRUN, because
 275  *      a preemption switch may interrupt the process and then return via
 276  *      cpu_heavy_restore.
 277  *
 278  *      YYY theoretically we do not have to restore everything here, a lot
 279  *      of this junk can wait until we return to usermode.  But for now
 280  *      we restore everything.
 281  *
 282  *      YYY the PCB crap is really crap, it makes startup a bitch because
 283  *      we can't switch away.
 284  *
 285  *      YYY note: spl check is done in mi_switch when it splx()'s.
 286  */
 287
 288 ENTRY(cpu_heavy_restore)
 289         popfq
 290         movq    TD_PCB(%rax),%rdx               /* RDX = PCB */
 291         movq    TD_LWP(%rax),%rcx
 292
 293 #if defined(SWTCH_OPTIM_STATS)
 294         incl    _swtch_optim_stats
 295 #endif
 296         /*
 297          * Tell the pmap that our cpu is using the VMSPACE now.  We cannot
 298          * safely test/reload %cr3 until after we have set the bit in the
 299          * pmap (remember, we do not hold the MP lock in the switch code).
 300          */
 301         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 302         movl    PCPU(cpuid), %esi
 303         MPLOCKED btsl   %esi, VM_PMAP+PM_ACTIVE(%rcx)
 304
 305         /*
 306          * Restore the MMU address space.  If it is the same as the last
 307          * thread we don't have to invalidate the tlb (i.e. reload cr3).
 308          * YYY which naturally also means that the PM_ACTIVE bit had better
 309          * already have been set before we set it above, check? YYY
 310          */
 311         movq    %cr3,%rsi
 312         movq    PCB_CR3(%rdx),%rcx
 313         cmpq    %rsi,%rcx
 314         je      4f
 315 #if defined(SWTCH_OPTIM_STATS)
 316         decl    _swtch_optim_stats
 317         incl    _tlb_flush_count
 318 #endif
 319         movq    %rcx,%cr3
 320 4:
 321         /*
 322          * Clear TDF_RUNNING flag in old thread only after cleaning up
 323          * %cr3.  The target thread is already protected by being TDF_RUNQ
 324          * so setting TDF_RUNNING isn't as big a deal.
 325          */
 326         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 327         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 328
 329         /*
 330          * Deal with the PCB extension, restore the private tss
 331          */
 332         movq    PCB_EXT(%rdx),%rdi      /* check for a PCB extension */
 333         /* JG cheaper than "movq $1,%rbx", right? */
 334         /* JG what's that magic value $1? */
 335         movl    $1,%ebx                 /* maybe mark use of a private tss */
 336         testq   %rdi,%rdi
 337 #if JG
 338         jnz     2f
 339 #endif
 340
 341         /* JG
 342          * Going back to the common_tss.  We may need to update TSS_ESP0
 343          * which sets the top of the supervisor stack when entering from
 344          * usermode.  The PCB is at the top of the stack but we need another
 345          * 16 bytes to take vm86 into account.
 346          */
 347         leaq    -16(%rdx),%rbx
 348         movq    %rbx, PCPU(common_tss) + TSS_RSP0
 349         movq    %rbx, PCPU(rsp0)
 350
 351 #if JG
 352         cmpl    $0,PCPU(private_tss)    /* don't have to reload if      */
 353         je      3f                      /* already using the common TSS */
 354
 355         /* JG? */
 356         subl    %ebx,%ebx               /* unmark use of private tss */
 357
 358         /*
 359          * Get the address of the common TSS descriptor for the ltr.
 360          * There is no way to get the address of a segment-accessed variable
 361          * so we store a self-referential pointer at the base of the per-cpu
 362          * data area and add the appropriate offset.
 363          */
 364         /* JG movl? */
 365         movq    $gd_common_tssd, %rdi
 366         /* JG name for "%gs:0"? */
 367         addq    %gs:0, %rdi
 368
 369         /*
 370          * Move the correct TSS descriptor into the GDT slot, then reload
 371          * ltr.
 372          */
 373 2:
 374         /* JG */
 375         movl    %ebx,PCPU(private_tss)          /* mark/unmark private tss */
 376         movq    PCPU(tss_gdt), %rbx             /* entry in GDT */
 377         movq    0(%rdi), %rax
 378         movq    %rax, 0(%rbx)
 379         movl    $GPROC0_SEL*8, %esi             /* GSEL(entry, SEL_KPL) */
 380         ltr     %si
 381 #endif
 382
 383 3:
 384         /*
 385          * Restore the user %gs and %fs
 386          */
 387         movq    PCB_FSBASE(%rdx),%r9
 388         cmpq    PCPU(user_fs),%r9
 389         je      4f
 390         movq    %rdx,%r10
 391         movq    %r9,PCPU(user_fs)
 392         movl    $MSR_FSBASE,%ecx
 393         movl    PCB_FSBASE(%r10),%eax
 394         movl    PCB_FSBASE+4(%r10),%edx
 395         wrmsr
 396         movq    %r10,%rdx
 397 4:
 398         movq    PCB_GSBASE(%rdx),%r9
 399         cmpq    PCPU(user_gs),%r9
 400         je      5f
 401         movq    %rdx,%r10
 402         movq    %r9,PCPU(user_gs)
 403         movl    $MSR_KGSBASE,%ecx       /* later swapgs moves it to GSBASE */
 404         movl    PCB_GSBASE(%r10),%eax
 405         movl    PCB_GSBASE+4(%r10),%edx
 406         wrmsr
 407         movq    %r10,%rdx
 408 5:
 409
 410         /*
 411          * Restore general registers.
 412          */
 413         movq    PCB_RBX(%rdx), %rbx
 414         movq    PCB_RSP(%rdx), %rsp
 415         movq    PCB_RBP(%rdx), %rbp
 416         movq    PCB_R12(%rdx), %r12
 417         movq    PCB_R13(%rdx), %r13
 418         movq    PCB_R14(%rdx), %r14
 419         movq    PCB_R15(%rdx), %r15
 420         movq    PCB_RIP(%rdx), %rax
 421         movq    %rax, (%rsp)
 422
 423 #if JG
 424         /*
 425          * Restore the user LDT if we have one
 426          */
 427         cmpl    $0, PCB_USERLDT(%edx)
 428         jnz     1f
 429         movl    _default_ldt,%eax
 430         cmpl    PCPU(currentldt),%eax
 431         je      2f
 432         lldt    _default_ldt
 433         movl    %eax,PCPU(currentldt)
 434         jmp     2f
 435 1:      pushl   %edx
 436         call    set_user_ldt
 437         popl    %edx
 438 2:
 439 #endif
 440 #if JG
 441         /*
 442          * Restore the user TLS if we have one
 443          */
 444         pushl   %edx
 445         call    set_user_TLS
 446         popl    %edx
 447 #endif
 448
 449         /*
 450          * Restore the DEBUG register state if necessary.
 451          */
 452         movq    PCB_FLAGS(%rdx),%rax
 453         andq    $PCB_DBREGS,%rax
 454         jz      1f                              /* no, skip over */
 455         movq    PCB_DR6(%rdx),%rax              /* yes, do the restore */
 456         movq    %rax,%dr6
 457         movq    PCB_DR3(%rdx),%rax
 458         movq    %rax,%dr3
 459         movq    PCB_DR2(%rdx),%rax
 460         movq    %rax,%dr2
 461         movq    PCB_DR1(%rdx),%rax
 462         movq    %rax,%dr1
 463         movq    PCB_DR0(%rdx),%rax
 464         movq    %rax,%dr0
 465         movq    %dr7,%rax                /* load dr7 so as not to disturb */
 466         /* JG correct value? */
 467         andq    $0x0000fc00,%rax         /*   reserved bits               */
 468         /* JG we've got more registers on amd64 */
 469         pushq   %rbx
 470         movq    PCB_DR7(%rdx),%rbx
 471         /* JG correct value? */
 472         andq    $~0x0000fc00,%rbx
 473         orq     %rbx,%rax
 474         popq    %rbx
 475         movq    %rax,%dr7
 476 1:
 477
 478         CHECKNZ((%rsp), %r9)
 479         ret
 480
 481 /*
 482  * savectx(struct pcb *pcb)
 483  *
 484  * Update pcb, saving current processor state.
 485  */
 486 ENTRY(savectx)
 487         /* fetch PCB */
 488         /* JG use %rdi instead of %rcx everywhere? */
 489         movq    %rdi,%rcx
 490
 491         /* caller's return address - child won't execute this routine */
 492         movq    (%rsp),%rax
 493         movq    %rax,PCB_RIP(%rcx)
 494
 495         movq    %cr3,%rax
 496         movq    %rax,PCB_CR3(%rcx)
 497
 498         movq    %rbx,PCB_RBX(%rcx)
 499         movq    %rsp,PCB_RSP(%rcx)
 500         movq    %rbp,PCB_RBP(%rcx)
 501         movq    %r12,PCB_R12(%rcx)
 502         movq    %r13,PCB_R13(%rcx)
 503         movq    %r14,PCB_R14(%rcx)
 504         movq    %r15,PCB_R15(%rcx)
 505
 506 #if 1
 507         /*
 508          * If npxthread == NULL, then the npx h/w state is irrelevant and the
 509          * state had better already be in the pcb.  This is true for forks
 510          * but not for dumps (the old book-keeping with FP flags in the pcb
 511          * always lost for dumps because the dump pcb has 0 flags).
 512          *
 513          * If npxthread != NULL, then we have to save the npx h/w state to
 514          * npxthread's pcb and copy it to the requested pcb, or save to the
 515          * requested pcb and reload.  Copying is easier because we would
 516          * have to handle h/w bugs for reloading.  We used to lose the
 517          * parent's npx state for forks by forgetting to reload.
 518          */
 519         movq    PCPU(npxthread),%rax
 520         testq   %rax,%rax
 521         jz      1f
 522
 523         pushq   %rcx                    /* target pcb */
 524         movq    TD_SAVEFPU(%rax),%rax   /* originating savefpu area */
 525         pushq   %rax
 526
 527         movq    %rax,%rdi
 528         call    npxsave
 529
 530         popq    %rax
 531         popq    %rcx
 532
 533         movq    $PCB_SAVEFPU_SIZE,%rdx
 534         leaq    PCB_SAVEFPU(%rcx),%rcx
 535         movq    %rcx,%rsi
 536         movq    %rax,%rdi
 537         call    bcopy
 538 #endif
 539
 540 1:
 541         CHECKNZ((%rsp), %r9)
 542         ret
 543
 544 /*
 545  * cpu_idle_restore()   (current thread in %rax on entry) (one-time execution)
 546  *
 547  *      Don't bother setting up any regs other than %rbp so backtraces
 548  *      don't die.  This restore function is used to bootstrap into the
 549  *      cpu_idle() LWKT only, after that cpu_lwkt_*() will be used for
 550  *      switching.
 551  *
 552  *      Clear TDF_RUNNING in old thread only after we've cleaned up %cr3.
 553  *
 554  *      If we are an AP we have to call ap_init() before jumping to
 555  *      cpu_idle().  ap_init() will synchronize with the BP and finish
 556  *      setting up various ncpu-dependant globaldata fields.  This may
 557  *      happen on UP as well as SMP if we happen to be simulating multiple
 558  *      cpus.
 559  */
 560 ENTRY(cpu_idle_restore)
 561         /* cli */
 562         movq    KPML4phys,%rcx
 563         /* JG xor? */
 564         movl    $0,%ebp
 565         /* JG push RBP? */
 566         pushq   $0
 567         movq    %rcx,%cr3
 568         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 569         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 570 #ifdef SMP
 571         cmpl    $0,PCPU(cpuid)
 572         je      1f
 573         call    ap_init
 574 1:
 575 #endif
 576         /*
 577          * ap_init can decide to enable interrupts early, but otherwise, or if
 578          * we are UP, do it here.
 579          */
 580         sti
 581         jmp     cpu_idle
 582
 583 /*
 584  * cpu_kthread_restore() (current thread is %rax on entry) (one-time execution)
 585  *
 586  *      Don't bother setting up any regs other then %rbp so backtraces
 587  *      don't die.  This restore function is used to bootstrap into an
 588  *      LWKT based kernel thread only.  cpu_lwkt_switch() will be used
 589  *      after this.
 590  *
 591  *      Since all of our context is on the stack we are reentrant and
 592  *      we can release our critical section and enable interrupts early.
 593  */
 594 ENTRY(cpu_kthread_restore)
 595         sti
 596         movq    KPML4phys,%rcx
 597         movq    TD_PCB(%rax),%rdx
 598         /* JG "movq $0, %rbp"? "xorq %rbp, %rbp"? */
 599         movl    $0,%ebp
 600         movq    %rcx,%cr3
 601         /* rax and rbx come from the switchout code */
 602         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 603         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 604         subl    $TDPRI_CRIT,TD_PRI(%rax)
 605         movq    PCB_R12(%rdx),%rdi      /* argument to RBX function */
 606         movq    PCB_RBX(%rdx),%rax      /* thread function */
 607         /* note: top of stack return address inherited by function */
 608         CHECKNZ(%rax, %r9)
 609         jmp     *%rax
 610
 611 /*
 612  * cpu_lwkt_switch(struct thread *)
 613  *
 614  *      Standard LWKT switching function.  Only non-scratch registers are
 615  *      saved and we don't bother with the MMU state or anything else.
 616  *
 617  *      This function is always called while in a critical section.
 618  *
 619  *      There is a one-instruction window where curthread is the new
 620  *      thread but %rsp still points to the old thread's stack, but
 621  *      we are protected by a critical section so it is ok.
 622  *
 623  *      YYY BGL, SPL
 624  */
 625 ENTRY(cpu_lwkt_switch)
 626         pushq   %rbp    /* JG note: GDB hacked to locate ebp relative to td_sp */
 627         /* JG we've got more registers on AMD64 */
 628         pushq   %rbx
 629         movq    PCPU(curthread),%rbx
 630         pushq   %r12
 631         pushq   %r13
 632         pushq   %r14
 633         pushq   %r15
 634         pushfq
 635
 636 #if 1
 637         /*
 638          * Save the FP state if we have used the FP.  Note that calling
 639          * npxsave will NULL out PCPU(npxthread).
 640          *
 641          * We have to deal with the FP state for LWKT threads in case they
 642          * happen to get preempted or block while doing an optimized
 643          * bzero/bcopy/memcpy.
 644          */
 645         cmpq    %rbx,PCPU(npxthread)
 646         jne     1f
 647         movq    %rdi,%r12               /* save %rdi. %r12 is callee-saved */
 648         movq    TD_SAVEFPU(%rbx),%rdi
 649         call    npxsave                 /* do it in a big C function */
 650         movq    %r12,%rdi               /* restore %rdi */
 651 1:
 652 #endif
 653
 654         movq    %rdi,%rax               /* switch to this thread */
 655         pushq   $cpu_lwkt_restore
 656         movq    %rsp,TD_SP(%rbx)
 657         movq    %rax,PCPU(curthread)
 658         movq    TD_SP(%rax),%rsp
 659
 660         /*
 661          * %rax contains new thread, %rbx contains old thread.
 662          */
 663         CHECKNZ((%rsp), %r9)
 664         ret
 665
 666 /*
 667  * cpu_lwkt_restore()   (current thread in %rax on entry)
 668  *
 669  *      Standard LWKT restore function.  This function is always called
 670  *      while in a critical section.
 671  *
 672  *      Warning: due to preemption the restore function can be used to
 673  *      'return' to the original thread.  Interrupt disablement must be
 674  *      protected through the switch so we cannot run splz here.
 675  *
 676  *      YYY we theoretically do not need to load KPML4phys into cr3, but if
 677  *      so we need a way to detect when the PTD we are using is being
 678  *      deleted due to a process exiting.
 679  */
 680 ENTRY(cpu_lwkt_restore)
 681         movq    KPML4phys,%rcx  /* YYY borrow but beware desched/cpuchg/exit */
 682         movq    %cr3,%rdx
 683         cmpq    %rcx,%rdx
 684         je      1f
 685         movq    %rcx,%cr3
 686 1:
 687         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 688         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 689         popfq
 690         popq    %r15
 691         popq    %r14
 692         popq    %r13
 693         popq    %r12
 694         popq    %rbx
 695         popq    %rbp
 696         ret