contrib/groff/font/devps/generate/symbol.sed

   1 #! /bin/sed -f
   2 # Set up uniform vertical dimensions for extensible glyphs (needed by eqn).
   3 /^C .*[ ;]N bracketlefttp[ ;]/bx
   4 /^C .*[ ;]N bracketleftex[ ;]/bx
   5 /^C .*[ ;]N bracketleftbt[ ;]/bx
   6 /^C .*[ ;]N bracketrighttp[ ;]/bx
   7 /^C .*[ ;]N bracketrightex[ ;]/bx
   8 /^C .*[ ;]N bracketrightbt[ ;]/bx
   9 /^C .*[ ;]N bracelefttp[ ;]/bx
  10 /^C .*[ ;]N braceleftmid[ ;]/bx
  11 /^C .*[ ;]N braceleftbt[ ;]/bx
  12 /^C .*[ ;]N bracerighttp[ ;]/bx
  13 /^C .*[ ;]N bracerightmid[ ;]/bx
  14 /^C .*[ ;]N bracerightbt[ ;]/bx
  15 /^C .*[ ;]N braceex[ ;]/bx
  16 /^C .*[ ;]N parenleftex[ ;]/by
  17 /^C .*[ ;]N parenrightex[ ;]/by
  18 /^C .*[ ;]N parenleftbt[ ;]/bz
  19 /^C .*[ ;]N parenrightbt[ ;]/bz
  20 /^EndCharMetrics/a\
  21 italicCorrection integral 67\
  22 leftItalicCorrection integral 52\
  23 subscriptCorrection integral -10
  24 b
  25 :x
  26 s/B \([-0-9][0-9]*\) [-0-9][0-9]* \([-0-9][0-9]*\) [-0-9][0-9]*/B \1 -75 \2 925/
  27 b
  28 :y
  29 s/B \([-0-9][0-9]*\) [-0-9][0-9]* \([-0-9][0-9]*\) [-0-9][0-9]*/B \1 -80 \2 920/
  30 b
  31 :z
  32 s/B \([-0-9][0-9]*\) \([-0-9][0-9]*\) \([-0-9][0-9]*\) [-0-9][0-9]*/B \1 \2 \3 920/
  33 b