sys/platform/pc32/i386/swtch.s

   1 /*
   2  * Copyright (c) 2003,2004 The DragonFly Project.  All rights reserved.
   3  *
   4  * This code is derived from software contributed to The DragonFly Project
   5  * by Matthew Dillon <dillon@backplane.com>
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  *
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in
  15  *    the documentation and/or other materials provided with the
  16  *    distribution.
  17  * 3. Neither the name of The DragonFly Project nor the names of its
  18  *    contributors may be used to endorse or promote products derived
  19  *    from this software without specific, prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  22  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  23  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  24  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  25  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  26  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  27  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  28  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  29  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  30  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  31  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  * Copyright (c) 1990 The Regents of the University of California.
  35  * All rights reserved.
  36  *
  37  * This code is derived from software contributed to Berkeley by
  38  * William Jolitz.
  39  *
  40  * Redistribution and use in source and binary forms, with or without
  41  * modification, are permitted provided that the following conditions
  42  * are met:
  43  * 1. Redistributions of source code must retain the above copyright
  44  *    notice, this list of conditions and the following disclaimer.
  45  * 2. Redistributions in binary form must reproduce the above copyright
  46  *    notice, this list of conditions and the following disclaimer in the
  47  *    documentation and/or other materials provided with the distribution.
  48  * 3. All advertising materials mentioning features or use of this software
  49  *    must display the following acknowledgement:
  50  *      This product includes software developed by the University of
  51  *      California, Berkeley and its contributors.
  52  * 4. Neither the name of the University nor the names of its contributors
  53  *    may be used to endorse or promote products derived from this software
  54  *    without specific prior written permission.
  55  *
  56  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  57  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  58  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  59  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  60  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  61  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  62  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  63  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  64  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  65  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  66  * SUCH DAMAGE.
  67  *
  68  * $FreeBSD: src/sys/i386/i386/swtch.s,v 1.89.2.10 2003/01/23 03:36:24 ps Exp $
  69  * $DragonFly: src/sys/platform/pc32/i386/swtch.s,v 1.37 2005/02/21 21:40:53 dillon Exp $
  70  */
  71
  72 #include "use_npx.h"
  73
  74 #include <sys/rtprio.h>
  75
  76 #include <machine/asmacros.h>
  77 #include <machine/ipl.h>
  78
  79 #include <machine/pmap.h>
  80 #include <machine/smptests.h>           /** GRAB_LOPRIO */
  81 #include <machine/apicreg.h>
  82 #include <machine/lock.h>
  83
  84 #include "assym.s"
  85
  86 #if defined(SMP)
  87 #define MPLOCKED        lock ;
  88 #else
  89 #define MPLOCKED
  90 #endif
  91
  92         .data
  93
  94         .globl  panic
  95
  96 #if defined(SWTCH_OPTIM_STATS)
  97         .globl  swtch_optim_stats, tlb_flush_count
  98 swtch_optim_stats:      .long   0               /* number of _swtch_optims */
  99 tlb_flush_count:        .long   0
 100 #endif
 101
 102         .text
 103
 104
 105 /*
 106  * cpu_heavy_switch(next_thread)
 107  *
 108  *      Switch from the current thread to a new thread.  This entry
 109  *      is normally called via the thread->td_switch function, and will
 110  *      only be called when the current thread is a heavy weight process.
 111  *
 112  *      Some instructions have been reordered to reduce pipeline stalls.
 113  *
 114  *      YYY disable interrupts once giant is removed.
 115  */
 116 ENTRY(cpu_heavy_switch)
 117         /*
 118          * Save general regs
 119          */
 120         movl    PCPU(curthread),%ecx
 121         movl    (%esp),%eax                     /* (reorder optimization) */
 122         movl    TD_PCB(%ecx),%edx               /* EDX = PCB */
 123         movl    %eax,PCB_EIP(%edx)              /* return PC may be modified */
 124         movl    %ebx,PCB_EBX(%edx)
 125         movl    %esp,PCB_ESP(%edx)
 126         movl    %ebp,PCB_EBP(%edx)
 127         movl    %esi,PCB_ESI(%edx)
 128         movl    %edi,PCB_EDI(%edx)
 129         movl    %gs,PCB_GS(%edx)
 130
 131         movl    %ecx,%ebx                       /* EBX = curthread */
 132         movl    TD_PROC(%ecx),%ecx
 133         movl    PCPU(cpuid), %eax
 134         movl    P_VMSPACE(%ecx), %ecx           /* ECX = vmspace */
 135         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%ecx)
 136
 137         /*
 138          * Push the LWKT switch restore function, which resumes a heavy
 139          * weight process.  Note that the LWKT switcher is based on
 140          * TD_SP, while the heavy weight process switcher is based on
 141          * PCB_ESP.  TD_SP is usually two ints pushed relative to
 142          * PCB_ESP.  We push the flags for later restore by cpu_heavy_restore.
 143          */
 144         pushfl
 145         pushl   $cpu_heavy_restore
 146         movl    %esp,TD_SP(%ebx)
 147
 148         /*
 149          * Save debug regs if necessary
 150          */
 151         movb    PCB_FLAGS(%edx),%al
 152         andb    $PCB_DBREGS,%al
 153         jz      1f                              /* no, skip over */
 154         movl    %dr7,%eax                       /* yes, do the save */
 155         movl    %eax,PCB_DR7(%edx)
 156         andl    $0x0000fc00, %eax               /* disable all watchpoints */
 157         movl    %eax,%dr7
 158         movl    %dr6,%eax
 159         movl    %eax,PCB_DR6(%edx)
 160         movl    %dr3,%eax
 161         movl    %eax,PCB_DR3(%edx)
 162         movl    %dr2,%eax
 163         movl    %eax,PCB_DR2(%edx)
 164         movl    %dr1,%eax
 165         movl    %eax,PCB_DR1(%edx)
 166         movl    %dr0,%eax
 167         movl    %eax,PCB_DR0(%edx)
 168 1:
 169
 170 #if NNPX > 0
 171         /*
 172          * Save the FP state if we have used the FP.  Note that calling
 173          * npxsave will NULL out PCPU(npxthread).
 174          */
 175         cmpl    %ebx,PCPU(npxthread)
 176         jne     1f
 177         pushl   TD_SAVEFPU(%ebx)
 178         call    npxsave                 /* do it in a big C function */
 179         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 180 1:
 181 #endif  /* NNPX > 0 */
 182
 183         /*
 184          * Switch to the next thread, which was passed as an argument
 185          * to cpu_heavy_switch().  Due to the eflags and switch-restore
 186          * function we pushed, the argument is at 12(%esp).  Set the current
 187          * thread, load the stack pointer, and 'ret' into the switch-restore
 188          * function.
 189          *
 190          * The switch restore function expects the new thread to be in %eax
 191          * and the old one to be in %ebx.
 192          *
 193          * There is a one-instruction window where curthread is the new
 194          * thread but %esp still points to the old thread's stack, but
 195          * we are protected by a critical section so it is ok.
 196          */
 197         movl    12(%esp),%eax           /* EAX = newtd, EBX = oldtd */
 198         movl    %eax,PCPU(curthread)
 199         movl    TD_SP(%eax),%esp
 200         ret
 201
 202 /*
 203  *  cpu_exit_switch()
 204  *
 205  *      The switch function is changed to this when a thread is going away
 206  *      for good.  We have to ensure that the MMU state is not cached, and
 207  *      we don't bother saving the existing thread state before switching.
 208  *
 209  *      At this point we are in a critical section and this cpu owns the
 210  *      thread's token, which serves as an interlock until the switchout is
 211  *      complete.
 212  */
 213 ENTRY(cpu_exit_switch)
 214         /*
 215          * Get us out of the vmspace
 216          */
 217         movl    IdlePTD,%ecx
 218         movl    %cr3,%eax
 219         cmpl    %ecx,%eax
 220         je      1f
 221         movl    %ecx,%cr3
 222 1:
 223         movl    PCPU(curthread),%ebx
 224         /*
 225          * Switch to the next thread.  RET into the restore function, which
 226          * expects the new thread in EAX and the old in EBX.
 227          *
 228          * There is a one-instruction window where curthread is the new
 229          * thread but %esp still points to the old thread's stack, but
 230          * we are protected by a critical section so it is ok.
 231          */
 232         movl    4(%esp),%eax
 233         movl    %eax,PCPU(curthread)
 234         movl    TD_SP(%eax),%esp
 235         ret
 236
 237 /*
 238  * cpu_heavy_restore()  (current thread in %eax on entry)
 239  *
 240  *      Restore the thread after an LWKT switch.  This entry is normally
 241  *      called via the LWKT switch restore function, which was pulled
 242  *      off the thread stack and jumped to.
 243  *
 244  *      This entry is only called if the thread was previously saved
 245  *      using cpu_heavy_switch() (the heavy weight process thread switcher),
 246  *      or when a new process is initially scheduled.  The first thing we
 247  *      do is clear the TDF_RUNNING bit in the old thread and set it in the
 248  *      new thread.
 249  *
 250  *      NOTE: The process may be in any state, not necessarily SRUN, because
 251  *      a preemption switch may interrupt the process and then return via
 252  *      cpu_heavy_restore.
 253  *
 254  *      YYY theoretically we do not have to restore everything here, a lot
 255  *      of this junk can wait until we return to usermode.  But for now
 256  *      we restore everything.
 257  *
 258  *      YYY the PCB crap is really crap, it makes startup a bitch because
 259  *      we can't switch away.
 260  *
 261  *      YYY note: spl check is done in mi_switch when it splx()'s.
 262  */
 263
 264 ENTRY(cpu_heavy_restore)
 265         popfl
 266         movl    TD_PCB(%eax),%edx               /* EDX = PCB */
 267         movl    TD_PROC(%eax),%ecx
 268
 269 #if defined(SWTCH_OPTIM_STATS)
 270         incl    _swtch_optim_stats
 271 #endif
 272         /*
 273          * Tell the pmap that our cpu is using the VMSPACE now.  We cannot
 274          * safely test/reload %cr3 until after we have set the bit in the
 275          * pmap (remember, we do not hold the MP lock in the switch code).
 276          */
 277         movl    P_VMSPACE(%ecx), %ecx           /* ECX = vmspace */
 278         movl    PCPU(cpuid), %esi
 279         MPLOCKED btsl   %esi, VM_PMAP+PM_ACTIVE(%ecx)
 280
 281         /*
 282          * Restore the MMU address space.  If it is the same as the last
 283          * thread we don't have to invalidate the tlb (i.e. reload cr3).
 284          * YYY which naturally also means that the PM_ACTIVE bit had better
 285          * already have been set before we set it above, check? YYY
 286          */
 287         movl    %cr3,%esi
 288         movl    PCB_CR3(%edx),%ecx
 289         cmpl    %esi,%ecx
 290         je      4f
 291 #if defined(SWTCH_OPTIM_STATS)
 292         decl    _swtch_optim_stats
 293         incl    _tlb_flush_count
 294 #endif
 295         movl    %ecx,%cr3
 296 4:
 297         /*
 298          * Clear TDF_RUNNING flag in old thread only after cleaning up
 299          * %cr3.  The target thread is already protected by being TDF_RUNQ
 300          * so setting TDF_RUNNING isn't as big a deal.
 301          */
 302         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 303         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 304
 305         /*
 306          * Deal with the PCB extension, restore the private tss
 307          */
 308         movl    PCB_EXT(%edx),%edi      /* check for a PCB extension */
 309         movl    $1,%ebx                 /* maybe mark use of a private tss */
 310         testl   %edi,%edi
 311         jnz     2f
 312
 313         /*
 314          * Going back to the common_tss.  We may need to update TSS_ESP0
 315          * which sets the top of the supervisor stack when entering from
 316          * usermode.  The PCB is at the top of the stack but we need another
 317          * 16 bytes to take vm86 into account.
 318          */
 319         leal    -16(%edx),%ebx
 320         movl    %ebx, PCPU(common_tss) + TSS_ESP0
 321
 322         cmpl    $0,PCPU(private_tss)    /* don't have to reload if      */
 323         je      3f                      /* already using the common TSS */
 324
 325         subl    %ebx,%ebx               /* unmark use of private tss */
 326
 327         /*
 328          * Get the address of the common TSS descriptor for the ltr.
 329          * There is no way to get the address of a segment-accessed variable
 330          * so we store a self-referential pointer at the base of the per-cpu
 331          * data area and add the appropriate offset.
 332          */
 333         movl    $gd_common_tssd, %edi
 334         addl    %fs:0, %edi
 335
 336         /*
 337          * Move the correct TSS descriptor into the GDT slot, then reload
 338          * ltr.
 339          */
 340 2:
 341         movl    %ebx,PCPU(private_tss)          /* mark/unmark private tss */
 342         movl    PCPU(tss_gdt), %ebx             /* entry in GDT */
 343         movl    0(%edi), %eax
 344         movl    %eax, 0(%ebx)
 345         movl    4(%edi), %eax
 346         movl    %eax, 4(%ebx)
 347         movl    $GPROC0_SEL*8, %esi             /* GSEL(entry, SEL_KPL) */
 348         ltr     %si
 349
 350 3:
 351         /*
 352          * Restore general registers.
 353          */
 354         movl    PCB_EBX(%edx),%ebx
 355         movl    PCB_ESP(%edx),%esp
 356         movl    PCB_EBP(%edx),%ebp
 357         movl    PCB_ESI(%edx),%esi
 358         movl    PCB_EDI(%edx),%edi
 359         movl    PCB_EIP(%edx),%eax
 360         movl    %eax,(%esp)
 361
 362         /*
 363          * Restore the user LDT if we have one
 364          */
 365         cmpl    $0, PCB_USERLDT(%edx)
 366         jnz     1f
 367         movl    _default_ldt,%eax
 368         cmpl    PCPU(currentldt),%eax
 369         je      2f
 370         lldt    _default_ldt
 371         movl    %eax,PCPU(currentldt)
 372         jmp     2f
 373 1:      pushl   %edx
 374         call    set_user_ldt
 375         popl    %edx
 376 2:
 377         /*
 378          * Restore the user TLS if we have one
 379          */
 380         pushl   %edx
 381         call    set_user_TLS
 382         popl    %edx
 383         /*
 384          * Restore the %gs segment register, which must be done after
 385          * loading the user LDT.  Since user processes can modify the
 386          * register via procfs, this may result in a fault which is
 387          * detected by checking the fault address against cpu_switch_load_gs
 388          * in i386/i386/trap.c
 389          */
 390         .globl  cpu_switch_load_gs
 391 cpu_switch_load_gs:
 392         movl    PCB_GS(%edx),%gs
 393
 394         /*
 395          * Restore the DEBUG register state if necessary.
 396          */
 397         movb    PCB_FLAGS(%edx),%al
 398         andb    $PCB_DBREGS,%al
 399         jz      1f                              /* no, skip over */
 400         movl    PCB_DR6(%edx),%eax              /* yes, do the restore */
 401         movl    %eax,%dr6
 402         movl    PCB_DR3(%edx),%eax
 403         movl    %eax,%dr3
 404         movl    PCB_DR2(%edx),%eax
 405         movl    %eax,%dr2
 406         movl    PCB_DR1(%edx),%eax
 407         movl    %eax,%dr1
 408         movl    PCB_DR0(%edx),%eax
 409         movl    %eax,%dr0
 410         movl    %dr7,%eax                /* load dr7 so as not to disturb */
 411         andl    $0x0000fc00,%eax         /*   reserved bits               */
 412         pushl   %ebx
 413         movl    PCB_DR7(%edx),%ebx
 414         andl    $~0x0000fc00,%ebx
 415         orl     %ebx,%eax
 416         popl    %ebx
 417         movl    %eax,%dr7
 418 1:
 419
 420         ret
 421
 422 /*
 423  * savectx(pcb)
 424  *
 425  * Update pcb, saving current processor state.
 426  */
 427 ENTRY(savectx)
 428         /* fetch PCB */
 429         movl    4(%esp),%ecx
 430
 431         /* caller's return address - child won't execute this routine */
 432         movl    (%esp),%eax
 433         movl    %eax,PCB_EIP(%ecx)
 434
 435         movl    %cr3,%eax
 436         movl    %eax,PCB_CR3(%ecx)
 437
 438         movl    %ebx,PCB_EBX(%ecx)
 439         movl    %esp,PCB_ESP(%ecx)
 440         movl    %ebp,PCB_EBP(%ecx)
 441         movl    %esi,PCB_ESI(%ecx)
 442         movl    %edi,PCB_EDI(%ecx)
 443         movl    %gs,PCB_GS(%ecx)
 444
 445 #if NNPX > 0
 446         /*
 447          * If npxthread == NULL, then the npx h/w state is irrelevant and the
 448          * state had better already be in the pcb.  This is true for forks
 449          * but not for dumps (the old book-keeping with FP flags in the pcb
 450          * always lost for dumps because the dump pcb has 0 flags).
 451          *
 452          * If npxthread != NULL, then we have to save the npx h/w state to
 453          * npxthread's pcb and copy it to the requested pcb, or save to the
 454          * requested pcb and reload.  Copying is easier because we would
 455          * have to handle h/w bugs for reloading.  We used to lose the
 456          * parent's npx state for forks by forgetting to reload.
 457          */
 458         movl    PCPU(npxthread),%eax
 459         testl   %eax,%eax
 460         je      1f
 461
 462         pushl   %ecx                    /* target pcb */
 463         movl    TD_SAVEFPU(%eax),%eax   /* originating savefpu area */
 464         pushl   %eax
 465
 466         pushl   %eax
 467         call    npxsave
 468         addl    $4,%esp
 469
 470         popl    %eax
 471         popl    %ecx
 472
 473         pushl   $PCB_SAVEFPU_SIZE
 474         leal    PCB_SAVEFPU(%ecx),%ecx
 475         pushl   %ecx
 476         pushl   %eax
 477         call    bcopy
 478         addl    $12,%esp
 479 #endif  /* NNPX > 0 */
 480
 481 1:
 482         ret
 483
 484 /*
 485  * cpu_idle_restore()   (current thread in %eax on entry) (one-time execution)
 486  *
 487  *      Don't bother setting up any regs other then %ebp so backtraces
 488  *      don't die.  This restore function is used to bootstrap into the
 489  *      cpu_idle() LWKT only, after that cpu_lwkt_*() will be used for
 490  *      switching.
 491  *
 492  *      Clear TDF_RUNNING in old thread only after we've cleaned up %cr3.
 493  *
 494  *      If we are an AP we have to call ap_init() before jumping to
 495  *      cpu_idle().  ap_init() will synchronize with the BP and finish
 496  *      setting up various ncpu-dependant globaldata fields.  This may
 497  *      happen on UP as well as SMP if we happen to be simulating multiple
 498  *      cpus.
 499  */
 500 ENTRY(cpu_idle_restore)
 501         /* cli */
 502         movl    IdlePTD,%ecx
 503         movl    $0,%ebp
 504         pushl   $0
 505         movl    %ecx,%cr3
 506         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 507         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 508 #ifdef SMP
 509         cmpl    $0,PCPU(cpuid)
 510         je      1f
 511         call    ap_init
 512 1:
 513 #endif
 514         sti
 515         jmp     cpu_idle
 516
 517 /*
 518  * cpu_kthread_restore() (current thread is %eax on entry) (one-time execution)
 519  *
 520  *      Don't bother setting up any regs other then %ebp so backtraces
 521  *      don't die.  This restore function is used to bootstrap into an
 522  *      LWKT based kernel thread only.  cpu_lwkt_switch() will be used
 523  *      after this.
 524  *
 525  *      Since all of our context is on the stack we are reentrant and
 526  *      we can release our critical section and enable interrupts early.
 527  */
 528 ENTRY(cpu_kthread_restore)
 529         sti
 530         movl    IdlePTD,%ecx
 531         movl    TD_PCB(%eax),%edx
 532         movl    $0,%ebp
 533         movl    %ecx,%cr3
 534         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 535         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 536         subl    $TDPRI_CRIT,TD_PRI(%eax)
 537         popl    %eax            /* kthread exit function */
 538         pushl   PCB_EBX(%edx)   /* argument to ESI function */
 539         pushl   %eax            /* set exit func as return address */
 540         movl    PCB_ESI(%edx),%eax
 541         jmp     *%eax
 542
 543 /*
 544  * cpu_lwkt_switch()
 545  *
 546  *      Standard LWKT switching function.  Only non-scratch registers are
 547  *      saved and we don't bother with the MMU state or anything else.
 548  *
 549  *      This function is always called while in a critical section.
 550  *
 551  *      There is a one-instruction window where curthread is the new
 552  *      thread but %esp still points to the old thread's stack, but
 553  *      we are protected by a critical section so it is ok.
 554  *
 555  *      YYY BGL, SPL
 556  */
 557 ENTRY(cpu_lwkt_switch)
 558         pushl   %ebp    /* note: GDB hacked to locate ebp relative to td_sp */
 559         pushl   %ebx
 560         movl    PCPU(curthread),%ebx
 561         pushl   %esi
 562         pushl   %edi
 563         pushfl
 564         /* warning: adjust movl into %eax below if you change the pushes */
 565
 566 #if NNPX > 0
 567         /*
 568          * Save the FP state if we have used the FP.  Note that calling
 569          * npxsave will NULL out PCPU(npxthread).
 570          *
 571          * We have to deal with the FP state for LWKT threads in case they
 572          * happen to get preempted or block while doing an optimized
 573          * bzero/bcopy/memcpy.
 574          */
 575         cmpl    %ebx,PCPU(npxthread)
 576         jne     1f
 577         pushl   TD_SAVEFPU(%ebx)
 578         call    npxsave                 /* do it in a big C function */
 579         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 580 1:
 581 #endif  /* NNPX > 0 */
 582
 583         movl    4+20(%esp),%eax         /* switch to this thread */
 584         pushl   $cpu_lwkt_restore
 585         movl    %esp,TD_SP(%ebx)
 586         movl    %eax,PCPU(curthread)
 587         movl    TD_SP(%eax),%esp
 588
 589         /*
 590          * eax contains new thread, ebx contains old thread.
 591          */
 592         ret
 593
 594 /*
 595  * cpu_lwkt_restore()   (current thread in %eax on entry)
 596  *
 597  *      Standard LWKT restore function.  This function is always called
 598  *      while in a critical section.
 599  *
 600  *      Warning: due to preemption the restore function can be used to
 601  *      'return' to the original thread.  Interrupt disablement must be
 602  *      protected through the switch so we cannot run splz here.
 603  *
 604  *      YYY we theoretically do not need to load IdlePTD into cr3, but if
 605  *      so we need a way to detect when the PTD we are using is being
 606  *      deleted due to a process exiting.
 607  */
 608 ENTRY(cpu_lwkt_restore)
 609         movl    IdlePTD,%ecx    /* YYY borrow but beware desched/cpuchg/exit */
 610         movl    %cr3,%edx
 611         cmpl    %ecx,%edx
 612         je      1f
 613         movl    %ecx,%cr3
 614 1:
 615         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 616         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 617         popfl
 618         popl    %edi
 619         popl    %esi
 620         popl    %ebx
 621         popl    %ebp
 622         ret
 623