sys/dev/crypto/padlock/rng_harvest_i386.S

   1 /*
   2  * Copyright (c) 2011 Alex Hornung <alex@alexhornung.com>.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  *
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in
  13  *    the documentation and/or other materials provided with the
  14  *    distribution.
  15  *
  16  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  17  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  18  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  19  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  20  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  21  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  22  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  23  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  24  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  25  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  26  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #include <machine/asmacros.h>
  31
  32         .text
  33
  34 /* int padlock_rng(uint8_t *out, int limit) */
  35 ENTRY(padlock_rng)
  36         movl    4(%esp),%edi
  37         movl    8(%esp),%ecx
  38
  39         movl    $3,     %edx
  40         xorl    %ebx,   %ebx
  41 loop:
  42         /*
  43          * edx: (input)         quality factor of rng entropy
  44          * edi: (input)         buffer for random data
  45                                 autoincremented at end of instruction
  46          * eax: (output)        rng status word
  47          */
  48         .byte   0x0f, 0xa7, 0xc0 /* xstore-rng */
  49
  50
  51         /*
  52          * The lower 5 bits of %eax contain the number of random
  53          * bytes stored.
  54          * If no bytes were stored, there is no more entropy
  55          * available, so we finish up.
  56          */
  57         andl    $0x1f,  %eax
  58         jz      out
  59
  60         /*
  61          * Increment the count of stored random bytes. The buffer pointer
  62          * in edi is auto-incremented by the xstore-rng instruction.
  63          */
  64         addl    %eax,   %ebx
  65
  66         /*
  67          * If we haven't already read enough random bytes,
  68          * loop again.
  69          */
  70         cmpl    %ecx,   %ebx
  71         jl      loop
  72 out:
  73         /* return the number of stored random bytes. */
  74         movl    %ebx,   %eax
  75         ret
  76