sys/contrib/dev/acpica/source/compiler/prparser.y

   1 %{
   2 /******************************************************************************
   3  *
   4  * Module Name: prparser.y - Bison input file for preprocessor parser
   5  *
   6  *****************************************************************************/
   7
   8 /*
   9  * Copyright (C) 2000 - 2015, Intel Corp.
  10  * All rights reserved.
  11  *
  12  * Redistribution and use in source and binary forms, with or without
  13  * modification, are permitted provided that the following conditions
  14  * are met:
  15  * 1. Redistributions of source code must retain the above copyright
  16  *    notice, this list of conditions, and the following disclaimer,
  17  *    without modification.
  18  * 2. Redistributions in binary form must reproduce at minimum a disclaimer
  19  *    substantially similar to the "NO WARRANTY" disclaimer below
  20  *    ("Disclaimer") and any redistribution must be conditioned upon
  21  *    including a substantially similar Disclaimer requirement for further
  22  *    binary redistribution.
  23  * 3. Neither the names of the above-listed copyright holders nor the names
  24  *    of any contributors may be used to endorse or promote products derived
  25  *    from this software without specific prior written permission.
  26  *
  27  * Alternatively, this software may be distributed under the terms of the
  28  * GNU General Public License ("GPL") version 2 as published by the Free
  29  * Software Foundation.
  30  *
  31  * NO WARRANTY
  32  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  33  * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  34  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTIBILITY AND FITNESS FOR
  35  * A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  36  * HOLDERS OR CONTRIBUTORS BE LIABLE FOR SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  37  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  38  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  39  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT,
  40  * STRICT LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING
  41  * IN ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
  42  * POSSIBILITY OF SUCH DAMAGES.
  43  */
  44
  45 #include "aslcompiler.h"
  46 #include "dtcompiler.h"
  47
  48 #define _COMPONENT          ASL_PREPROCESSOR
  49         ACPI_MODULE_NAME    ("prparser")
  50
  51 void *                      AslLocalAllocate (unsigned int Size);
  52
  53 /* Bison/yacc configuration */
  54
  55 #undef alloca
  56 #define alloca              AslLocalAllocate
  57
  58 int                         PrParserlex (void);
  59 int                         PrParserparse (void);
  60 void                        PrParsererror (char const *msg);
  61 extern char                 *PrParsertext;
  62
  63 UINT64                      PrParserResult; /* Expression return value */
  64
  65 /* Bison/yacc configuration */
  66
  67 #define yytname             PrParsername
  68 #define YYDEBUG             1               /* Enable debug output */
  69 #define YYERROR_VERBOSE     1               /* Verbose error messages */
  70 #define YYFLAG              -32768
  71
  72 /* Define YYMALLOC/YYFREE to prevent redefinition errors  */
  73
  74 #define YYMALLOC            malloc
  75 #define YYFREE              free
  76 %}
  77
  78 %union
  79 {
  80      UINT64                 value;
  81      UINT32                 op;
  82      char                   *str;
  83 }
  84
  85 /*! [Begin] no source code translation */
  86
  87 %type  <value>  Expression
  88
  89 %token <op>     EXPOP_EOF
  90 %token <op>     EXPOP_NEW_LINE
  91 %token <op>     EXPOP_NUMBER
  92 %token <op>     EXPOP_HEX_NUMBER
  93 %token <op>     EXPOP_RESERVED1
  94 %token <op>     EXPOP_RESERVED2
  95 %token <op>     EXPOP_PAREN_OPEN
  96 %token <op>     EXPOP_PAREN_CLOSE
  97
  98 %left <op>      EXPOP_LOGICAL_OR
  99 %left <op>      EXPOP_LOGICAL_AND
 100 %left <op>      EXPOP_OR
 101 %left <op>      EXPOP_XOR
 102 %left <op>      EXPOP_AND
 103 %left <op>      EXPOP_EQUAL EXPOP_NOT_EQUAL
 104 %left <op>      EXPOP_GREATER EXPOP_LESS EXPOP_GREATER_EQUAL EXPOP_LESS_EQUAL
 105 %left <op>      EXPOP_SHIFT_RIGHT EXPOP_SHIFT_LEFT
 106 %left <op>      EXPOP_ADD EXPOP_SUBTRACT
 107 %left <op>      EXPOP_MULTIPLY EXPOP_DIVIDE EXPOP_MODULO
 108 %right <op>     EXPOP_ONES_COMPLIMENT EXPOP_LOGICAL_NOT
 109
 110 /* Tokens above must be kept in synch with dtparser.y */
 111
 112 %token <op>     EXPOP_DEFINE
 113 %token <op>     EXPOP_IDENTIFIER
 114
 115 %%
 116
 117 /*
 118  *  Operator precedence rules (from K&R)
 119  *
 120  *  1)      ( )
 121  *  2)      ! ~ (unary operators that are supported here)
 122  *  3)      *   /   %
 123  *  4)      +   -
 124  *  5)      >>  <<
 125  *  6)      <   >   <=  >=
 126  *  7)      ==  !=
 127  *  8)      &
 128  *  9)      ^
 129  *  10)     |
 130  *  11)     &&
 131  *  12)     ||
 132  */
 133
 134 /*! [End] no source code translation !*/
 135
 136 Value
 137     : Expression EXPOP_NEW_LINE                     { PrParserResult=$1; return 0; } /* End of line (newline) */
 138     | Expression EXPOP_EOF                          { PrParserResult=$1; return 0; } /* End of string (0) */
 139     ;
 140
 141 Expression
 142
 143       /* Unary operators */
 144
 145     : EXPOP_LOGICAL_NOT         Expression          { $$ = DtDoOperator ($2, EXPOP_LOGICAL_NOT,     $2);}
 146     | EXPOP_ONES_COMPLIMENT     Expression          { $$ = DtDoOperator ($2, EXPOP_ONES_COMPLIMENT, $2);}
 147
 148       /* Binary operators */
 149
 150     | Expression EXPOP_MULTIPLY         Expression  { $$ = DtDoOperator ($1, EXPOP_MULTIPLY,        $3);}
 151     | Expression EXPOP_DIVIDE           Expression  { $$ = DtDoOperator ($1, EXPOP_DIVIDE,          $3);}
 152     | Expression EXPOP_MODULO           Expression  { $$ = DtDoOperator ($1, EXPOP_MODULO,          $3);}
 153     | Expression EXPOP_ADD              Expression  { $$ = DtDoOperator ($1, EXPOP_ADD,             $3);}
 154     | Expression EXPOP_SUBTRACT         Expression  { $$ = DtDoOperator ($1, EXPOP_SUBTRACT,        $3);}
 155     | Expression EXPOP_SHIFT_RIGHT      Expression  { $$ = DtDoOperator ($1, EXPOP_SHIFT_RIGHT,     $3);}
 156     | Expression EXPOP_SHIFT_LEFT       Expression  { $$ = DtDoOperator ($1, EXPOP_SHIFT_LEFT,      $3);}
 157     | Expression EXPOP_GREATER          Expression  { $$ = DtDoOperator ($1, EXPOP_GREATER,         $3);}
 158     | Expression EXPOP_LESS             Expression  { $$ = DtDoOperator ($1, EXPOP_LESS,            $3);}
 159     | Expression EXPOP_GREATER_EQUAL    Expression  { $$ = DtDoOperator ($1, EXPOP_GREATER_EQUAL,   $3);}
 160     | Expression EXPOP_LESS_EQUAL       Expression  { $$ = DtDoOperator ($1, EXPOP_LESS_EQUAL,      $3);}
 161     | Expression EXPOP_EQUAL            Expression  { $$ = DtDoOperator ($1, EXPOP_EQUAL,           $3);}
 162     | Expression EXPOP_NOT_EQUAL        Expression  { $$ = DtDoOperator ($1, EXPOP_NOT_EQUAL,       $3);}
 163     | Expression EXPOP_AND              Expression  { $$ = DtDoOperator ($1, EXPOP_AND,             $3);}
 164     | Expression EXPOP_XOR              Expression  { $$ = DtDoOperator ($1, EXPOP_XOR,             $3);}
 165     | Expression EXPOP_OR               Expression  { $$ = DtDoOperator ($1, EXPOP_OR,              $3);}
 166     | Expression EXPOP_LOGICAL_AND      Expression  { $$ = DtDoOperator ($1, EXPOP_LOGICAL_AND,     $3);}
 167     | Expression EXPOP_LOGICAL_OR       Expression  { $$ = DtDoOperator ($1, EXPOP_LOGICAL_OR,      $3);}
 168
 169       /* Parentheses: '(' Expression ')' */
 170
 171     | EXPOP_PAREN_OPEN          Expression
 172         EXPOP_PAREN_CLOSE                           { $$ = $2;}
 173
 174       /* #if defined (ID) or #if defined ID */
 175
 176     | EXPOP_DEFINE EXPOP_PAREN_OPEN EXPOP_IDENTIFIER
 177         EXPOP_PAREN_CLOSE                           { $$ = PrIsDefined (PrParserlval.str);}
 178
 179     | EXPOP_DEFINE EXPOP_IDENTIFIER                 { $$ = PrIsDefined (PrParserlval.str);}
 180
 181     | EXPOP_IDENTIFIER                              { $$ = PrResolveDefine (PrParserlval.str);}
 182
 183       /* Default base for a non-prefixed integer is 10 */
 184
 185     | EXPOP_NUMBER                                  { stroul64 (PrParsertext, 10, &$$);}
 186
 187       /* Standard hex number (0x1234) */
 188
 189     | EXPOP_HEX_NUMBER                              { stroul64 (PrParsertext, 16, &$$);}
 190     ;
 191 %%
 192
 193 /*
 194  * Local support functions, including parser entry point
 195  */
 196 #define PR_FIRST_PARSE_OPCODE   EXPOP_EOF
 197 #define PR_YYTNAME_START        3
 198
 199
 200 /******************************************************************************
 201  *
 202  * FUNCTION:    PrParsererror
 203  *
 204  * PARAMETERS:  Message             - Parser-generated error message
 205  *
 206  * RETURN:      None
 207  *
 208  * DESCRIPTION: Handler for parser errors
 209  *
 210  *****************************************************************************/
 211
 212 void
 213 PrParsererror (
 214     char const              *Message)
 215 {
 216
 217     sprintf (StringBuffer, "Preprocessor Parser : %s (near line %u)",
 218         Message, Gbl_CurrentLineNumber);
 219     DtError (ASL_ERROR, ASL_MSG_SYNTAX,
 220         NULL, (char *) StringBuffer);
 221 }
 222
 223
 224 /******************************************************************************
 225  *
 226  * FUNCTION:    PrGetOpName
 227  *
 228  * PARAMETERS:  ParseOpcode         - Parser token (EXPOP_*)
 229  *
 230  * RETURN:      Pointer to the opcode name
 231  *
 232  * DESCRIPTION: Get the ascii name of the parse opcode for debug output
 233  *
 234  *****************************************************************************/
 235
 236 char *
 237 PrGetOpName (
 238     UINT32                  ParseOpcode)
 239 {
 240 #ifdef ASL_YYTNAME_START
 241     /*
 242      * First entries (PR_YYTNAME_START) in yytname are special reserved names.
 243      * Ignore first 6 characters of name (EXPOP_)
 244      */
 245     return ((char *) yytname
 246         [(ParseOpcode - PR_FIRST_PARSE_OPCODE) + PR_YYTNAME_START] + 6);
 247 #else
 248     return ("[Unknown parser generator]");
 249 #endif
 250 }
 251
 252
 253 /******************************************************************************
 254  *
 255  * FUNCTION:    PrEvaluateExpression
 256  *
 257  * PARAMETERS:  ExprString          - Expression to be evaluated. Must be
 258  *                                    terminated by either a newline or a NUL
 259  *                                    string terminator
 260  *
 261  * RETURN:      64-bit value for the expression
 262  *
 263  * DESCRIPTION: Main entry point for the DT expression parser
 264  *
 265  *****************************************************************************/
 266
 267 UINT64
 268 PrEvaluateExpression (
 269     char                    *ExprString)
 270 {
 271
 272     DbgPrint (ASL_DEBUG_OUTPUT,
 273         "**** Input expression: %s\n", ExprString);
 274
 275     /* Point lexer to the input string */
 276
 277     if (PrInitLexer (ExprString))
 278     {
 279         DtError (ASL_ERROR, ASL_MSG_COMPILER_INTERNAL,
 280             NULL, "Could not initialize lexer");
 281         return (0);
 282     }
 283
 284     /* Parse/Evaluate the input string (value returned in PrParserResult) */
 285
 286     PrParserparse ();
 287     PrTerminateLexer ();
 288
 289     DbgPrint (ASL_DEBUG_OUTPUT,
 290         "**** Parser returned value: %u (%8.8X%8.8X)\n",
 291         (UINT32) PrParserResult, ACPI_FORMAT_UINT64 (PrParserResult));
 292
 293     return (PrParserResult);
 294 }