lib/libcr/i386/string/memset.S

   1 /*
   2  * Copyright (c) 1993 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/lib/libc/i386/string/memset.S,v 1.5 1999/08/27 23:59:32 peter Exp $
  31  * $DragonFly: src/lib/libcr/i386/string/Attic/memset.S,v 1.3 2004/04/25 12:40:49 joerg Exp $
  32  */
  33
  34 #include "DEFS.h"
  35
  36 /*
  37  * memset(void *b, int c, size_t len)
  38  *      write len bytes of value c (converted to an unsigned char) to
  39  *      the string b.
  40  *
  41  * Written by:
  42  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  43  */
  44
  45 ENTRY(memset)
  46         pushl   %edi
  47         pushl   %ebx
  48         movl    12(%esp),%edi
  49         movzbl  16(%esp),%eax           /* unsigned char, zero extend */
  50         movl    20(%esp),%ecx
  51         pushl   %edi                    /* push address of buffer */
  52
  53         cld                             /* set fill direction forward */
  54
  55         /*
  56          * if the string is too short, it's really not worth the overhead
  57          * of aligning to word boundries, etc.  So we jump to a plain
  58          * unaligned set.
  59          */
  60         cmpl    $0x0f,%ecx
  61         jle     L1
  62
  63         movb    %al,%ah                 /* copy char to all bytes in word */
  64         movl    %eax,%edx
  65         sall    $16,%eax
  66         orl     %edx,%eax
  67
  68         movl    %edi,%edx               /* compute misalignment */
  69         negl    %edx
  70         andl    $3,%edx
  71         movl    %ecx,%ebx
  72         subl    %edx,%ebx
  73
  74         movl    %edx,%ecx               /* set until word aligned */
  75         rep
  76         stosb
  77
  78         movl    %ebx,%ecx
  79         shrl    $2,%ecx                 /* set by words */
  80         rep
  81         stosl
  82
  83         movl    %ebx,%ecx               /* set remainder by bytes */
  84         andl    $3,%ecx
  85 L1:     rep
  86         stosb
  87
  88         popl    %eax                    /* pop address of buffer */
  89         popl    %ebx
  90         popl    %edi
  91         ret