sys/platform/pc64/x86_64/swtch.s

   1 /*
   2  * Copyright (c) 2003,2004,2008 The DragonFly Project.  All rights reserved.
   3  * Copyright (c) 2008 Jordan Gordeev.
   4  *
   5  * This code is derived from software contributed to The DragonFly Project
   6  * by Matthew Dillon <dillon@backplane.com>
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  *
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in
  16  *    the documentation and/or other materials provided with the
  17  *    distribution.
  18  * 3. Neither the name of The DragonFly Project nor the names of its
  19  *    contributors may be used to endorse or promote products derived
  20  *    from this software without specific, prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  23  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  24  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  25  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  26  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  27  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  28  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  29  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  30  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  31  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  32  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  *
  35  * Copyright (c) 1990 The Regents of the University of California.
  36  * All rights reserved.
  37  *
  38  * This code is derived from software contributed to Berkeley by
  39  * William Jolitz.
  40  *
  41  * Redistribution and use in source and binary forms, with or without
  42  * modification, are permitted provided that the following conditions
  43  * are met:
  44  * 1. Redistributions of source code must retain the above copyright
  45  *    notice, this list of conditions and the following disclaimer.
  46  * 2. Redistributions in binary form must reproduce the above copyright
  47  *    notice, this list of conditions and the following disclaimer in the
  48  *    documentation and/or other materials provided with the distribution.
  49  * 3. All advertising materials mentioning features or use of this software
  50  *    must display the following acknowledgement:
  51  *      This product includes software developed by the University of
  52  *      California, Berkeley and its contributors.
  53  * 4. Neither the name of the University nor the names of its contributors
  54  *    may be used to endorse or promote products derived from this software
  55  *    without specific prior written permission.
  56  *
  57  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  58  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  59  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  60  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  61  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  62  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  63  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  64  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  65  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  66  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  67  * SUCH DAMAGE.
  68  *
  69  * $FreeBSD: src/sys/i386/i386/swtch.s,v 1.89.2.10 2003/01/23 03:36:24 ps Exp $
  70  */
  71
  72 //#include "use_npx.h"
  73
  74 #include <sys/rtprio.h>
  75
  76 #include <machine/asmacros.h>
  77 #include <machine/segments.h>
  78
  79 #include <machine/pmap.h>
  80 #if JG
  81 #include <machine_base/apic/apicreg.h>
  82 #endif
  83 #include <machine/lock.h>
  84
  85 #include "assym.s"
  86
  87 #if defined(SMP)
  88 #define MPLOCKED        lock ;
  89 #else
  90 #define MPLOCKED
  91 #endif
  92
  93         .data
  94
  95         .globl  panic
  96         .globl  lwkt_switch_return
  97
  98 #if defined(SWTCH_OPTIM_STATS)
  99         .globl  swtch_optim_stats, tlb_flush_count
 100 swtch_optim_stats:      .long   0               /* number of _swtch_optims */
 101 tlb_flush_count:        .long   0
 102 #endif
 103
 104         .text
 105
 106
 107 /*
 108  * cpu_heavy_switch(struct thread *next_thread)
 109  *
 110  *      Switch from the current thread to a new thread.  This entry
 111  *      is normally called via the thread->td_switch function, and will
 112  *      only be called when the current thread is a heavy weight process.
 113  *
 114  *      Some instructions have been reordered to reduce pipeline stalls.
 115  *
 116  *      YYY disable interrupts once giant is removed.
 117  */
 118 ENTRY(cpu_heavy_switch)
 119         /*
 120          * Save RIP, RSP and callee-saved registers (RBX, RBP, R12-R15).
 121          */
 122         movq    PCPU(curthread),%rcx
 123         /* On top of the stack is the return adress. */
 124         movq    (%rsp),%rax                     /* (reorder optimization) */
 125         movq    TD_PCB(%rcx),%rdx               /* RDX = PCB */
 126         movq    %rax,PCB_RIP(%rdx)              /* return PC may be modified */
 127         movq    %rbx,PCB_RBX(%rdx)
 128         movq    %rsp,PCB_RSP(%rdx)
 129         movq    %rbp,PCB_RBP(%rdx)
 130         movq    %r12,PCB_R12(%rdx)
 131         movq    %r13,PCB_R13(%rdx)
 132         movq    %r14,PCB_R14(%rdx)
 133         movq    %r15,PCB_R15(%rdx)
 134
 135         /*
 136          * Clear the cpu bit in the pmap active mask.  The restore
 137          * function will set the bit in the pmap active mask.
 138          *
 139          * Special case: when switching between threads sharing the
 140          * same vmspace if we avoid clearing the bit we do not have
 141          * to reload %cr3 (if we clear the bit we could race page
 142          * table ops done by other threads and would have to reload
 143          * %cr3, because those ops will not know to IPI us).
 144          */
 145         movq    %rcx,%rbx                       /* RBX = oldthread */
 146         movq    TD_LWP(%rcx),%rcx               /* RCX = oldlwp */
 147         movq    TD_LWP(%rdi),%r13               /* R13 = newlwp */
 148         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = oldvmspace */
 149         testq   %r13,%r13                       /* might not be a heavy */
 150         jz      1f
 151         cmpq    LWP_VMSPACE(%r13),%rcx          /* same vmspace? */
 152         je      2f
 153 1:
 154         movslq  PCPU(cpuid), %rax
 155         MPLOCKED btrq   %rax, VM_PMAP+PM_ACTIVE(%rcx)
 156 2:
 157
 158         /*
 159          * Push the LWKT switch restore function, which resumes a heavy
 160          * weight process.  Note that the LWKT switcher is based on
 161          * TD_SP, while the heavy weight process switcher is based on
 162          * PCB_RSP.  TD_SP is usually two ints pushed relative to
 163          * PCB_RSP.  We push the flags for later restore by cpu_heavy_restore.
 164          */
 165         pushfq
 166         movq    $cpu_heavy_restore, %rax
 167         pushq   %rax
 168         movq    %rsp,TD_SP(%rbx)
 169
 170         /*
 171          * Save debug regs if necessary
 172          */
 173         movq    PCB_FLAGS(%rdx),%rax
 174         andq    $PCB_DBREGS,%rax
 175         jz      1f                              /* no, skip over */
 176         movq    %dr7,%rax                       /* yes, do the save */
 177         movq    %rax,PCB_DR7(%rdx)
 178         /* JG correct value? */
 179         andq    $0x0000fc00, %rax               /* disable all watchpoints */
 180         movq    %rax,%dr7
 181         movq    %dr6,%rax
 182         movq    %rax,PCB_DR6(%rdx)
 183         movq    %dr3,%rax
 184         movq    %rax,PCB_DR3(%rdx)
 185         movq    %dr2,%rax
 186         movq    %rax,PCB_DR2(%rdx)
 187         movq    %dr1,%rax
 188         movq    %rax,PCB_DR1(%rdx)
 189         movq    %dr0,%rax
 190         movq    %rax,PCB_DR0(%rdx)
 191 1:
 192
 193 #if 1
 194         /*
 195          * Save the FP state if we have used the FP.  Note that calling
 196          * npxsave will NULL out PCPU(npxthread).
 197          */
 198         cmpq    %rbx,PCPU(npxthread)
 199         jne     1f
 200         movq    %rdi,%r12               /* save %rdi. %r12 is callee-saved */
 201         movq    TD_SAVEFPU(%rbx),%rdi
 202         call    npxsave                 /* do it in a big C function */
 203         movq    %r12,%rdi               /* restore %rdi */
 204 1:
 205 #endif
 206
 207         /*
 208          * Switch to the next thread, which was passed as an argument
 209          * to cpu_heavy_switch().  The argument is in %rdi.
 210          * Set the current thread, load the stack pointer,
 211          * and 'ret' into the switch-restore function.
 212          *
 213          * The switch restore function expects the new thread to be in %rax
 214          * and the old one to be in %rbx.
 215          *
 216          * There is a one-instruction window where curthread is the new
 217          * thread but %rsp still points to the old thread's stack, but
 218          * we are protected by a critical section so it is ok.
 219          */
 220         movq    %rdi,%rax               /* RAX = newtd, RBX = oldtd */
 221         movq    %rax,PCPU(curthread)
 222         movq    TD_SP(%rax),%rsp
 223         ret
 224
 225 /*
 226  *  cpu_exit_switch(struct thread *next)
 227  *
 228  *      The switch function is changed to this when a thread is going away
 229  *      for good.  We have to ensure that the MMU state is not cached, and
 230  *      we don't bother saving the existing thread state before switching.
 231  *
 232  *      At this point we are in a critical section and this cpu owns the
 233  *      thread's token, which serves as an interlock until the switchout is
 234  *      complete.
 235  */
 236 ENTRY(cpu_exit_switch)
 237         /*
 238          * Get us out of the vmspace
 239          */
 240         movq    KPML4phys,%rcx
 241         movq    %cr3,%rax
 242         cmpq    %rcx,%rax
 243         je      1f
 244         /* JG no increment of statistics counters? see cpu_heavy_restore */
 245         movq    %rcx,%cr3
 246 1:
 247         movq    PCPU(curthread),%rbx
 248
 249         /*
 250          * If this is a process/lwp, deactivate the pmap after we've
 251          * switched it out.
 252          */
 253         movq    TD_LWP(%rbx),%rcx
 254         testq   %rcx,%rcx
 255         jz      2f
 256         movslq  PCPU(cpuid), %rax
 257         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 258         MPLOCKED btrq   %rax, VM_PMAP+PM_ACTIVE(%rcx)
 259 2:
 260         /*
 261          * Switch to the next thread.  RET into the restore function, which
 262          * expects the new thread in RAX and the old in RBX.
 263          *
 264          * There is a one-instruction window where curthread is the new
 265          * thread but %rsp still points to the old thread's stack, but
 266          * we are protected by a critical section so it is ok.
 267          */
 268         movq    %rdi,%rax
 269         movq    %rax,PCPU(curthread)
 270         movq    TD_SP(%rax),%rsp
 271         ret
 272
 273 /*
 274  * cpu_heavy_restore()  (current thread in %rax on entry)
 275  *
 276  *      Restore the thread after an LWKT switch.  This entry is normally
 277  *      called via the LWKT switch restore function, which was pulled
 278  *      off the thread stack and jumped to.
 279  *
 280  *      This entry is only called if the thread was previously saved
 281  *      using cpu_heavy_switch() (the heavy weight process thread switcher),
 282  *      or when a new process is initially scheduled.
 283  *
 284  *      NOTE: The lwp may be in any state, not necessarily LSRUN, because
 285  *      a preemption switch may interrupt the process and then return via
 286  *      cpu_heavy_restore.
 287  *
 288  *      YYY theoretically we do not have to restore everything here, a lot
 289  *      of this junk can wait until we return to usermode.  But for now
 290  *      we restore everything.
 291  *
 292  *      YYY the PCB crap is really crap, it makes startup a bitch because
 293  *      we can't switch away.
 294  *
 295  *      YYY note: spl check is done in mi_switch when it splx()'s.
 296  */
 297
 298 ENTRY(cpu_heavy_restore)
 299         popfq
 300         movq    TD_LWP(%rax),%rcx
 301
 302 #if defined(SWTCH_OPTIM_STATS)
 303         incl    _swtch_optim_stats
 304 #endif
 305         /*
 306          * Tell the pmap that our cpu is using the VMSPACE now.  We cannot
 307          * safely test/reload %cr3 until after we have set the bit in the
 308          * pmap (remember, we do not hold the MP lock in the switch code).
 309          *
 310          * Also note that when switching between two lwps sharing the
 311          * same vmspace we have already avoided clearing the cpu bit
 312          * in pm_active.  If we had cleared it other cpus would not know
 313          * to IPI us and we would have to unconditionally reload %cr3.
 314          *
 315          * Also note that if the pmap is undergoing an atomic inval/mod
 316          * that is unaware that our cpu has been added to it we have to
 317          * wait for it to complete before we can continue.
 318          */
 319         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 320         movq    PCPU(cpumask), %rsi
 321         MPLOCKED orq    %rsi, VM_PMAP+PM_ACTIVE(%rcx)
 322 #ifdef SMP
 323         btq     $CPUMASK_BIT,VM_PMAP+PM_ACTIVE(%rcx)
 324         jnc     1f
 325         pushq   %rax
 326         movq    %rcx,%rdi
 327         call    pmap_interlock_wait             /* pmap_interlock_wait(vm) */
 328         popq    %rax
 329 1:
 330 #endif
 331
 332         /*
 333          * Restore the MMU address space.  If it is the same as the last
 334          * thread we don't have to invalidate the tlb (i.e. reload cr3).
 335          * YYY which naturally also means that the PM_ACTIVE bit had better
 336          * already have been set before we set it above, check? YYY
 337          */
 338         movq    TD_PCB(%rax),%rdx               /* RDX = PCB */
 339         movq    %cr3,%rsi
 340         movq    PCB_CR3(%rdx),%rcx
 341         cmpq    %rsi,%rcx
 342         je      4f
 343 #if defined(SWTCH_OPTIM_STATS)
 344         decl    _swtch_optim_stats
 345         incl    _tlb_flush_count
 346 #endif
 347         movq    %rcx,%cr3
 348 4:
 349         /*
 350          * NOTE: %rbx is the previous thread and %eax is the new thread.
 351          *       %rbx is retained throughout so we can return it.
 352          *
 353          *       lwkt_switch[_return] is responsible for handling TDF_RUNNING.
 354          */
 355
 356         /*
 357          * Deal with the PCB extension, restore the private tss
 358          */
 359         movq    PCB_EXT(%rdx),%rdi      /* check for a PCB extension */
 360         movq    $1,%rcx                 /* maybe mark use of a private tss */
 361         testq   %rdi,%rdi
 362 #if JG
 363         jnz     2f
 364 #endif
 365
 366         /*
 367          * Going back to the common_tss.  We may need to update TSS_RSP0
 368          * which sets the top of the supervisor stack when entering from
 369          * usermode.  The PCB is at the top of the stack but we need another
 370          * 16 bytes to take vm86 into account.
 371          */
 372         movq    %rdx,%rcx
 373         /*leaq  -TF_SIZE(%rdx),%rcx*/
 374         movq    %rcx, PCPU(common_tss) + TSS_RSP0
 375
 376 #if JG
 377         cmpl    $0,PCPU(private_tss)    /* don't have to reload if      */
 378         je      3f                      /* already using the common TSS */
 379
 380         /* JG? */
 381         subq    %rcx,%rcx               /* unmark use of private tss */
 382
 383         /*
 384          * Get the address of the common TSS descriptor for the ltr.
 385          * There is no way to get the address of a segment-accessed variable
 386          * so we store a self-referential pointer at the base of the per-cpu
 387          * data area and add the appropriate offset.
 388          */
 389         /* JG movl? */
 390         movq    $gd_common_tssd, %rdi
 391         /* JG name for "%gs:0"? */
 392         addq    %gs:0, %rdi
 393
 394         /*
 395          * Move the correct TSS descriptor into the GDT slot, then reload
 396          * ltr.
 397          */
 398 2:
 399         /* JG */
 400         movl    %rcx,PCPU(private_tss)          /* mark/unmark private tss */
 401         movq    PCPU(tss_gdt), %rbx             /* entry in GDT */
 402         movq    0(%rdi), %rax
 403         movq    %rax, 0(%rbx)
 404         movl    $GPROC0_SEL*8, %esi             /* GSEL(entry, SEL_KPL) */
 405         ltr     %si
 406 #endif
 407
 408 3:
 409         /*
 410          * Restore the user %gs and %fs
 411          */
 412         movq    PCB_FSBASE(%rdx),%r9
 413         cmpq    PCPU(user_fs),%r9
 414         je      4f
 415         movq    %rdx,%r10
 416         movq    %r9,PCPU(user_fs)
 417         movl    $MSR_FSBASE,%ecx
 418         movl    PCB_FSBASE(%r10),%eax
 419         movl    PCB_FSBASE+4(%r10),%edx
 420         wrmsr
 421         movq    %r10,%rdx
 422 4:
 423         movq    PCB_GSBASE(%rdx),%r9
 424         cmpq    PCPU(user_gs),%r9
 425         je      5f
 426         movq    %rdx,%r10
 427         movq    %r9,PCPU(user_gs)
 428         movl    $MSR_KGSBASE,%ecx       /* later swapgs moves it to GSBASE */
 429         movl    PCB_GSBASE(%r10),%eax
 430         movl    PCB_GSBASE+4(%r10),%edx
 431         wrmsr
 432         movq    %r10,%rdx
 433 5:
 434
 435         /*
 436          * Restore general registers.  %rbx is restored later.
 437          */
 438         movq    PCB_RSP(%rdx), %rsp
 439         movq    PCB_RBP(%rdx), %rbp
 440         movq    PCB_R12(%rdx), %r12
 441         movq    PCB_R13(%rdx), %r13
 442         movq    PCB_R14(%rdx), %r14
 443         movq    PCB_R15(%rdx), %r15
 444         movq    PCB_RIP(%rdx), %rax
 445         movq    %rax, (%rsp)
 446
 447 #if JG
 448         /*
 449          * Restore the user LDT if we have one
 450          */
 451         cmpl    $0, PCB_USERLDT(%edx)
 452         jnz     1f
 453         movl    _default_ldt,%eax
 454         cmpl    PCPU(currentldt),%eax
 455         je      2f
 456         lldt    _default_ldt
 457         movl    %eax,PCPU(currentldt)
 458         jmp     2f
 459 1:      pushl   %edx
 460         call    set_user_ldt
 461         popl    %edx
 462 2:
 463 #endif
 464 #if JG
 465         /*
 466          * Restore the user TLS if we have one
 467          */
 468         pushl   %edx
 469         call    set_user_TLS
 470         popl    %edx
 471 #endif
 472
 473         /*
 474          * Restore the DEBUG register state if necessary.
 475          */
 476         movq    PCB_FLAGS(%rdx),%rax
 477         andq    $PCB_DBREGS,%rax
 478         jz      1f                              /* no, skip over */
 479         movq    PCB_DR6(%rdx),%rax              /* yes, do the restore */
 480         movq    %rax,%dr6
 481         movq    PCB_DR3(%rdx),%rax
 482         movq    %rax,%dr3
 483         movq    PCB_DR2(%rdx),%rax
 484         movq    %rax,%dr2
 485         movq    PCB_DR1(%rdx),%rax
 486         movq    %rax,%dr1
 487         movq    PCB_DR0(%rdx),%rax
 488         movq    %rax,%dr0
 489         movq    %dr7,%rax                /* load dr7 so as not to disturb */
 490         /* JG correct value? */
 491         andq    $0x0000fc00,%rax         /*   reserved bits               */
 492         /* JG we've got more registers on x86_64 */
 493         movq    PCB_DR7(%rdx),%rcx
 494         /* JG correct value? */
 495         andq    $~0x0000fc00,%rcx
 496         orq     %rcx,%rax
 497         movq    %rax,%dr7
 498
 499         /*
 500          * Clear the QUICKRET flag when restoring a user process context
 501          * so we don't try to do a quick syscall return.
 502          */
 503 1:
 504         andl    $~RQF_QUICKRET,PCPU(reqflags)
 505         movq    %rbx,%rax
 506         movq    PCB_RBX(%rdx),%rbx
 507         ret
 508
 509 /*
 510  * savectx(struct pcb *pcb)
 511  *
 512  * Update pcb, saving current processor state.
 513  */
 514 ENTRY(savectx)
 515         /* fetch PCB */
 516         /* JG use %rdi instead of %rcx everywhere? */
 517         movq    %rdi,%rcx
 518
 519         /* caller's return address - child won't execute this routine */
 520         movq    (%rsp),%rax
 521         movq    %rax,PCB_RIP(%rcx)
 522
 523         movq    %cr3,%rax
 524         movq    %rax,PCB_CR3(%rcx)
 525
 526         movq    %rbx,PCB_RBX(%rcx)
 527         movq    %rsp,PCB_RSP(%rcx)
 528         movq    %rbp,PCB_RBP(%rcx)
 529         movq    %r12,PCB_R12(%rcx)
 530         movq    %r13,PCB_R13(%rcx)
 531         movq    %r14,PCB_R14(%rcx)
 532         movq    %r15,PCB_R15(%rcx)
 533
 534 #if 1
 535         /*
 536          * If npxthread == NULL, then the npx h/w state is irrelevant and the
 537          * state had better already be in the pcb.  This is true for forks
 538          * but not for dumps (the old book-keeping with FP flags in the pcb
 539          * always lost for dumps because the dump pcb has 0 flags).
 540          *
 541          * If npxthread != NULL, then we have to save the npx h/w state to
 542          * npxthread's pcb and copy it to the requested pcb, or save to the
 543          * requested pcb and reload.  Copying is easier because we would
 544          * have to handle h/w bugs for reloading.  We used to lose the
 545          * parent's npx state for forks by forgetting to reload.
 546          */
 547         movq    PCPU(npxthread),%rax
 548         testq   %rax,%rax
 549         jz      1f
 550
 551         pushq   %rcx                    /* target pcb */
 552         movq    TD_SAVEFPU(%rax),%rax   /* originating savefpu area */
 553         pushq   %rax
 554
 555         movq    %rax,%rdi
 556         call    npxsave
 557
 558         popq    %rax
 559         popq    %rcx
 560
 561         movq    $PCB_SAVEFPU_SIZE,%rdx
 562         leaq    PCB_SAVEFPU(%rcx),%rcx
 563         movq    %rcx,%rsi
 564         movq    %rax,%rdi
 565         call    bcopy
 566 #endif
 567
 568 1:
 569         ret
 570
 571 /*
 572  * cpu_idle_restore()   (current thread in %rax on entry) (one-time execution)
 573  *
 574  *      Don't bother setting up any regs other than %rbp so backtraces
 575  *      don't die.  This restore function is used to bootstrap into the
 576  *      cpu_idle() LWKT only, after that cpu_lwkt_*() will be used for
 577  *      switching.
 578  *
 579  *      Clear TDF_RUNNING in old thread only after we've cleaned up %cr3.
 580  *      This only occurs during system boot so no special handling is
 581  *      required for migration.
 582  *
 583  *      If we are an AP we have to call ap_init() before jumping to
 584  *      cpu_idle().  ap_init() will synchronize with the BP and finish
 585  *      setting up various ncpu-dependant globaldata fields.  This may
 586  *      happen on UP as well as SMP if we happen to be simulating multiple
 587  *      cpus.
 588  */
 589 ENTRY(cpu_idle_restore)
 590         /* cli */
 591         movq    KPML4phys,%rcx
 592         /* JG xor? */
 593         movq    $0,%rbp
 594         /* JG push RBP? */
 595         pushq   $0
 596         movq    %rcx,%cr3
 597         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 598 #if 0
 599         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 600 #endif
 601 #ifdef SMP
 602         cmpl    $0,PCPU(cpuid)
 603         je      1f
 604         call    ap_init
 605 1:
 606 #endif
 607         /*
 608          * ap_init can decide to enable interrupts early, but otherwise, or if
 609          * we are UP, do it here.
 610          */
 611         sti
 612         jmp     cpu_idle
 613
 614 /*
 615  * cpu_kthread_restore() (current thread is %rax on entry) (one-time execution)
 616  *
 617  *      Don't bother setting up any regs other then %rbp so backtraces
 618  *      don't die.  This restore function is used to bootstrap into an
 619  *      LWKT based kernel thread only.  cpu_lwkt_switch() will be used
 620  *      after this.
 621  *
 622  *      Because this switch target does not 'return' to lwkt_switch()
 623  *      we have to call lwkt_switch_return(otd) to clean up otd.
 624  *      otd is in %ebx.
 625  *
 626  *      Since all of our context is on the stack we are reentrant and
 627  *      we can release our critical section and enable interrupts early.
 628  */
 629 ENTRY(cpu_kthread_restore)
 630         sti
 631         movq    KPML4phys,%rcx
 632         movq    TD_PCB(%rax),%r13
 633         /* JG "movq $0, %rbp"? "xorq %rbp, %rbp"? */
 634         movq    $0,%rbp
 635         movq    %rcx,%cr3
 636
 637         /*
 638          * rax and rbx come from the switchout code.  Call
 639          * lwkt_switch_return(otd).
 640          *
 641          * NOTE: unlike i386, %rsi and %rdi are not call-saved regs.
 642          */
 643         pushq   %rax
 644         movq    %rbx,%rdi
 645         call    lwkt_switch_return
 646         popq    %rax
 647 #if 0
 648         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 649         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 650 #endif
 651         decl    TD_CRITCOUNT(%rax)
 652         movq    PCB_R12(%r13),%rdi      /* argument to RBX function */
 653         movq    PCB_RBX(%r13),%rax      /* thread function */
 654         /* note: top of stack return address inherited by function */
 655         jmp     *%rax
 656
 657 /*
 658  * cpu_lwkt_switch(struct thread *)
 659  *
 660  *      Standard LWKT switching function.  Only non-scratch registers are
 661  *      saved and we don't bother with the MMU state or anything else.
 662  *
 663  *      This function is always called while in a critical section.
 664  *
 665  *      There is a one-instruction window where curthread is the new
 666  *      thread but %rsp still points to the old thread's stack, but
 667  *      we are protected by a critical section so it is ok.
 668  */
 669 ENTRY(cpu_lwkt_switch)
 670         pushq   %rbp    /* JG note: GDB hacked to locate ebp rel to td_sp */
 671         pushq   %rbx
 672         movq    PCPU(curthread),%rbx
 673         pushq   %r12
 674         pushq   %r13
 675         pushq   %r14
 676         pushq   %r15
 677         pushfq
 678
 679 #if 1
 680         /*
 681          * Save the FP state if we have used the FP.  Note that calling
 682          * npxsave will NULL out PCPU(npxthread).
 683          *
 684          * We have to deal with the FP state for LWKT threads in case they
 685          * happen to get preempted or block while doing an optimized
 686          * bzero/bcopy/memcpy.
 687          */
 688         cmpq    %rbx,PCPU(npxthread)
 689         jne     1f
 690         movq    %rdi,%r12               /* save %rdi. %r12 is callee-saved */
 691         movq    TD_SAVEFPU(%rbx),%rdi
 692         call    npxsave                 /* do it in a big C function */
 693         movq    %r12,%rdi               /* restore %rdi */
 694 1:
 695 #endif
 696
 697         movq    %rdi,%rax               /* switch to this thread */
 698         pushq   $cpu_lwkt_restore
 699         movq    %rsp,TD_SP(%rbx)
 700         movq    %rax,PCPU(curthread)
 701         movq    TD_SP(%rax),%rsp
 702
 703         /*
 704          * %rax contains new thread, %rbx contains old thread.
 705          */
 706         ret
 707
 708 /*
 709  * cpu_lwkt_restore()   (current thread in %rax on entry)
 710  *
 711  *      Standard LWKT restore function.  This function is always called
 712  *      while in a critical section.
 713  *
 714  *      Warning: due to preemption the restore function can be used to
 715  *      'return' to the original thread.  Interrupt disablement must be
 716  *      protected through the switch so we cannot run splz here.
 717  *
 718  *      YYY we theoretically do not need to load KPML4phys into cr3, but if
 719  *      so we need a way to detect when the PTD we are using is being
 720  *      deleted due to a process exiting.
 721  */
 722 ENTRY(cpu_lwkt_restore)
 723         movq    KPML4phys,%rcx  /* YYY borrow but beware desched/cpuchg/exit */
 724         movq    %cr3,%rdx
 725         cmpq    %rcx,%rdx
 726         je      1f
 727         movq    %rcx,%cr3
 728 1:
 729         /*
 730          * NOTE: %rbx is the previous thread and %eax is the new thread.
 731          *       %rbx is retained throughout so we can return it.
 732          *
 733          *       lwkt_switch[_return] is responsible for handling TDF_RUNNING.
 734          */
 735         movq    %rbx,%rax
 736         popfq
 737         popq    %r15
 738         popq    %r14
 739         popq    %r13
 740         popq    %r12
 741         popq    %rbx
 742         popq    %rbp
 743         ret