sys/platform/pc32/i386/vm86bios.s

   1 /*-
   2  * Copyright (c) 1998 Jonathan Lemon
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  * $FreeBSD: src/sys/i386/i386/vm86bios.s,v 1.15.2.1 2000/05/16 06:58:07 dillon Exp $
  27  * $DragonFly: src/sys/platform/pc32/i386/vm86bios.s,v 1.2 2003/06/17 04:28:35 dillon Exp $
  28  */
  29
  30 #include <machine/asmacros.h>           /* miscellaneous asm macros */
  31 #include <machine/trap.h>
  32
  33 #include "assym.s"
  34
  35 #define SCR_NEWPTD      PCB_ESI         /* readability macros */
  36 #define SCR_VMFRAME     PCB_EBP         /* see vm86.c for explanation */
  37 #define SCR_STACK       PCB_ESP
  38 #define SCR_PGTABLE     PCB_EBX
  39 #define SCR_ARGFRAME    PCB_EIP
  40 #define SCR_TSS0        PCB_SPARE
  41 #define SCR_TSS1        (PCB_SPARE+4)
  42
  43         .data
  44         ALIGN_DATA
  45
  46         .globl  _in_vm86call, _vm86pcb
  47
  48 _in_vm86call:           .long   0
  49 _vm86pcb:               .long   0
  50
  51         .text
  52
  53 /*
  54  * vm86_bioscall(struct trapframe_vm86 *vm86)
  55  */
  56 ENTRY(vm86_bioscall)
  57         movl    _vm86pcb,%edx           /* scratch data area */
  58         movl    4(%esp),%eax
  59         movl    %eax,SCR_ARGFRAME(%edx) /* save argument pointer */
  60         pushl   %ebx
  61         pushl   %ebp
  62         pushl   %esi
  63         pushl   %edi
  64         pushl   %gs
  65
  66 #ifdef SMP
  67         pushl   %edx
  68         MP_LOCK                         /* Get global lock */
  69         popl    %edx
  70 #endif
  71
  72 #if NNPX > 0
  73         movl    _curproc,%ecx
  74         cmpl    %ecx,_npxproc           /* do we need to save fp? */
  75         jne     1f
  76         testl   %ecx,%ecx
  77         je      1f                      /* no curproc/npxproc */
  78         pushl   %edx
  79         movl    P_ADDR(%ecx),%ecx
  80         addl    $PCB_SAVEFPU,%ecx
  81         pushl   %ecx
  82         call    _npxsave
  83         popl    %ecx
  84         popl    %edx                    /* recover our pcb */
  85 #endif
  86
  87 1:
  88         movl    SCR_VMFRAME(%edx),%ebx  /* target frame location */
  89         movl    %ebx,%edi               /* destination */
  90         movl    SCR_ARGFRAME(%edx),%esi /* source (set on entry) */
  91         movl    $VM86_FRAMESIZE/4,%ecx  /* sizeof(struct vm86frame)/4 */
  92         cld
  93         rep
  94         movsl                           /* copy frame to new stack */
  95
  96         movl    _curpcb,%eax
  97         pushl   %eax                    /* save curpcb */
  98         movl    %edx,_curpcb            /* set curpcb to vm86pcb */
  99
 100         movl    _tss_gdt,%ebx           /* entry in GDT */
 101         movl    0(%ebx),%eax
 102         movl    %eax,SCR_TSS0(%edx)     /* save first word */
 103         movl    4(%ebx),%eax
 104         andl    $~0x200, %eax           /* flip 386BSY -> 386TSS */
 105         movl    %eax,SCR_TSS1(%edx)     /* save second word */
 106
 107         movl    PCB_EXT(%edx),%edi      /* vm86 tssd entry */
 108         movl    0(%edi),%eax
 109         movl    %eax,0(%ebx)
 110         movl    4(%edi),%eax
 111         movl    %eax,4(%ebx)
 112         movl    $GPROC0_SEL*8,%esi      /* GSEL(entry, SEL_KPL) */
 113         ltr     %si
 114
 115         movl    %cr3,%eax
 116         pushl   %eax                    /* save address space */
 117         movl    _IdlePTD,%ecx
 118         movl    %ecx,%ebx
 119         addl    $KERNBASE,%ebx          /* va of Idle PTD */
 120         movl    0(%ebx),%eax
 121         pushl   %eax                    /* old ptde != 0 when booting */
 122         pushl   %ebx                    /* keep for reuse */
 123
 124         movl    %esp,SCR_STACK(%edx)    /* save current stack location */
 125
 126         movl    SCR_NEWPTD(%edx),%eax   /* mapping for vm86 page table */
 127         movl    %eax,0(%ebx)            /* ... install as PTD entry 0 */
 128
 129         movl    %ecx,%cr3               /* new page tables */
 130         movl    SCR_VMFRAME(%edx),%esp  /* switch to new stack */
 131
 132         call    _vm86_prepcall          /* finish setup */
 133
 134         movl    $1,_in_vm86call         /* set flag for trap() */
 135
 136         /*
 137          * Return via _doreti
 138          */
 139 #ifdef SMP
 140         pushl   _cpl                    /* cpl to restore */
 141 #else
 142         pushl   _cpl                    /* cpl to restore */
 143 #endif
 144         subl    $4,%esp                 /* dummy unit */
 145         incb    _intr_nesting_level
 146         MEXITCOUNT
 147         jmp     _doreti
 148
 149
 150 /*
 151  * vm86_biosret(struct trapframe_vm86 *vm86)
 152  */
 153 ENTRY(vm86_biosret)
 154         movl    _vm86pcb,%edx           /* data area */
 155
 156         movl    4(%esp),%esi            /* source */
 157         movl    SCR_ARGFRAME(%edx),%edi /* destination */
 158         movl    $VM86_FRAMESIZE/4,%ecx  /* size */
 159         cld
 160         rep
 161         movsl                           /* copy frame to original frame */
 162
 163         movl    SCR_STACK(%edx),%esp    /* back to old stack */
 164         popl    %ebx                    /* saved va of Idle PTD */
 165         popl    %eax
 166         movl    %eax,0(%ebx)            /* restore old pte */
 167         popl    %eax
 168         movl    %eax,%cr3               /* install old page table */
 169
 170         movl    $0,_in_vm86call         /* reset trapflag */
 171
 172         movl    _tss_gdt,%ebx           /* entry in GDT */
 173         movl    SCR_TSS0(%edx),%eax
 174         movl    %eax,0(%ebx)            /* restore first word */
 175         movl    SCR_TSS1(%edx),%eax
 176         movl    %eax,4(%ebx)            /* restore second word */
 177         movl    $GPROC0_SEL*8,%esi      /* GSEL(entry, SEL_KPL) */
 178         ltr     %si
 179
 180         popl    _curpcb                 /* restore curpcb/curproc */
 181         movl    SCR_ARGFRAME(%edx),%edx /* original stack frame */
 182         movl    TF_TRAPNO(%edx),%eax    /* return (trapno) */
 183
 184         popl    %gs
 185         popl    %edi
 186         popl    %esi
 187         popl    %ebp
 188         popl    %ebx
 189         ret                             /* back to our normal program */