lib/libc/i386/gen/sigsetjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  * $FreeBSD: src/lib/libc/i386/gen/sigsetjmp.S,v 1.19.2.2 2001/07/06 12:41:44 deischen Exp $
  37  * $DragonFly: src/lib/libc/i386/gen/sigsetjmp.S,v 1.2 2003/06/17 04:26:43 dillon Exp $
  38  *
  39  * $FreeBSD: src/lib/libc/i386/gen/sigsetjmp.S,v 1.19.2.2 2001/07/06 12:41:44 deischen Exp $
  40  */
  41
  42 #include "DEFS.h"
  43 #include "SYS.h"
  44
  45 /*-
  46  * TODO:
  47  *      Rename sigsetjmp to __sigsetjmp and siglongjmp to __siglongjmp,
  48  *      remove the other *jmp functions and define everything in terms
  49  *      of the renamed functions.  This requires compiler support for
  50  *      the renamed functions (introduced in gcc-2.5.3; previous versions
  51  *      only supported *jmp with 0 or 1 leading underscores).
  52  *
  53  *      Use sigprocmask() instead of sigblock() and sigsetmask(), and
  54  *      check for and handle errors.
  55  *
  56  *      Restore _all_ the registers and the signal mask atomically.  Can
  57  *      use sigreturn() if sigreturn() works.
  58  */
  59
  60 ENTRY(sigsetjmp)
  61         movl    8(%esp),%eax
  62         movl    4(%esp),%ecx
  63         movl    %eax,44(%ecx)
  64         testl   %eax,%eax
  65         jz      2f
  66         PIC_PROLOGUE
  67         leal    28(%ecx), %eax
  68         pushl   %eax                    /* (sigset_t*)oset */
  69         pushl   $0                      /* (sigset_t*)set  */
  70         pushl   $1                      /* SIG_BLOCK       */
  71         call    PIC_PLT(CNAME(sigprocmask))
  72         addl    $12,%esp
  73         PIC_EPILOGUE
  74         movl    4(%esp),%ecx
  75 2:      movl    0(%esp),%edx
  76         movl    %edx, 0(%ecx)
  77         movl    %ebx, 4(%ecx)
  78         movl    %esp, 8(%ecx)
  79         movl    %ebp,12(%ecx)
  80         movl    %esi,16(%ecx)
  81         movl    %edi,20(%ecx)
  82         fnstcw  24(%ecx)
  83         xorl    %eax,%eax
  84         ret
  85
  86 #ifndef _THREAD_SAFE
  87 .weak CNAME(siglongjmp);
  88 .set CNAME(siglongjmp),CNAME(__siglongjmp);
  89 #endif
  90 ENTRY(__siglongjmp);
  91         movl    4(%esp),%edx
  92         cmpl    $0,44(%edx)
  93         jz      2f
  94         PIC_PROLOGUE
  95         pushl   $0                      /* (sigset_t*)oset */
  96         leal    28(%edx), %eax
  97         pushl   %eax                    /* (sigset_t*)set  */
  98         pushl   $3                      /* SIG_SETMASK     */
  99         call    PIC_PLT(CNAME(sigprocmask))
 100         addl    $12,%esp
 101         PIC_EPILOGUE
 102         movl    4(%esp),%edx
 103 2:      movl    8(%esp),%eax
 104         movl    0(%edx),%ecx
 105         movl    4(%edx),%ebx
 106         movl    8(%edx),%esp
 107         movl    12(%edx),%ebp
 108         movl    16(%edx),%esi
 109         movl    20(%edx),%edi
 110         fninit
 111         fldcw   24(%edx)
 112         testl   %eax,%eax
 113         jnz     1f
 114         incl    %eax
 115 1:      movl    %ecx,0(%esp)
 116         ret