48a0eae684e753cb7b346dff603f439e5dccac98
[dragonfly.git] / sys / platform / pc64 / x86_64 / swtch.s
1 /*
2  * Copyright (c) 2003,2004,2008 The DragonFly Project.  All rights reserved.
3  * Copyright (c) 2008 Jordan Gordeev.
4  * 
5  * This code is derived from software contributed to The DragonFly Project
6  * by Matthew Dillon <dillon@backplane.com>
7  * 
8  * Redistribution and use in source and binary forms, with or without
9  * modification, are permitted provided that the following conditions
10  * are met:
11  * 
12  * 1. Redistributions of source code must retain the above copyright
13  *    notice, this list of conditions and the following disclaimer.
14  * 2. Redistributions in binary form must reproduce the above copyright
15  *    notice, this list of conditions and the following disclaimer in
16  *    the documentation and/or other materials provided with the
17  *    distribution.
18  * 3. Neither the name of The DragonFly Project nor the names of its
19  *    contributors may be used to endorse or promote products derived
20  *    from this software without specific, prior written permission.
21  * 
22  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
23  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
24  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
25  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
26  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
27  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
28  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
29  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
30  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
31  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
32  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
33  * SUCH DAMAGE.
34  * 
35  * Copyright (c) 1990 The Regents of the University of California.
36  * All rights reserved.
37  *
38  * This code is derived from software contributed to Berkeley by
39  * William Jolitz.
40  *
41  * Redistribution and use in source and binary forms, with or without
42  * modification, are permitted provided that the following conditions
43  * are met:
44  * 1. Redistributions of source code must retain the above copyright
45  *    notice, this list of conditions and the following disclaimer.
46  * 2. Redistributions in binary form must reproduce the above copyright
47  *    notice, this list of conditions and the following disclaimer in the
48  *    documentation and/or other materials provided with the distribution.
49  * 3. All advertising materials mentioning features or use of this software
50  *    must display the following acknowledgement:
51  *      This product includes software developed by the University of
52  *      California, Berkeley and its contributors.
53  * 4. Neither the name of the University nor the names of its contributors
54  *    may be used to endorse or promote products derived from this software
55  *    without specific prior written permission.
56  *
57  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
58  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
59  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
60  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
61  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
62  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
63  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
64  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
65  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
66  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
67  * SUCH DAMAGE.
68  *
69  * $FreeBSD: src/sys/i386/i386/swtch.s,v 1.89.2.10 2003/01/23 03:36:24 ps Exp $
70  */
71
72 //#include "use_npx.h"
73
74 #include <sys/rtprio.h>
75
76 #include <machine/asmacros.h>
77 #include <machine/segments.h>
78
79 #include <machine/pmap.h>
80 #if JG
81 #include <machine_base/apic/apicreg.h>
82 #endif
83 #include <machine/lock.h>
84
85 #include "assym.s"
86
87 #if defined(SMP)
88 #define MPLOCKED        lock ;
89 #else
90 #define MPLOCKED
91 #endif
92
93         .data
94
95         .globl  panic
96         .globl  lwkt_switch_return
97
98 #if defined(SWTCH_OPTIM_STATS)
99         .globl  swtch_optim_stats, tlb_flush_count
100 swtch_optim_stats:      .long   0               /* number of _swtch_optims */
101 tlb_flush_count:        .long   0
102 #endif
103
104         .text
105
106
107 /*
108  * cpu_heavy_switch(struct thread *next_thread)
109  *
110  *      Switch from the current thread to a new thread.  This entry
111  *      is normally called via the thread->td_switch function, and will
112  *      only be called when the current thread is a heavy weight process.
113  *
114  *      Some instructions have been reordered to reduce pipeline stalls.
115  *
116  *      YYY disable interrupts once giant is removed.
117  */
118 ENTRY(cpu_heavy_switch)
119         /*
120          * Save RIP, RSP and callee-saved registers (RBX, RBP, R12-R15).
121          */
122         movq    PCPU(curthread),%rcx
123         /* On top of the stack is the return adress. */
124         movq    (%rsp),%rax                     /* (reorder optimization) */
125         movq    TD_PCB(%rcx),%rdx               /* RDX = PCB */
126         movq    %rax,PCB_RIP(%rdx)              /* return PC may be modified */
127         movq    %rbx,PCB_RBX(%rdx)
128         movq    %rsp,PCB_RSP(%rdx)
129         movq    %rbp,PCB_RBP(%rdx)
130         movq    %r12,PCB_R12(%rdx)
131         movq    %r13,PCB_R13(%rdx)
132         movq    %r14,PCB_R14(%rdx)
133         movq    %r15,PCB_R15(%rdx)
134
135         /*
136          * Clear the cpu bit in the pmap active mask.  The restore
137          * function will set the bit in the pmap active mask.
138          *
139          * Special case: when switching between threads sharing the
140          * same vmspace if we avoid clearing the bit we do not have
141          * to reload %cr3 (if we clear the bit we could race page
142          * table ops done by other threads and would have to reload
143          * %cr3, because those ops will not know to IPI us).
144          */
145         movq    %rcx,%rbx                       /* RBX = oldthread */
146         movq    TD_LWP(%rcx),%rcx               /* RCX = oldlwp */
147         movq    TD_LWP(%rdi),%r13               /* R13 = newlwp */
148         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = oldvmspace */
149         testq   %r13,%r13                       /* might not be a heavy */
150         jz      1f
151         cmpq    LWP_VMSPACE(%r13),%rcx          /* same vmspace? */
152         je      2f
153 1:
154         movslq  PCPU(cpuid), %rax
155         MPLOCKED btrq   %rax, VM_PMAP+PM_ACTIVE(%rcx)
156 2:
157
158         /*
159          * Push the LWKT switch restore function, which resumes a heavy
160          * weight process.  Note that the LWKT switcher is based on
161          * TD_SP, while the heavy weight process switcher is based on
162          * PCB_RSP.  TD_SP is usually two ints pushed relative to
163          * PCB_RSP.  We push the flags for later restore by cpu_heavy_restore.
164          */
165         pushfq
166         movq    $cpu_heavy_restore, %rax
167         pushq   %rax
168         movq    %rsp,TD_SP(%rbx)
169
170         /*
171          * Save debug regs if necessary
172          */
173         movq    PCB_FLAGS(%rdx),%rax
174         andq    $PCB_DBREGS,%rax
175         jz      1f                              /* no, skip over */
176         movq    %dr7,%rax                       /* yes, do the save */
177         movq    %rax,PCB_DR7(%rdx)
178         /* JG correct value? */
179         andq    $0x0000fc00, %rax               /* disable all watchpoints */
180         movq    %rax,%dr7
181         movq    %dr6,%rax
182         movq    %rax,PCB_DR6(%rdx)
183         movq    %dr3,%rax
184         movq    %rax,PCB_DR3(%rdx)
185         movq    %dr2,%rax
186         movq    %rax,PCB_DR2(%rdx)
187         movq    %dr1,%rax
188         movq    %rax,PCB_DR1(%rdx)
189         movq    %dr0,%rax
190         movq    %rax,PCB_DR0(%rdx)
191 1:
192  
193 #if 1
194         /*
195          * Save the FP state if we have used the FP.  Note that calling
196          * npxsave will NULL out PCPU(npxthread).
197          */
198         cmpq    %rbx,PCPU(npxthread)
199         jne     1f
200         movq    %rdi,%r12               /* save %rdi. %r12 is callee-saved */
201         movq    TD_SAVEFPU(%rbx),%rdi
202         call    npxsave                 /* do it in a big C function */
203         movq    %r12,%rdi               /* restore %rdi */
204 1:
205 #endif
206
207         /*
208          * Switch to the next thread, which was passed as an argument
209          * to cpu_heavy_switch().  The argument is in %rdi.
210          * Set the current thread, load the stack pointer,
211          * and 'ret' into the switch-restore function.
212          *
213          * The switch restore function expects the new thread to be in %rax
214          * and the old one to be in %rbx.
215          *
216          * There is a one-instruction window where curthread is the new
217          * thread but %rsp still points to the old thread's stack, but
218          * we are protected by a critical section so it is ok.
219          */
220         movq    %rdi,%rax               /* RAX = newtd, RBX = oldtd */
221         movq    %rax,PCPU(curthread)
222         movq    TD_SP(%rax),%rsp
223         ret
224
225 /*
226  *  cpu_exit_switch(struct thread *next)
227  *
228  *      The switch function is changed to this when a thread is going away
229  *      for good.  We have to ensure that the MMU state is not cached, and
230  *      we don't bother saving the existing thread state before switching.
231  *
232  *      At this point we are in a critical section and this cpu owns the
233  *      thread's token, which serves as an interlock until the switchout is
234  *      complete.
235  */
236 ENTRY(cpu_exit_switch)
237         /*
238          * Get us out of the vmspace
239          */
240         movq    KPML4phys,%rcx
241         movq    %cr3,%rax
242 #if 1
243         cmpq    %rcx,%rax
244         je      1f
245 #endif
246         /* JG no increment of statistics counters? see cpu_heavy_restore */
247         movq    %rcx,%cr3
248 1:
249         movq    PCPU(curthread),%rbx
250
251         /*
252          * If this is a process/lwp, deactivate the pmap after we've
253          * switched it out.
254          */
255         movq    TD_LWP(%rbx),%rcx
256         testq   %rcx,%rcx
257         jz      2f
258         movslq  PCPU(cpuid), %rax
259         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
260         MPLOCKED btrq   %rax, VM_PMAP+PM_ACTIVE(%rcx)
261 2:
262         /*
263          * Switch to the next thread.  RET into the restore function, which
264          * expects the new thread in RAX and the old in RBX.
265          *
266          * There is a one-instruction window where curthread is the new
267          * thread but %rsp still points to the old thread's stack, but
268          * we are protected by a critical section so it is ok.
269          */
270         movq    %rdi,%rax
271         movq    %rax,PCPU(curthread)
272         movq    TD_SP(%rax),%rsp
273         ret
274
275 /*
276  * cpu_heavy_restore()  (current thread in %rax on entry, old thread in %rbx)
277  *
278  *      Restore the thread after an LWKT switch.  This entry is normally
279  *      called via the LWKT switch restore function, which was pulled 
280  *      off the thread stack and jumped to.
281  *
282  *      This entry is only called if the thread was previously saved
283  *      using cpu_heavy_switch() (the heavy weight process thread switcher),
284  *      or when a new process is initially scheduled.
285  *
286  *      NOTE: The lwp may be in any state, not necessarily LSRUN, because
287  *      a preemption switch may interrupt the process and then return via 
288  *      cpu_heavy_restore.
289  *
290  *      YYY theoretically we do not have to restore everything here, a lot
291  *      of this junk can wait until we return to usermode.  But for now
292  *      we restore everything.
293  *
294  *      YYY the PCB crap is really crap, it makes startup a bitch because
295  *      we can't switch away.
296  *
297  *      YYY note: spl check is done in mi_switch when it splx()'s.
298  */
299
300 ENTRY(cpu_heavy_restore)
301         popfq
302
303 #if defined(SWTCH_OPTIM_STATS)
304         incl    _swtch_optim_stats
305 #endif
306         /*
307          * Tell the pmap that our cpu is using the VMSPACE now.  We cannot
308          * safely test/reload %cr3 until after we have set the bit in the
309          * pmap.
310          *
311          * We must do an interlocked test of the CPUMASK_BIT at the same
312          * time.  If found to be set we will have to wait for it to clear
313          * and then do a forced reload of %cr3 (even if the value matches).
314          *
315          * XXX When switching between two LWPs sharing the same vmspace
316          *     the cpu_heavy_switch() code currently avoids clearing the
317          *     cpu bit in PM_ACTIVE.  So if the bit is already set we can
318          *     avoid checking for the interlock via CPUMASK_BIT.  We currently
319          *     do not perform this optimization.
320          *
321          * %rax is needed for the cmpxchgl so store newthread in %r12
322          * temporarily.
323          */
324         movq    TD_LWP(%rax),%rcx
325         movq    LWP_VMSPACE(%rcx),%rcx          /* RCX = vmspace */
326 #ifdef SMP
327         movq    %rax,%r12                       /* save newthread ptr */
328 1:
329         movq    VM_PMAP+PM_ACTIVE(%rcx),%rax    /* old contents */
330         movq    PCPU(cpumask),%rsi              /* new contents */
331         orq     %rax,%rsi
332         MPLOCKED cmpxchgq %rsi,VM_PMAP+PM_ACTIVE(%rcx)
333         jnz     1b
334
335         /*
336          * Check CPUMASK_BIT
337          */
338         btq     $CPUMASK_BIT,%rax       /* test interlock */
339         jnc     1f
340         movq    %rcx,%rdi               /* (found to be set) */
341         call    pmap_interlock_wait     /* pmap_interlock_wait(%rdi:vm) */
342
343         /*
344          * Need unconditional load cr3
345          */
346         movq    %r12,%rax
347         movq    TD_PCB(%rax),%rdx       /* RDX = PCB */
348         movq    PCB_CR3(%rdx),%rcx      /* RCX = desired CR3 */
349         jmp     2f                      /* unconditional reload */
350 1:
351         movq    %r12,%rax               /* restore RAX = newthread */
352 #else
353         movq    PCPU(cpumask),%rsi
354         orq     %rsi,VM_PMAP+PM_ACTIVE(%rcx)
355 #endif
356         /*
357          * Restore the MMU address space.  If it is the same as the last
358          * thread we don't have to invalidate the tlb (i.e. reload cr3).
359          * YYY which naturally also means that the PM_ACTIVE bit had better
360          * already have been set before we set it above, check? YYY
361          */
362         movq    TD_PCB(%rax),%rdx               /* RDX = PCB */
363         movq    %cr3,%rsi                       /* RSI = current CR3 */
364         movq    PCB_CR3(%rdx),%rcx              /* RCX = desired CR3 */
365         cmpq    %rsi,%rcx
366         je      4f
367 2:
368 #if defined(SWTCH_OPTIM_STATS)
369         decl    _swtch_optim_stats
370         incl    _tlb_flush_count
371 #endif
372         movq    %rcx,%cr3
373 4:
374
375         /*
376          * NOTE: %rbx is the previous thread and %rax is the new thread.
377          *       %rbx is retained throughout so we can return it.
378          *
379          *       lwkt_switch[_return] is responsible for handling TDF_RUNNING.
380          */
381
382         /*
383          * Deal with the PCB extension, restore the private tss
384          */
385         movq    PCB_EXT(%rdx),%rdi      /* check for a PCB extension */
386         movq    $1,%rcx                 /* maybe mark use of a private tss */
387         testq   %rdi,%rdi
388 #if JG
389         jnz     2f
390 #endif
391
392         /*
393          * Going back to the common_tss.  We may need to update TSS_RSP0
394          * which sets the top of the supervisor stack when entering from
395          * usermode.  The PCB is at the top of the stack but we need another
396          * 16 bytes to take vm86 into account.
397          */
398         movq    %rdx,%rcx
399         /*leaq  -TF_SIZE(%rdx),%rcx*/
400         movq    %rcx, PCPU(common_tss) + TSS_RSP0
401
402 #if JG
403         cmpl    $0,PCPU(private_tss)    /* don't have to reload if      */
404         je      3f                      /* already using the common TSS */
405
406         /* JG? */
407         subq    %rcx,%rcx               /* unmark use of private tss */
408
409         /*
410          * Get the address of the common TSS descriptor for the ltr.
411          * There is no way to get the address of a segment-accessed variable
412          * so we store a self-referential pointer at the base of the per-cpu
413          * data area and add the appropriate offset.
414          */
415         /* JG movl? */
416         movq    $gd_common_tssd, %rdi
417         /* JG name for "%gs:0"? */
418         addq    %gs:0, %rdi
419
420         /*
421          * Move the correct TSS descriptor into the GDT slot, then reload
422          * ltr.
423          */
424 2:
425         /* JG */
426         movl    %rcx,PCPU(private_tss)          /* mark/unmark private tss */
427         movq    PCPU(tss_gdt), %rbx             /* entry in GDT */
428         movq    0(%rdi), %rax
429         movq    %rax, 0(%rbx)
430         movl    $GPROC0_SEL*8, %esi             /* GSEL(entry, SEL_KPL) */
431         ltr     %si
432 #endif
433
434 3:
435         /*
436          * Restore the user %gs and %fs
437          */
438         movq    PCB_FSBASE(%rdx),%r9
439         cmpq    PCPU(user_fs),%r9
440         je      4f
441         movq    %rdx,%r10
442         movq    %r9,PCPU(user_fs)
443         movl    $MSR_FSBASE,%ecx
444         movl    PCB_FSBASE(%r10),%eax
445         movl    PCB_FSBASE+4(%r10),%edx
446         wrmsr
447         movq    %r10,%rdx
448 4:
449         movq    PCB_GSBASE(%rdx),%r9
450         cmpq    PCPU(user_gs),%r9
451         je      5f
452         movq    %rdx,%r10
453         movq    %r9,PCPU(user_gs)
454         movl    $MSR_KGSBASE,%ecx       /* later swapgs moves it to GSBASE */
455         movl    PCB_GSBASE(%r10),%eax
456         movl    PCB_GSBASE+4(%r10),%edx
457         wrmsr
458         movq    %r10,%rdx
459 5:
460
461         /*
462          * Restore general registers.  %rbx is restored later.
463          */
464         movq    PCB_RSP(%rdx), %rsp
465         movq    PCB_RBP(%rdx), %rbp
466         movq    PCB_R12(%rdx), %r12
467         movq    PCB_R13(%rdx), %r13
468         movq    PCB_R14(%rdx), %r14
469         movq    PCB_R15(%rdx), %r15
470         movq    PCB_RIP(%rdx), %rax
471         movq    %rax, (%rsp)
472
473 #if JG
474         /*
475          * Restore the user LDT if we have one
476          */
477         cmpl    $0, PCB_USERLDT(%edx)
478         jnz     1f
479         movl    _default_ldt,%eax
480         cmpl    PCPU(currentldt),%eax
481         je      2f
482         lldt    _default_ldt
483         movl    %eax,PCPU(currentldt)
484         jmp     2f
485 1:      pushl   %edx
486         call    set_user_ldt
487         popl    %edx
488 2:
489 #endif
490 #if JG
491         /*
492          * Restore the user TLS if we have one
493          */
494         pushl   %edx
495         call    set_user_TLS
496         popl    %edx
497 #endif
498
499         /*
500          * Restore the DEBUG register state if necessary.
501          */
502         movq    PCB_FLAGS(%rdx),%rax
503         andq    $PCB_DBREGS,%rax
504         jz      1f                              /* no, skip over */
505         movq    PCB_DR6(%rdx),%rax              /* yes, do the restore */
506         movq    %rax,%dr6
507         movq    PCB_DR3(%rdx),%rax
508         movq    %rax,%dr3
509         movq    PCB_DR2(%rdx),%rax
510         movq    %rax,%dr2
511         movq    PCB_DR1(%rdx),%rax
512         movq    %rax,%dr1
513         movq    PCB_DR0(%rdx),%rax
514         movq    %rax,%dr0
515         movq    %dr7,%rax                /* load dr7 so as not to disturb */
516         /* JG correct value? */
517         andq    $0x0000fc00,%rax         /*   reserved bits               */
518         /* JG we've got more registers on x86_64 */
519         movq    PCB_DR7(%rdx),%rcx
520         /* JG correct value? */
521         andq    $~0x0000fc00,%rcx
522         orq     %rcx,%rax
523         movq    %rax,%dr7
524
525         /*
526          * Clear the QUICKRET flag when restoring a user process context
527          * so we don't try to do a quick syscall return.
528          */
529 1:
530         andl    $~RQF_QUICKRET,PCPU(reqflags)
531         movq    %rbx,%rax
532         movq    PCB_RBX(%rdx),%rbx
533         ret
534
535 /*
536  * savectx(struct pcb *pcb)
537  *
538  * Update pcb, saving current processor state.
539  */
540 ENTRY(savectx)
541         /* fetch PCB */
542         /* JG use %rdi instead of %rcx everywhere? */
543         movq    %rdi,%rcx
544
545         /* caller's return address - child won't execute this routine */
546         movq    (%rsp),%rax
547         movq    %rax,PCB_RIP(%rcx)
548
549         movq    %cr3,%rax
550         movq    %rax,PCB_CR3(%rcx)
551
552         movq    %rbx,PCB_RBX(%rcx)
553         movq    %rsp,PCB_RSP(%rcx)
554         movq    %rbp,PCB_RBP(%rcx)
555         movq    %r12,PCB_R12(%rcx)
556         movq    %r13,PCB_R13(%rcx)
557         movq    %r14,PCB_R14(%rcx)
558         movq    %r15,PCB_R15(%rcx)
559
560 #if 1
561         /*
562          * If npxthread == NULL, then the npx h/w state is irrelevant and the
563          * state had better already be in the pcb.  This is true for forks
564          * but not for dumps (the old book-keeping with FP flags in the pcb
565          * always lost for dumps because the dump pcb has 0 flags).
566          *
567          * If npxthread != NULL, then we have to save the npx h/w state to
568          * npxthread's pcb and copy it to the requested pcb, or save to the
569          * requested pcb and reload.  Copying is easier because we would
570          * have to handle h/w bugs for reloading.  We used to lose the
571          * parent's npx state for forks by forgetting to reload.
572          */
573         movq    PCPU(npxthread),%rax
574         testq   %rax,%rax
575         jz      1f
576
577         pushq   %rcx                    /* target pcb */
578         movq    TD_SAVEFPU(%rax),%rax   /* originating savefpu area */
579         pushq   %rax
580
581         movq    %rax,%rdi
582         call    npxsave
583
584         popq    %rax
585         popq    %rcx
586
587         movq    $PCB_SAVEFPU_SIZE,%rdx
588         leaq    PCB_SAVEFPU(%rcx),%rcx
589         movq    %rcx,%rsi
590         movq    %rax,%rdi
591         call    bcopy
592 #endif
593
594 1:
595         ret
596
597 /*
598  * cpu_idle_restore()   (current thread in %rax on entry) (one-time execution)
599  *
600  *      Don't bother setting up any regs other than %rbp so backtraces
601  *      don't die.  This restore function is used to bootstrap into the
602  *      cpu_idle() LWKT only, after that cpu_lwkt_*() will be used for
603  *      switching.
604  *
605  *      Clear TDF_RUNNING in old thread only after we've cleaned up %cr3.
606  *      This only occurs during system boot so no special handling is
607  *      required for migration.
608  *
609  *      If we are an AP we have to call ap_init() before jumping to
610  *      cpu_idle().  ap_init() will synchronize with the BP and finish
611  *      setting up various ncpu-dependant globaldata fields.  This may
612  *      happen on UP as well as SMP if we happen to be simulating multiple
613  *      cpus.
614  */
615 ENTRY(cpu_idle_restore)
616         /* cli */
617         movq    KPML4phys,%rcx
618         /* JG xor? */
619         movq    $0,%rbp
620         /* JG push RBP? */
621         pushq   $0
622         movq    %rcx,%cr3
623         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
624 #if 0
625         orl     $TDF_RUNNING,TD_FLAGS(%rax)
626 #endif
627 #ifdef SMP
628         cmpl    $0,PCPU(cpuid)
629         je      1f
630         call    ap_init
631 1:
632 #endif
633         /*
634          * ap_init can decide to enable interrupts early, but otherwise, or if
635          * we are UP, do it here.
636          */
637         sti
638         jmp     cpu_idle
639
640 /*
641  * cpu_kthread_restore() (current thread is %rax on entry, previous is %rbx)
642  *                       (one-time execution)
643  *
644  *      Don't bother setting up any regs other then %rbp so backtraces
645  *      don't die.  This restore function is used to bootstrap into an
646  *      LWKT based kernel thread only.  cpu_lwkt_switch() will be used
647  *      after this.
648  *
649  *      Because this switch target does not 'return' to lwkt_switch()
650  *      we have to call lwkt_switch_return(otd) to clean up otd.
651  *      otd is in %ebx.
652  *
653  *      Since all of our context is on the stack we are reentrant and
654  *      we can release our critical section and enable interrupts early.
655  */
656 ENTRY(cpu_kthread_restore)
657         sti
658         movq    KPML4phys,%rcx
659         movq    TD_PCB(%rax),%r13
660         xorq    %rbp,%rbp
661         movq    %rcx,%cr3
662
663         /*
664          * rax and rbx come from the switchout code.  Call
665          * lwkt_switch_return(otd).
666          *
667          * NOTE: unlike i386, %rsi and %rdi are not call-saved regs.
668          */
669         pushq   %rax
670         movq    %rbx,%rdi
671         call    lwkt_switch_return
672         popq    %rax
673         decl    TD_CRITCOUNT(%rax)
674         movq    PCB_R12(%r13),%rdi      /* argument to RBX function */
675         movq    PCB_RBX(%r13),%rax      /* thread function */
676         /* note: top of stack return address inherited by function */
677         jmp     *%rax
678
679 /*
680  * cpu_lwkt_switch(struct thread *)
681  *
682  *      Standard LWKT switching function.  Only non-scratch registers are
683  *      saved and we don't bother with the MMU state or anything else.
684  *
685  *      This function is always called while in a critical section.
686  *
687  *      There is a one-instruction window where curthread is the new
688  *      thread but %rsp still points to the old thread's stack, but
689  *      we are protected by a critical section so it is ok.
690  */
691 ENTRY(cpu_lwkt_switch)
692         pushq   %rbp    /* JG note: GDB hacked to locate ebp rel to td_sp */
693         pushq   %rbx
694         movq    PCPU(curthread),%rbx    /* becomes old thread in restore */
695         pushq   %r12
696         pushq   %r13
697         pushq   %r14
698         pushq   %r15
699         pushfq
700
701 #if 1
702         /*
703          * Save the FP state if we have used the FP.  Note that calling
704          * npxsave will NULL out PCPU(npxthread).
705          *
706          * We have to deal with the FP state for LWKT threads in case they
707          * happen to get preempted or block while doing an optimized
708          * bzero/bcopy/memcpy.
709          */
710         cmpq    %rbx,PCPU(npxthread)
711         jne     1f
712         movq    %rdi,%r12               /* save %rdi. %r12 is callee-saved */
713         movq    TD_SAVEFPU(%rbx),%rdi
714         call    npxsave                 /* do it in a big C function */
715         movq    %r12,%rdi               /* restore %rdi */
716 1:
717 #endif
718
719         movq    %rdi,%rax               /* switch to this thread */
720         pushq   $cpu_lwkt_restore
721         movq    %rsp,TD_SP(%rbx)
722         /*
723          * %rax contains new thread, %rbx contains old thread.
724          */
725         movq    %rax,PCPU(curthread)
726         movq    TD_SP(%rax),%rsp
727         ret
728
729 /*
730  * cpu_lwkt_restore()   (current thread in %rax on entry)
731  *
732  *      Standard LWKT restore function.  This function is always called
733  *      while in a critical section.
734  *      
735  *      Warning: due to preemption the restore function can be used to 
736  *      'return' to the original thread.  Interrupt disablement must be
737  *      protected through the switch so we cannot run splz here.
738  *
739  *      YYY we theoretically do not need to load KPML4phys into cr3, but if
740  *      so we need a way to detect when the PTD we are using is being 
741  *      deleted due to a process exiting.
742  */
743 ENTRY(cpu_lwkt_restore)
744         movq    KPML4phys,%rcx  /* YYY borrow but beware desched/cpuchg/exit */
745         movq    %cr3,%rdx
746 #if 1
747         cmpq    %rcx,%rdx
748         je      1f
749 #endif
750         movq    %rcx,%cr3
751 1:
752         /*
753          * NOTE: %rbx is the previous thread and %rax is the new thread.
754          *       %rbx is retained throughout so we can return it.
755          *
756          *       lwkt_switch[_return] is responsible for handling TDF_RUNNING.
757          */
758         movq    %rbx,%rax
759         popfq
760         popq    %r15
761         popq    %r14
762         popq    %r13
763         popq    %r12
764         popq    %rbx
765         popq    %rbp
766         ret