29dac4cd7c492938c471334d3056b55dd97f577c
[dragonfly.git] / sys / platform / pc32 / i386 / swtch.s
1 /*
2  * Copyright (c) 2003,2004 The DragonFly Project.  All rights reserved.
3  * 
4  * This code is derived from software contributed to The DragonFly Project
5  * by Matthew Dillon <dillon@backplane.com>
6  * 
7  * Redistribution and use in source and binary forms, with or without
8  * modification, are permitted provided that the following conditions
9  * are met:
10  * 
11  * 1. Redistributions of source code must retain the above copyright
12  *    notice, this list of conditions and the following disclaimer.
13  * 2. Redistributions in binary form must reproduce the above copyright
14  *    notice, this list of conditions and the following disclaimer in
15  *    the documentation and/or other materials provided with the
16  *    distribution.
17  * 3. Neither the name of The DragonFly Project nor the names of its
18  *    contributors may be used to endorse or promote products derived
19  *    from this software without specific, prior written permission.
20  * 
21  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
22  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
23  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
24  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
25  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
26  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
27  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
28  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
29  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
30  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
31  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
32  * SUCH DAMAGE.
33  * 
34  * Copyright (c) 1990 The Regents of the University of California.
35  * All rights reserved.
36  *
37  * This code is derived from software contributed to Berkeley by
38  * William Jolitz.
39  *
40  * Redistribution and use in source and binary forms, with or without
41  * modification, are permitted provided that the following conditions
42  * are met:
43  * 1. Redistributions of source code must retain the above copyright
44  *    notice, this list of conditions and the following disclaimer.
45  * 2. Redistributions in binary form must reproduce the above copyright
46  *    notice, this list of conditions and the following disclaimer in the
47  *    documentation and/or other materials provided with the distribution.
48  * 3. All advertising materials mentioning features or use of this software
49  *    must display the following acknowledgement:
50  *      This product includes software developed by the University of
51  *      California, Berkeley and its contributors.
52  * 4. Neither the name of the University nor the names of its contributors
53  *    may be used to endorse or promote products derived from this software
54  *    without specific prior written permission.
55  *
56  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
57  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
58  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
59  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
60  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
61  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
62  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
63  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
64  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
65  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
66  * SUCH DAMAGE.
67  *
68  * $FreeBSD: src/sys/i386/i386/swtch.s,v 1.89.2.10 2003/01/23 03:36:24 ps Exp $
69  * $DragonFly: src/sys/platform/pc32/i386/swtch.s,v 1.47 2007/06/29 21:54:10 dillon Exp $
70  */
71
72 #include "use_npx.h"
73
74 #include <sys/rtprio.h>
75
76 #include <machine/asmacros.h>
77 #include <machine/segments.h>
78
79 #include <machine/pmap.h>
80 #include <machine_base/apic/apicreg.h>
81 #include <machine/lock.h>
82
83 #include "assym.s"
84
85 #if defined(SMP)
86 #define MPLOCKED        lock ;
87 #else
88 #define MPLOCKED
89 #endif
90
91         .data
92
93         .globl  panic
94         .globl  lwkt_switch_return
95
96 #if defined(SWTCH_OPTIM_STATS)
97         .globl  swtch_optim_stats, tlb_flush_count
98 swtch_optim_stats:      .long   0               /* number of _swtch_optims */
99 tlb_flush_count:        .long   0
100 #endif
101
102         .text
103
104
105 /*
106  * cpu_heavy_switch(next_thread)
107  *
108  *      Switch from the current thread to a new thread.  This entry
109  *      is normally called via the thread->td_switch function, and will
110  *      only be called when the current thread is a heavy weight process.
111  *
112  *      Some instructions have been reordered to reduce pipeline stalls.
113  *
114  *      YYY disable interrupts once giant is removed.
115  */
116 ENTRY(cpu_heavy_switch)
117         /*
118          * Save general regs
119          */
120         movl    PCPU(curthread),%ecx
121         movl    (%esp),%eax                     /* (reorder optimization) */
122         movl    TD_PCB(%ecx),%edx               /* EDX = PCB */
123         movl    %eax,PCB_EIP(%edx)              /* return PC may be modified */
124         movl    %ebx,PCB_EBX(%edx)
125         movl    %esp,PCB_ESP(%edx)
126         movl    %ebp,PCB_EBP(%edx)
127         movl    %esi,PCB_ESI(%edx)
128         movl    %edi,PCB_EDI(%edx)
129         movl    4(%esp),%edi                    /* EDI = newthread */
130
131         /*
132          * Clear the cpu bit in the pmap active mask.  The restore
133          * function will set the bit in the pmap active mask.
134          *
135          * Special case: when switching between threads sharing the
136          * same vmspace if we avoid clearing the bit we do not have
137          * to reload %cr3 (if we clear the bit we could race page
138          * table ops done by other threads and would have to reload
139          * %cr3, because those ops will not know to IPI us).
140          */
141         movl    %ecx,%ebx                       /* EBX = oldthread */
142         movl    TD_LWP(%ecx),%ecx               /* ECX = oldlwp */
143         movl    TD_LWP(%edi),%esi               /* ESI = newlwp */
144         movl    LWP_VMSPACE(%ecx),%ecx          /* ECX = oldvmspace */
145         testl   %esi,%esi                       /* might not be a heavy */
146         jz      1f
147         cmpl    LWP_VMSPACE(%esi),%ecx          /* same vmspace? */
148         je      2f
149 1:
150         movl    PCPU(cpuid), %eax
151         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%ecx)
152 2:
153         /*
154          * Push the LWKT switch restore function, which resumes a heavy
155          * weight process.  Note that the LWKT switcher is based on
156          * TD_SP, while the heavy weight process switcher is based on
157          * PCB_ESP.  TD_SP is usually two ints pushed relative to
158          * PCB_ESP.  We push the flags for later restore by cpu_heavy_restore.
159          */
160         pushfl
161         pushl   $cpu_heavy_restore
162         movl    %esp,TD_SP(%ebx)
163
164         /*
165          * Save debug regs if necessary
166          */
167         movb    PCB_FLAGS(%edx),%al
168         andb    $PCB_DBREGS,%al
169         jz      1f                              /* no, skip over */
170         movl    %dr7,%eax                       /* yes, do the save */
171         movl    %eax,PCB_DR7(%edx)
172         andl    $0x0000fc00, %eax               /* disable all watchpoints */
173         movl    %eax,%dr7
174         movl    %dr6,%eax
175         movl    %eax,PCB_DR6(%edx)
176         movl    %dr3,%eax
177         movl    %eax,PCB_DR3(%edx)
178         movl    %dr2,%eax
179         movl    %eax,PCB_DR2(%edx)
180         movl    %dr1,%eax
181         movl    %eax,PCB_DR1(%edx)
182         movl    %dr0,%eax
183         movl    %eax,PCB_DR0(%edx)
184 1:
185  
186 #if NNPX > 0
187         /*
188          * Save the FP state if we have used the FP.  Note that calling
189          * npxsave will NULL out PCPU(npxthread).
190          */
191         cmpl    %ebx,PCPU(npxthread)
192         jne     1f
193         pushl   TD_SAVEFPU(%ebx)
194         call    npxsave                 /* do it in a big C function */
195         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
196 1:
197 #endif  /* NNPX > 0 */
198
199         /*
200          * Switch to the next thread, which was passed as an argument
201          * to cpu_heavy_switch().  Due to the eflags and switch-restore
202          * function we pushed, the argument is at 12(%esp).  Set the current
203          * thread, load the stack pointer, and 'ret' into the switch-restore
204          * function.
205          *
206          * The switch restore function expects the new thread to be in %eax
207          * and the old one to be in %ebx.
208          *
209          * There is a one-instruction window where curthread is the new
210          * thread but %esp still points to the old thread's stack, but
211          * we are protected by a critical section so it is ok.
212          */
213         movl    %edi,%eax               /* EAX = newtd, EBX = oldtd */
214         movl    %eax,PCPU(curthread)
215         movl    TD_SP(%eax),%esp
216         ret
217
218 /*
219  *  cpu_exit_switch()
220  *
221  *      The switch function is changed to this when a thread is going away
222  *      for good.  We have to ensure that the MMU state is not cached, and
223  *      we don't bother saving the existing thread state before switching.
224  *
225  *      At this point we are in a critical section and this cpu owns the
226  *      thread's token, which serves as an interlock until the switchout is
227  *      complete.
228  */
229 ENTRY(cpu_exit_switch)
230         /*
231          * Get us out of the vmspace
232          */
233         movl    IdlePTD,%ecx
234         movl    %cr3,%eax
235         cmpl    %ecx,%eax
236         je      1f
237         movl    %ecx,%cr3
238 1:
239         movl    PCPU(curthread),%ebx
240
241         /*
242          * If this is a process/lwp, deactivate the pmap after we've
243          * switched it out.
244          */
245         movl    TD_LWP(%ebx),%ecx
246         testl   %ecx,%ecx
247         jz      2f
248         movl    PCPU(cpuid), %eax
249         movl    LWP_VMSPACE(%ecx), %ecx         /* ECX = vmspace */
250         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%ecx)
251 2:
252         /*
253          * Switch to the next thread.  RET into the restore function, which
254          * expects the new thread in EAX and the old in EBX.
255          *
256          * There is a one-instruction window where curthread is the new
257          * thread but %esp still points to the old thread's stack, but
258          * we are protected by a critical section so it is ok.
259          */
260         movl    4(%esp),%eax
261         movl    %eax,PCPU(curthread)
262         movl    TD_SP(%eax),%esp
263         ret
264
265 /*
266  * cpu_heavy_restore()  (current thread in %eax on entry)
267  *
268  *      Restore the thread after an LWKT switch.  This entry is normally
269  *      called via the LWKT switch restore function, which was pulled 
270  *      off the thread stack and jumped to.
271  *
272  *      This entry is only called if the thread was previously saved
273  *      using cpu_heavy_switch() (the heavy weight process thread switcher),
274  *      or when a new process is initially scheduled.
275  *
276  *      NOTE: The lwp may be in any state, not necessarily LSRUN, because
277  *      a preemption switch may interrupt the process and then return via 
278  *      cpu_heavy_restore.
279  *
280  *      YYY theoretically we do not have to restore everything here, a lot
281  *      of this junk can wait until we return to usermode.  But for now
282  *      we restore everything.
283  *
284  *      YYY the PCB crap is really crap, it makes startup a bitch because
285  *      we can't switch away.
286  *
287  *      YYY note: spl check is done in mi_switch when it splx()'s.
288  */
289
290 ENTRY(cpu_heavy_restore)
291         popfl
292         movl    TD_LWP(%eax),%ecx
293
294 #if defined(SWTCH_OPTIM_STATS)
295         incl    _swtch_optim_stats
296 #endif
297         /*
298          * Tell the pmap that our cpu is using the VMSPACE now.  We cannot
299          * safely test/reload %cr3 until after we have set the bit in the
300          * pmap (remember, we do not hold the MP lock in the switch code).
301          *
302          * Also note that when switching between two lwps sharing the
303          * same vmspace we have already avoided clearing the cpu bit
304          * in pm_active.  If we had cleared it other cpus would not know
305          * to IPI us and we would have to unconditionally reload %cr3.
306          *
307          * Also note that if the pmap is undergoing an atomic inval/mod
308          * that is unaware that our cpu has been added to it we have to
309          * wait for it to complete before we can continue.
310          */
311         movl    LWP_VMSPACE(%ecx), %ecx         /* ECX = vmspace */
312 #ifdef SMP
313         pushl   %eax                            /* save curthread */
314 1:
315         movl    VM_PMAP+PM_ACTIVE(%ecx),%eax    /* old value for cmpxchgl */
316         movl    PCPU(cpumask), %esi
317         orl     %eax,%esi                       /* new value for cmpxchgl */
318         MPLOCKED cmpxchgl %esi,VM_PMAP+PM_ACTIVE(%ecx)
319         jnz     1b
320
321         /*
322          * Check CPUMASK_BIT
323          */
324         testl   $CPUMASK_LOCK,%eax
325         jz      1f
326         pushl   %ecx                            /* call(stack:vmspace) */
327         call    pmap_interlock_wait
328         popl    %ecx
329
330         /*
331          * Needs unconditional load cr3
332          */
333         popl    %eax                            /* EAX = curthread */
334         movl    TD_PCB(%eax),%edx               /* EDX = PCB */
335         movl    PCB_CR3(%edx),%ecx
336         jmp     2f
337 1:
338         popl    %eax
339 #else
340         movl    PCPU(cpumask), %esi
341         orl     %esi, VM_PMAP+PM_ACTIVE(%ecx)
342 #endif
343
344         /*
345          * Restore the MMU address space.  If it is the same as the last
346          * thread we don't have to invalidate the tlb (i.e. reload cr3).
347          * YYY which naturally also means that the PM_ACTIVE bit had better
348          * already have been set before we set it above, check? YYY
349          */
350         movl    TD_PCB(%eax),%edx               /* EDX = PCB */
351         movl    %cr3,%esi
352         movl    PCB_CR3(%edx),%ecx
353         cmpl    %esi,%ecx
354         je      4f
355 2:
356 #if defined(SWTCH_OPTIM_STATS)
357         decl    _swtch_optim_stats
358         incl    _tlb_flush_count
359 #endif
360         movl    %ecx,%cr3
361 4:
362
363         /*
364          * NOTE: %ebx is the previous thread and %eax is the new thread.
365          *       %ebx is retained throughout so we can return it.
366          *
367          *       lwkt_switch[_return] is responsible for handling TDF_RUNNING.
368          */
369
370         /*
371          * Deal with the PCB extension, restore the private tss
372          */
373         movl    PCB_EXT(%edx),%edi      /* check for a PCB extension */
374         movl    $1,%ecx                 /* maybe mark use of a private tss */
375         testl   %edi,%edi
376         jnz     2f
377
378         /*
379          * Going back to the common_tss.  We may need to update TSS_ESP0
380          * which sets the top of the supervisor stack when entering from
381          * usermode.  The PCB is at the top of the stack but we need another
382          * 16 bytes to take vm86 into account.
383          */
384         leal    -16(%edx),%ecx
385         movl    %ecx, PCPU(common_tss) + TSS_ESP0
386
387         cmpl    $0,PCPU(private_tss)    /* don't have to reload if      */
388         je      3f                      /* already using the common TSS */
389
390         subl    %ecx,%ecx               /* unmark use of private tss */
391
392         /*
393          * Get the address of the common TSS descriptor for the ltr.
394          * There is no way to get the address of a segment-accessed variable
395          * so we store a self-referential pointer at the base of the per-cpu
396          * data area and add the appropriate offset.
397          */
398         movl    $gd_common_tssd, %edi
399         addl    %fs:0, %edi
400
401         /*
402          * Move the correct TSS descriptor into the GDT slot, then reload
403          * ltr.
404          */
405 2:
406         movl    %ecx,PCPU(private_tss)          /* mark/unmark private tss */
407         movl    PCPU(tss_gdt), %ecx             /* entry in GDT */
408         movl    0(%edi), %eax
409         movl    %eax, 0(%ecx)
410         movl    4(%edi), %eax
411         movl    %eax, 4(%ecx)
412         movl    $GPROC0_SEL*8, %esi             /* GSEL(entry, SEL_KPL) */
413         ltr     %si
414
415 3:
416         /*
417          * Restore general registers.  %ebx is restored later.
418          */
419         movl    PCB_ESP(%edx),%esp
420         movl    PCB_EBP(%edx),%ebp
421         movl    PCB_ESI(%edx),%esi
422         movl    PCB_EDI(%edx),%edi
423         movl    PCB_EIP(%edx),%eax
424         movl    %eax,(%esp)
425
426         /*
427          * Restore the user LDT if we have one
428          */
429         cmpl    $0, PCB_USERLDT(%edx)
430         jnz     1f
431         movl    _default_ldt,%eax
432         cmpl    PCPU(currentldt),%eax
433         je      2f
434         lldt    _default_ldt
435         movl    %eax,PCPU(currentldt)
436         jmp     2f
437 1:      pushl   %edx
438         call    set_user_ldt
439         popl    %edx
440 2:
441         /*
442          * Restore the user TLS if we have one
443          */
444         pushl   %edx
445         call    set_user_TLS
446         popl    %edx
447
448         /*
449          * Restore the DEBUG register state if necessary.
450          */
451         movb    PCB_FLAGS(%edx),%al
452         andb    $PCB_DBREGS,%al
453         jz      1f                              /* no, skip over */
454         movl    PCB_DR6(%edx),%eax              /* yes, do the restore */
455         movl    %eax,%dr6
456         movl    PCB_DR3(%edx),%eax
457         movl    %eax,%dr3
458         movl    PCB_DR2(%edx),%eax
459         movl    %eax,%dr2
460         movl    PCB_DR1(%edx),%eax
461         movl    %eax,%dr1
462         movl    PCB_DR0(%edx),%eax
463         movl    %eax,%dr0
464         movl    %dr7,%eax                /* load dr7 so as not to disturb */
465         andl    $0x0000fc00,%eax         /*   reserved bits               */
466         movl    PCB_DR7(%edx),%ecx
467         andl    $~0x0000fc00,%ecx
468         orl     %ecx,%eax
469         movl    %eax,%dr7
470 1:
471         movl    %ebx,%eax               /* return previous thread */
472         movl    PCB_EBX(%edx),%ebx
473         ret
474
475 /*
476  * savectx(pcb)
477  *
478  * Update pcb, saving current processor state.
479  */
480 ENTRY(savectx)
481         /* fetch PCB */
482         movl    4(%esp),%ecx
483
484         /* caller's return address - child won't execute this routine */
485         movl    (%esp),%eax
486         movl    %eax,PCB_EIP(%ecx)
487
488         movl    %cr3,%eax
489         movl    %eax,PCB_CR3(%ecx)
490
491         movl    %ebx,PCB_EBX(%ecx)
492         movl    %esp,PCB_ESP(%ecx)
493         movl    %ebp,PCB_EBP(%ecx)
494         movl    %esi,PCB_ESI(%ecx)
495         movl    %edi,PCB_EDI(%ecx)
496
497 #if NNPX > 0
498         /*
499          * If npxthread == NULL, then the npx h/w state is irrelevant and the
500          * state had better already be in the pcb.  This is true for forks
501          * but not for dumps (the old book-keeping with FP flags in the pcb
502          * always lost for dumps because the dump pcb has 0 flags).
503          *
504          * If npxthread != NULL, then we have to save the npx h/w state to
505          * npxthread's pcb and copy it to the requested pcb, or save to the
506          * requested pcb and reload.  Copying is easier because we would
507          * have to handle h/w bugs for reloading.  We used to lose the
508          * parent's npx state for forks by forgetting to reload.
509          */
510         movl    PCPU(npxthread),%eax
511         testl   %eax,%eax
512         je      1f
513
514         pushl   %ecx                    /* target pcb */
515         movl    TD_SAVEFPU(%eax),%eax   /* originating savefpu area */
516         pushl   %eax
517
518         pushl   %eax
519         call    npxsave
520         addl    $4,%esp
521
522         popl    %eax
523         popl    %ecx
524
525         pushl   $PCB_SAVEFPU_SIZE
526         leal    PCB_SAVEFPU(%ecx),%ecx
527         pushl   %ecx
528         pushl   %eax
529         call    bcopy
530         addl    $12,%esp
531 #endif  /* NNPX > 0 */
532
533 1:
534         ret
535
536 /*
537  * cpu_idle_restore()   (current thread in %eax on entry) (one-time execution)
538  *
539  *      Don't bother setting up any regs other then %ebp so backtraces
540  *      don't die.  This restore function is used to bootstrap into the
541  *      cpu_idle() LWKT only, after that cpu_lwkt_*() will be used for
542  *      switching.
543  *
544  *      Clear TDF_RUNNING in old thread only after we've cleaned up %cr3.
545  *      This only occurs during system boot so no special handling is
546  *      required for migration.
547  *
548  *      If we are an AP we have to call ap_init() before jumping to
549  *      cpu_idle().  ap_init() will synchronize with the BP and finish
550  *      setting up various ncpu-dependant globaldata fields.  This may
551  *      happen on UP as well as SMP if we happen to be simulating multiple
552  *      cpus.
553  */
554 ENTRY(cpu_idle_restore)
555         /* cli */
556         movl    IdlePTD,%ecx
557         movl    $0,%ebp
558         pushl   $0
559         movl    %ecx,%cr3
560         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
561 #if 0
562         orl     $TDF_RUNNING,TD_FLAGS(%eax)
563 #endif
564 #ifdef SMP
565         cmpl    $0,PCPU(cpuid)
566         je      1f
567         call    ap_init
568 1:
569 #endif
570         /*
571          * ap_init can decide to enable interrupts early, but otherwise, or if
572          * we are UP, do it here.
573          */
574         sti
575         jmp     cpu_idle
576
577 /*
578  * cpu_kthread_restore() (current thread is %eax on entry) (one-time execution)
579  *
580  *      Don't bother setting up any regs other then %ebp so backtraces
581  *      don't die.  This restore function is used to bootstrap into an
582  *      LWKT based kernel thread only.  cpu_lwkt_switch() will be used
583  *      after this.
584  *
585  *      Since all of our context is on the stack we are reentrant and
586  *      we can release our critical section and enable interrupts early.
587  *
588  *      Because this switch target does not 'return' to lwkt_switch()
589  *      we have to call lwkt_switch_return(otd) to clean up otd.
590  *      otd is in %ebx.
591  */
592 ENTRY(cpu_kthread_restore)
593         sti
594         movl    IdlePTD,%ecx
595         movl    TD_PCB(%eax),%esi
596         movl    $0,%ebp
597         movl    %ecx,%cr3
598
599         pushl   %eax
600         pushl   %ebx    /* argument to lwkt_switch_return */
601         call    lwkt_switch_return
602         addl    $4,%esp
603         popl    %eax
604         decl    TD_CRITCOUNT(%eax)
605         popl    %eax            /* kthread exit function */
606         pushl   PCB_EBX(%esi)   /* argument to ESI function */
607         pushl   %eax            /* set exit func as return address */
608         movl    PCB_ESI(%esi),%eax
609         jmp     *%eax
610
611 /*
612  * cpu_lwkt_switch()
613  *
614  *      Standard LWKT switching function.  Only non-scratch registers are
615  *      saved and we don't bother with the MMU state or anything else.
616  *
617  *      This function is always called while in a critical section.
618  *
619  *      There is a one-instruction window where curthread is the new
620  *      thread but %esp still points to the old thread's stack, but
621  *      we are protected by a critical section so it is ok.
622  *
623  *      YYY BGL, SPL
624  */
625 ENTRY(cpu_lwkt_switch)
626         pushl   %ebp    /* note: GDB hacked to locate ebp relative to td_sp */
627         pushl   %ebx
628         movl    PCPU(curthread),%ebx
629         pushl   %esi
630         pushl   %edi
631         pushfl
632         /* warning: adjust movl into %eax below if you change the pushes */
633
634 #if NNPX > 0
635         /*
636          * Save the FP state if we have used the FP.  Note that calling
637          * npxsave will NULL out PCPU(npxthread).
638          *
639          * We have to deal with the FP state for LWKT threads in case they
640          * happen to get preempted or block while doing an optimized
641          * bzero/bcopy/memcpy.
642          */
643         cmpl    %ebx,PCPU(npxthread)
644         jne     1f
645         pushl   TD_SAVEFPU(%ebx)
646         call    npxsave                 /* do it in a big C function */
647         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
648 1:
649 #endif  /* NNPX > 0 */
650
651         movl    4+20(%esp),%eax         /* switch to this thread */
652         pushl   $cpu_lwkt_restore
653         movl    %esp,TD_SP(%ebx)
654         movl    %eax,PCPU(curthread)
655         movl    TD_SP(%eax),%esp
656
657         /*
658          * eax contains new thread, ebx contains old thread.
659          */
660         ret
661
662 /*
663  * cpu_lwkt_restore()   (current thread in %eax on entry)
664  *
665  *      Standard LWKT restore function.  This function is always called
666  *      while in a critical section.
667  *      
668  *      Warning: due to preemption the restore function can be used to 
669  *      'return' to the original thread.  Interrupt disablement must be
670  *      protected through the switch so we cannot run splz here.
671  *
672  *      YYY we theoretically do not need to load IdlePTD into cr3, but if
673  *      so we need a way to detect when the PTD we are using is being 
674  *      deleted due to a process exiting.
675  */
676 ENTRY(cpu_lwkt_restore)
677         movl    IdlePTD,%ecx    /* YYY borrow but beware desched/cpuchg/exit */
678         movl    %cr3,%edx
679         cmpl    %ecx,%edx
680         je      1f
681         movl    %ecx,%cr3
682 1:
683         /*
684          * NOTE: %ebx is the previous thread and %eax is the new thread.
685          *       %ebx is retained throughout so we can return it.
686          *
687          *       lwkt_switch[_return] is responsible for handling TDF_RUNNING.
688          */
689         movl    %ebx,%eax
690         popfl
691         popl    %edi
692         popl    %esi
693         popl    %ebx
694         popl    %ebp
695         ret
696