sys/i386/i386/locore.s

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  *      from: @(#)locore.s      7.3 (Berkeley) 5/13/91
  37  * $FreeBSD: src/sys/i386/i386/locore.s,v 1.132.2.10 2003/02/03 20:54:49 jhb Exp $
  38  * $DragonFly: src/sys/i386/i386/Attic/locore.s,v 1.3 2003/06/18 18:29:55 dillon Exp $
  39  *
  40  *              originally from: locore.s, by William F. Jolitz
  41  *
  42  *              Substantially rewritten by David Greenman, Rod Grimes,
  43  *                      Bruce Evans, Wolfgang Solfrank, Poul-Henning Kamp
  44  *                      and many others.
  45  */
  46
  47 #include "opt_bootp.h"
  48 #include "opt_nfsroot.h"
  49
  50 #include <sys/syscall.h>
  51 #include <sys/reboot.h>
  52
  53 #include <machine/asmacros.h>
  54 #include <machine/cputypes.h>
  55 #include <machine/psl.h>
  56 #include <machine/pmap.h>
  57 #include <machine/specialreg.h>
  58
  59 #include "assym.s"
  60
  61 /*
  62  *      XXX
  63  *
  64  * Note: This version greatly munged to avoid various assembler errors
  65  * that may be fixed in newer versions of gas. Perhaps newer versions
  66  * will have more pleasant appearance.
  67  */
  68
  69 /*
  70  * PTmap is recursive pagemap at top of virtual address space.
  71  * Within PTmap, the page directory can be found (third indirection).
  72  */
  73         .globl  _PTmap,_PTD,_PTDpde
  74         .set    _PTmap,(PTDPTDI << PDRSHIFT)
  75         .set    _PTD,_PTmap + (PTDPTDI * PAGE_SIZE)
  76         .set    _PTDpde,_PTD + (PTDPTDI * PDESIZE)
  77
  78 /*
  79  * APTmap, APTD is the alternate recursive pagemap.
  80  * It's used when modifying another process's page tables.
  81  */
  82         .globl  _APTmap,_APTD,_APTDpde
  83         .set    _APTmap,APTDPTDI << PDRSHIFT
  84         .set    _APTD,_APTmap + (APTDPTDI * PAGE_SIZE)
  85         .set    _APTDpde,_PTD + (APTDPTDI * PDESIZE)
  86
  87 /*
  88  * Compiled KERNBASE location
  89  */
  90         .globl  _kernbase
  91         .set    _kernbase,KERNBASE
  92
  93 /*
  94  * Globals
  95  */
  96         .data
  97         ALIGN_DATA              /* just to be sure */
  98
  99         .globl  HIDENAME(tmpstk)
 100         .space  0x2000          /* space for tmpstk - temporary stack */
 101 HIDENAME(tmpstk):
 102
 103         .globl  _boothowto,_bootdev
 104
 105         .globl  _cpu,_cpu_vendor,_cpu_id,_bootinfo
 106         .globl  _cpu_high, _cpu_feature, _cpu_procinfo
 107
 108 _cpu:           .long   0                       /* are we 386, 386sx, or 486 */
 109 _cpu_id:        .long   0                       /* stepping ID */
 110 _cpu_high:      .long   0                       /* highest arg to CPUID */
 111 _cpu_feature:   .long   0                       /* features */
 112 _cpu_procinfo:  .long   0                       /* brand index / HTT info */
 113 _cpu_vendor:    .space  20                      /* CPU origin code */
 114 _bootinfo:      .space  BOOTINFO_SIZE           /* bootinfo that we can handle */
 115
 116 _KERNend:       .long   0                       /* phys addr end of kernel (just after bss) */
 117 physfree:       .long   0                       /* phys addr of next free page */
 118
 119 #ifdef SMP
 120                 .globl  _cpu0prvpage
 121 cpu0pp:         .long   0                       /* phys addr cpu0 private pg */
 122 _cpu0prvpage:   .long   0                       /* relocated version */
 123
 124                 .globl  _SMPpt
 125 SMPptpa:        .long   0                       /* phys addr SMP page table */
 126 _SMPpt:         .long   0                       /* relocated version */
 127 #endif /* SMP */
 128
 129         .globl  _IdlePTD
 130 _IdlePTD:       .long   0                       /* phys addr of kernel PTD */
 131
 132 #ifdef SMP
 133         .globl  _KPTphys
 134 #endif
 135 _KPTphys:       .long   0                       /* phys addr of kernel page tables */
 136
 137         .globl  _proc0paddr
 138 _proc0paddr:    .long   0                       /* address of proc 0 address space */
 139 p0upa:          .long   0                       /* phys addr of proc0's UPAGES */
 140
 141 vm86phystk:     .long   0                       /* PA of vm86/bios stack */
 142
 143         .globl  _vm86paddr, _vm86pa
 144 _vm86paddr:     .long   0                       /* address of vm86 region */
 145 _vm86pa:        .long   0                       /* phys addr of vm86 region */
 146
 147 #ifdef BDE_DEBUGGER
 148         .globl  _bdb_exists                     /* flag to indicate BDE debugger is present */
 149 _bdb_exists:    .long   0
 150 #endif
 151
 152 #ifdef PC98
 153         .globl  _pc98_system_parameter
 154 _pc98_system_parameter:
 155         .space  0x240
 156 #endif
 157
 158 /**********************************************************************
 159  *
 160  * Some handy macros
 161  *
 162  */
 163
 164 #define R(foo) ((foo)-KERNBASE)
 165
 166 #define ALLOCPAGES(foo) \
 167         movl    R(physfree), %esi ; \
 168         movl    $((foo)*PAGE_SIZE), %eax ; \
 169         addl    %esi, %eax ; \
 170         movl    %eax, R(physfree) ; \
 171         movl    %esi, %edi ; \
 172         movl    $((foo)*PAGE_SIZE),%ecx ; \
 173         xorl    %eax,%eax ; \
 174         cld ; \
 175         rep ; \
 176         stosb
 177
 178 /*
 179  * fillkpt
 180  *      eax = page frame address
 181  *      ebx = index into page table
 182  *      ecx = how many pages to map
 183  *      base = base address of page dir/table
 184  *      prot = protection bits
 185  */
 186 #define fillkpt(base, prot)               \
 187         shll    $2,%ebx                 ; \
 188         addl    base,%ebx               ; \
 189         orl     $PG_V,%eax              ; \
 190         orl     prot,%eax               ; \
 191 1:      movl    %eax,(%ebx)             ; \
 192         addl    $PAGE_SIZE,%eax         ; /* increment physical address */ \
 193         addl    $4,%ebx                 ; /* next pte */ \
 194         loop    1b
 195
 196 /*
 197  * fillkptphys(prot)
 198  *      eax = physical address
 199  *      ecx = how many pages to map
 200  *      prot = protection bits
 201  */
 202 #define fillkptphys(prot)                 \
 203         movl    %eax, %ebx              ; \
 204         shrl    $PAGE_SHIFT, %ebx       ; \
 205         fillkpt(R(_KPTphys), prot)
 206
 207         .text
 208 /**********************************************************************
 209  *
 210  * This is where the bootblocks start us, set the ball rolling...
 211  *
 212  */
 213 NON_GPROF_ENTRY(btext)
 214
 215 #ifdef PC98
 216         /* save SYSTEM PARAMETER for resume (NS/T or other) */
 217         movl    $0xa1400,%esi
 218         movl    $R(_pc98_system_parameter),%edi
 219         movl    $0x0240,%ecx
 220         cld
 221         rep
 222         movsb
 223 #else   /* IBM-PC */
 224 #ifdef BDE_DEBUGGER
 225 #ifdef BIOS_STEALS_3K
 226         cmpl    $0x0375c339,0x95504
 227 #else
 228         cmpl    $0x0375c339,0x96104     /* XXX - debugger signature */
 229 #endif
 230         jne     1f
 231         movb    $1,R(_bdb_exists)
 232 1:
 233 #endif
 234 /* Tell the bios to warmboot next time */
 235         movw    $0x1234,0x472
 236 #endif  /* PC98 */
 237
 238 /* Set up a real frame in case the double return in newboot is executed. */
 239         pushl   %ebp
 240         movl    %esp, %ebp
 241
 242 /* Don't trust what the BIOS gives for eflags. */
 243         pushl   $PSL_KERNEL
 244         popfl
 245
 246 /*
 247  * Don't trust what the BIOS gives for %fs and %gs.  Trust the bootstrap
 248  * to set %cs, %ds, %es and %ss.
 249  */
 250         mov     %ds, %ax
 251         mov     %ax, %fs
 252         mov     %ax, %gs
 253
 254         call    recover_bootinfo
 255
 256 /* Get onto a stack that we can trust. */
 257 /*
 258  * XXX this step is delayed in case recover_bootinfo needs to return via
 259  * the old stack, but it need not be, since recover_bootinfo actually
 260  * returns via the old frame.
 261  */
 262         movl    $R(HIDENAME(tmpstk)),%esp
 263
 264 #ifdef PC98
 265         /* pc98_machine_type & M_EPSON_PC98 */
 266         testb   $0x02,R(_pc98_system_parameter)+220
 267         jz      3f
 268         /* epson_machine_id <= 0x0b */
 269         cmpb    $0x0b,R(_pc98_system_parameter)+224
 270         ja      3f
 271
 272         /* count up memory */
 273         movl    $0x100000,%eax          /* next, talley remaining memory */
 274         movl    $0xFFF-0x100,%ecx
 275 1:      movl    0(%eax),%ebx            /* save location to check */
 276         movl    $0xa55a5aa5,0(%eax)     /* write test pattern */
 277         cmpl    $0xa55a5aa5,0(%eax)     /* does not check yet for rollover */
 278         jne     2f
 279         movl    %ebx,0(%eax)            /* restore memory */
 280         addl    $PAGE_SIZE,%eax
 281         loop    1b
 282 2:      subl    $0x100000,%eax
 283         shrl    $17,%eax
 284         movb    %al,R(_pc98_system_parameter)+1
 285 3:
 286
 287         movw    R(_pc98_system_parameter+0x86),%ax
 288         movw    %ax,R(_cpu_id)
 289 #endif
 290
 291         call    identify_cpu
 292
 293 /* clear bss */
 294 /*
 295  * XXX this should be done a little earlier.
 296  *
 297  * XXX we don't check that there is memory for our bss and page tables
 298  * before using it.
 299  *
 300  * XXX the boot program somewhat bogusly clears the bss.  We still have
 301  * to do it in case we were unzipped by kzipboot.  Then the boot program
 302  * only clears kzipboot's bss.
 303  *
 304  * XXX the gdt and idt are still somewhere in the boot program.  We
 305  * depend on the convention that the boot program is below 1MB and we
 306  * are above 1MB to keep the gdt and idt  away from the bss and page
 307  * tables.  The idt is only used if BDE_DEBUGGER is enabled.
 308  */
 309         movl    $R(_end),%ecx
 310         movl    $R(_edata),%edi
 311         subl    %edi,%ecx
 312         xorl    %eax,%eax
 313         cld
 314         rep
 315         stosb
 316
 317         call    create_pagetables
 318
 319 /*
 320  * If the CPU has support for VME, turn it on.
 321  */
 322         testl   $CPUID_VME, R(_cpu_feature)
 323         jz      1f
 324         movl    %cr4, %eax
 325         orl     $CR4_VME, %eax
 326         movl    %eax, %cr4
 327 1:
 328
 329 #ifdef BDE_DEBUGGER
 330 /*
 331  * Adjust as much as possible for paging before enabling paging so that the
 332  * adjustments can be traced.
 333  */
 334         call    bdb_prepare_paging
 335 #endif
 336
 337 /* Now enable paging */
 338         movl    R(_IdlePTD), %eax
 339         movl    %eax,%cr3                       /* load ptd addr into mmu */
 340         movl    %cr0,%eax                       /* get control word */
 341         orl     $CR0_PE|CR0_PG,%eax             /* enable paging */
 342         movl    %eax,%cr0                       /* and let's page NOW! */
 343
 344 #ifdef BDE_DEBUGGER
 345 /*
 346  * Complete the adjustments for paging so that we can keep tracing through
 347  * initi386() after the low (physical) addresses for the gdt and idt become
 348  * invalid.
 349  */
 350         call    bdb_commit_paging
 351 #endif
 352
 353         pushl   $begin                          /* jump to high virtualized address */
 354         ret
 355
 356 /* now running relocated at KERNBASE where the system is linked to run */
 357 begin:
 358         /*
 359          * set up the bootstrap stack.  The pcb sits at the end of the
 360          * bootstrap stack.
 361          */
 362         /* set up bootstrap stack */
 363         movl    _proc0paddr,%esp        /* location of in-kernel pages */
 364         addl    $UPAGES*PAGE_SIZE-PCB_SIZE,%esp
 365         xorl    %eax,%eax               /* mark end of frames */
 366         movl    %eax,%ebp
 367         /*movl  _proc0paddr,%eax*/
 368         movl    _IdlePTD, %esi
 369         movl    %esi,PCB_CR3(%esp)
 370
 371         testl   $CPUID_PGE, R(_cpu_feature)
 372         jz      1f
 373         movl    %cr4, %eax
 374         orl     $CR4_PGE, %eax
 375         movl    %eax, %cr4
 376 1:
 377
 378         movl    physfree, %esi
 379         pushl   %esi                            /* value of first for init386(first) */
 380         call    _init386                        /* wire 386 chip for unix operation */
 381         popl    %esi
 382
 383         call    _mi_startup                     /* autoconfiguration, mountroot etc */
 384
 385         hlt             /* never returns to here */
 386
 387 /*
 388  * Signal trampoline, copied to top of user stack
 389  */
 390 NON_GPROF_ENTRY(sigcode)
 391         call    *SIGF_HANDLER(%esp)             /* call signal handler */
 392         lea     SIGF_UC(%esp),%eax              /* get ucontext_t */
 393         pushl   %eax
 394         testl   $PSL_VM,UC_EFLAGS(%eax)
 395         jne     9f
 396         movl    UC_GS(%eax),%gs                 /* restore %gs */
 397 9:
 398         movl    $SYS_sigreturn,%eax
 399         pushl   %eax                            /* junk to fake return addr. */
 400         int     $0x80                           /* enter kernel with args */
 401 0:      jmp     0b
 402
 403         ALIGN_TEXT
 404 _osigcode:
 405         call    *SIGF_HANDLER(%esp)             /* call signal handler */
 406         lea     SIGF_SC(%esp),%eax              /* get sigcontext */
 407         pushl   %eax
 408         testl   $PSL_VM,SC_PS(%eax)
 409         jne     9f
 410         movl    SC_GS(%eax),%gs                 /* restore %gs */
 411 9:
 412         movl    $0x01d516,SC_TRAPNO(%eax)       /* magic: 0ldSiG */
 413         movl    $SYS_sigreturn,%eax
 414         pushl   %eax                            /* junk to fake return addr. */
 415         int     $0x80                           /* enter kernel with args */
 416 0:      jmp     0b
 417
 418         ALIGN_TEXT
 419 _esigcode:
 420
 421         .data
 422         .globl  _szsigcode, _szosigcode
 423 _szsigcode:
 424         .long   _esigcode-_sigcode
 425 _szosigcode:
 426         .long   _esigcode-_osigcode
 427         .text
 428
 429 /**********************************************************************
 430  *
 431  * Recover the bootinfo passed to us from the boot program
 432  *
 433  */
 434 recover_bootinfo:
 435         /*
 436          * This code is called in different ways depending on what loaded
 437          * and started the kernel.  This is used to detect how we get the
 438          * arguments from the other code and what we do with them.
 439          *
 440          * Old disk boot blocks:
 441          *      (*btext)(howto, bootdev, cyloffset, esym);
 442          *      [return address == 0, and can NOT be returned to]
 443          *      [cyloffset was not supported by the FreeBSD boot code
 444          *       and always passed in as 0]
 445          *      [esym is also known as total in the boot code, and
 446          *       was never properly supported by the FreeBSD boot code]
 447          *
 448          * Old diskless netboot code:
 449          *      (*btext)(0,0,0,0,&nfsdiskless,0,0,0);
 450          *      [return address != 0, and can NOT be returned to]
 451          *      If we are being booted by this code it will NOT work,
 452          *      so we are just going to halt if we find this case.
 453          *
 454          * New uniform boot code:
 455          *      (*btext)(howto, bootdev, 0, 0, 0, &bootinfo)
 456          *      [return address != 0, and can be returned to]
 457          *
 458          * There may seem to be a lot of wasted arguments in here, but
 459          * that is so the newer boot code can still load very old kernels
 460          * and old boot code can load new kernels.
 461          */
 462
 463         /*
 464          * The old style disk boot blocks fake a frame on the stack and
 465          * did an lret to get here.  The frame on the stack has a return
 466          * address of 0.
 467          */
 468         cmpl    $0,4(%ebp)
 469         je      olddiskboot
 470
 471         /*
 472          * We have some form of return address, so this is either the
 473          * old diskless netboot code, or the new uniform code.  That can
 474          * be detected by looking at the 5th argument, if it is 0
 475          * we are being booted by the new uniform boot code.
 476          */
 477         cmpl    $0,24(%ebp)
 478         je      newboot
 479
 480         /*
 481          * Seems we have been loaded by the old diskless boot code, we
 482          * don't stand a chance of running as the diskless structure
 483          * changed considerably between the two, so just halt.
 484          */
 485          hlt
 486
 487         /*
 488          * We have been loaded by the new uniform boot code.
 489          * Let's check the bootinfo version, and if we do not understand
 490          * it we return to the loader with a status of 1 to indicate this error
 491          */
 492 newboot:
 493         movl    28(%ebp),%ebx           /* &bootinfo.version */
 494         movl    BI_VERSION(%ebx),%eax
 495         cmpl    $1,%eax                 /* We only understand version 1 */
 496         je      1f
 497         movl    $1,%eax                 /* Return status */
 498         leave
 499         /*
 500          * XXX this returns to our caller's caller (as is required) since
 501          * we didn't set up a frame and our caller did.
 502          */
 503         ret
 504
 505 1:
 506         /*
 507          * If we have a kernelname copy it in
 508          */
 509         movl    BI_KERNELNAME(%ebx),%esi
 510         cmpl    $0,%esi
 511         je      2f                      /* No kernelname */
 512         movl    $MAXPATHLEN,%ecx        /* Brute force!!! */
 513         movl    $R(_kernelname),%edi
 514         cmpb    $'/',(%esi)             /* Make sure it starts with a slash */
 515         je      1f
 516         movb    $'/',(%edi)
 517         incl    %edi
 518         decl    %ecx
 519 1:
 520         cld
 521         rep
 522         movsb
 523
 524 2:
 525         /*
 526          * Determine the size of the boot loader's copy of the bootinfo
 527          * struct.  This is impossible to do properly because old versions
 528          * of the struct don't contain a size field and there are 2 old
 529          * versions with the same version number.
 530          */
 531         movl    $BI_ENDCOMMON,%ecx      /* prepare for sizeless version */
 532         testl   $RB_BOOTINFO,8(%ebp)    /* bi_size (and bootinfo) valid? */
 533         je      got_bi_size             /* no, sizeless version */
 534         movl    BI_SIZE(%ebx),%ecx
 535 got_bi_size:
 536
 537         /*
 538          * Copy the common part of the bootinfo struct
 539          */
 540         movl    %ebx,%esi
 541         movl    $R(_bootinfo),%edi
 542         cmpl    $BOOTINFO_SIZE,%ecx
 543         jbe     got_common_bi_size
 544         movl    $BOOTINFO_SIZE,%ecx
 545 got_common_bi_size:
 546         cld
 547         rep
 548         movsb
 549
 550 #ifdef NFS_ROOT
 551 #ifndef BOOTP_NFSV3
 552         /*
 553          * If we have a nfs_diskless structure copy it in
 554          */
 555         movl    BI_NFS_DISKLESS(%ebx),%esi
 556         cmpl    $0,%esi
 557         je      olddiskboot
 558         movl    $R(_nfs_diskless),%edi
 559         movl    $NFSDISKLESS_SIZE,%ecx
 560         cld
 561         rep
 562         movsb
 563         movl    $R(_nfs_diskless_valid),%edi
 564         movl    $1,(%edi)
 565 #endif
 566 #endif
 567
 568         /*
 569          * The old style disk boot.
 570          *      (*btext)(howto, bootdev, cyloffset, esym);
 571          * Note that the newer boot code just falls into here to pick
 572          * up howto and bootdev, cyloffset and esym are no longer used
 573          */
 574 olddiskboot:
 575         movl    8(%ebp),%eax
 576         movl    %eax,R(_boothowto)
 577         movl    12(%ebp),%eax
 578         movl    %eax,R(_bootdev)
 579
 580         ret
 581
 582
 583 /**********************************************************************
 584  *
 585  * Identify the CPU and initialize anything special about it
 586  *
 587  */
 588 identify_cpu:
 589
 590         /* Try to toggle alignment check flag; does not exist on 386. */
 591         pushfl
 592         popl    %eax
 593         movl    %eax,%ecx
 594         orl     $PSL_AC,%eax
 595         pushl   %eax
 596         popfl
 597         pushfl
 598         popl    %eax
 599         xorl    %ecx,%eax
 600         andl    $PSL_AC,%eax
 601         pushl   %ecx
 602         popfl
 603
 604         testl   %eax,%eax
 605         jnz     try486
 606
 607         /* NexGen CPU does not have aligment check flag. */
 608         pushfl
 609         movl    $0x5555, %eax
 610         xorl    %edx, %edx
 611         movl    $2, %ecx
 612         clc
 613         divl    %ecx
 614         jz      trynexgen
 615         popfl
 616         movl    $CPU_386,R(_cpu)
 617         jmp     3f
 618
 619 trynexgen:
 620         popfl
 621         movl    $CPU_NX586,R(_cpu)
 622         movl    $0x4778654e,R(_cpu_vendor)      # store vendor string
 623         movl    $0x72446e65,R(_cpu_vendor+4)
 624         movl    $0x6e657669,R(_cpu_vendor+8)
 625         movl    $0,R(_cpu_vendor+12)
 626         jmp     3f
 627
 628 try486: /* Try to toggle identification flag; does not exist on early 486s. */
 629         pushfl
 630         popl    %eax
 631         movl    %eax,%ecx
 632         xorl    $PSL_ID,%eax
 633         pushl   %eax
 634         popfl
 635         pushfl
 636         popl    %eax
 637         xorl    %ecx,%eax
 638         andl    $PSL_ID,%eax
 639         pushl   %ecx
 640         popfl
 641
 642         testl   %eax,%eax
 643         jnz     trycpuid
 644         movl    $CPU_486,R(_cpu)
 645
 646         /*
 647          * Check Cyrix CPU
 648          * Cyrix CPUs do not change the undefined flags following
 649          * execution of the divide instruction which divides 5 by 2.
 650          *
 651          * Note: CPUID is enabled on M2, so it passes another way.
 652          */
 653         pushfl
 654         movl    $0x5555, %eax
 655         xorl    %edx, %edx
 656         movl    $2, %ecx
 657         clc
 658         divl    %ecx
 659         jnc     trycyrix
 660         popfl
 661         jmp     3f              /* You may use Intel CPU. */
 662
 663 trycyrix:
 664         popfl
 665         /*
 666          * IBM Bluelighting CPU also doesn't change the undefined flags.
 667          * Because IBM doesn't disclose the information for Bluelighting
 668          * CPU, we couldn't distinguish it from Cyrix's (including IBM
 669          * brand of Cyrix CPUs).
 670          */
 671         movl    $0x69727943,R(_cpu_vendor)      # store vendor string
 672         movl    $0x736e4978,R(_cpu_vendor+4)
 673         movl    $0x64616574,R(_cpu_vendor+8)
 674         jmp     3f
 675
 676 trycpuid:       /* Use the `cpuid' instruction. */
 677         xorl    %eax,%eax
 678         cpuid                                   # cpuid 0
 679         movl    %eax,R(_cpu_high)               # highest capability
 680         movl    %ebx,R(_cpu_vendor)             # store vendor string
 681         movl    %edx,R(_cpu_vendor+4)
 682         movl    %ecx,R(_cpu_vendor+8)
 683         movb    $0,R(_cpu_vendor+12)
 684
 685         movl    $1,%eax
 686         cpuid                                   # cpuid 1
 687         movl    %eax,R(_cpu_id)                 # store cpu_id
 688         movl    %ebx,R(_cpu_procinfo)           # store cpu_procinfo
 689         movl    %edx,R(_cpu_feature)            # store cpu_feature
 690         rorl    $8,%eax                         # extract family type
 691         andl    $15,%eax
 692         cmpl    $5,%eax
 693         jae     1f
 694
 695         /* less than Pentium; must be 486 */
 696         movl    $CPU_486,R(_cpu)
 697         jmp     3f
 698 1:
 699         /* a Pentium? */
 700         cmpl    $5,%eax
 701         jne     2f
 702         movl    $CPU_586,R(_cpu)
 703         jmp     3f
 704 2:
 705         /* Greater than Pentium...call it a Pentium Pro */
 706         movl    $CPU_686,R(_cpu)
 707 3:
 708         ret
 709
 710
 711 /**********************************************************************
 712  *
 713  * Create the first page directory and its page tables.
 714  *
 715  */
 716
 717 create_pagetables:
 718
 719 /* Find end of kernel image (rounded up to a page boundary). */
 720         movl    $R(_end),%esi
 721
 722 /* Include symbols, if any. */
 723         movl    R(_bootinfo+BI_ESYMTAB),%edi
 724         testl   %edi,%edi
 725         je      over_symalloc
 726         movl    %edi,%esi
 727         movl    $KERNBASE,%edi
 728         addl    %edi,R(_bootinfo+BI_SYMTAB)
 729         addl    %edi,R(_bootinfo+BI_ESYMTAB)
 730 over_symalloc:
 731
 732 /* If we are told where the end of the kernel space is, believe it. */
 733         movl    R(_bootinfo+BI_KERNEND),%edi
 734         testl   %edi,%edi
 735         je      no_kernend
 736         movl    %edi,%esi
 737 no_kernend:
 738
 739         addl    $PAGE_MASK,%esi
 740         andl    $~PAGE_MASK,%esi
 741         movl    %esi,R(_KERNend)        /* save end of kernel */
 742         movl    %esi,R(physfree)        /* next free page is at end of kernel */
 743
 744 /* Allocate Kernel Page Tables */
 745         ALLOCPAGES(NKPT)
 746         movl    %esi,R(_KPTphys)
 747
 748 /* Allocate Page Table Directory */
 749         ALLOCPAGES(1)
 750         movl    %esi,R(_IdlePTD)
 751
 752 /* Allocate UPAGES */
 753         ALLOCPAGES(UPAGES)
 754         movl    %esi,R(p0upa)
 755         addl    $KERNBASE, %esi
 756         movl    %esi, R(_proc0paddr)
 757
 758         ALLOCPAGES(1)                   /* vm86/bios stack */
 759         movl    %esi,R(vm86phystk)
 760
 761         ALLOCPAGES(3)                   /* pgtable + ext + IOPAGES */
 762         movl    %esi,R(_vm86pa)
 763         addl    $KERNBASE, %esi
 764         movl    %esi, R(_vm86paddr)
 765
 766 #ifdef SMP
 767 /* Allocate cpu0's private data page */
 768         ALLOCPAGES(1)
 769         movl    %esi,R(cpu0pp)
 770         addl    $KERNBASE, %esi
 771         movl    %esi, R(_cpu0prvpage)   /* relocated to KVM space */
 772
 773 /* Allocate SMP page table page */
 774         ALLOCPAGES(1)
 775         movl    %esi,R(SMPptpa)
 776         addl    $KERNBASE, %esi
 777         movl    %esi, R(_SMPpt)         /* relocated to KVM space */
 778 #endif  /* SMP */
 779
 780 /* Map read-only from zero to the end of the kernel text section */
 781         xorl    %eax, %eax
 782 #ifdef BDE_DEBUGGER
 783 /* If the debugger is present, actually map everything read-write. */
 784         cmpl    $0,R(_bdb_exists)
 785         jne     map_read_write
 786 #endif
 787         xorl    %edx,%edx
 788
 789 #if !defined(SMP)
 790         testl   $CPUID_PGE, R(_cpu_feature)
 791         jz      2f
 792         orl     $PG_G,%edx
 793 #endif
 794
 795 2:      movl    $R(_etext),%ecx
 796         addl    $PAGE_MASK,%ecx
 797         shrl    $PAGE_SHIFT,%ecx
 798         fillkptphys(%edx)
 799
 800 /* Map read-write, data, bss and symbols */
 801         movl    $R(_etext),%eax
 802         addl    $PAGE_MASK, %eax
 803         andl    $~PAGE_MASK, %eax
 804 map_read_write:
 805         movl    $PG_RW,%edx
 806 #if !defined(SMP)
 807         testl   $CPUID_PGE, R(_cpu_feature)
 808         jz      1f
 809         orl     $PG_G,%edx
 810 #endif
 811
 812 1:      movl    R(_KERNend),%ecx
 813         subl    %eax,%ecx
 814         shrl    $PAGE_SHIFT,%ecx
 815         fillkptphys(%edx)
 816
 817 /* Map page directory. */
 818         movl    R(_IdlePTD), %eax
 819         movl    $1, %ecx
 820         fillkptphys($PG_RW)
 821
 822 /* Map proc0's UPAGES in the physical way ... */
 823         movl    R(p0upa), %eax
 824         movl    $UPAGES, %ecx
 825         fillkptphys($PG_RW)
 826
 827 /* Map ISA hole */
 828         movl    $ISA_HOLE_START, %eax
 829         movl    $ISA_HOLE_LENGTH>>PAGE_SHIFT, %ecx
 830         fillkptphys($PG_RW)
 831
 832 /* Map space for the vm86 region */
 833         movl    R(vm86phystk), %eax
 834         movl    $4, %ecx
 835         fillkptphys($PG_RW)
 836
 837 /* Map page 0 into the vm86 page table */
 838         movl    $0, %eax
 839         movl    $0, %ebx
 840         movl    $1, %ecx
 841         fillkpt(R(_vm86pa), $PG_RW|PG_U)
 842
 843 /* ...likewise for the ISA hole */
 844         movl    $ISA_HOLE_START, %eax
 845         movl    $ISA_HOLE_START>>PAGE_SHIFT, %ebx
 846         movl    $ISA_HOLE_LENGTH>>PAGE_SHIFT, %ecx
 847         fillkpt(R(_vm86pa), $PG_RW|PG_U)
 848
 849 #ifdef SMP
 850 /* Map cpu0's private page into global kmem (4K @ cpu0prvpage) */
 851         movl    R(cpu0pp), %eax
 852         movl    $1, %ecx
 853         fillkptphys($PG_RW)
 854
 855 /* Map SMP page table page into global kmem FWIW */
 856         movl    R(SMPptpa), %eax
 857         movl    $1, %ecx
 858         fillkptphys($PG_RW)
 859
 860 /* Map the private page into the SMP page table */
 861         movl    R(cpu0pp), %eax
 862         movl    $0, %ebx                /* pte offset = 0 */
 863         movl    $1, %ecx                /* one private page coming right up */
 864         fillkpt(R(SMPptpa), $PG_RW)
 865
 866 /* ... and put the page table table in the pde. */
 867         movl    R(SMPptpa), %eax
 868         movl    $MPPTDI, %ebx
 869         movl    $1, %ecx
 870         fillkpt(R(_IdlePTD), $PG_RW)
 871
 872 /* Fakeup VA for the local apic to allow early traps. */
 873         ALLOCPAGES(1)
 874         movl    %esi, %eax
 875         movl    $(NPTEPG-1), %ebx       /* pte offset = NTEPG-1 */
 876         movl    $1, %ecx                /* one private pt coming right up */
 877         fillkpt(R(SMPptpa), $PG_RW)
 878
 879 /* Initialize mp lock to allow early traps */
 880         movl    $1, R(_mp_lock)
 881 #endif  /* SMP */
 882
 883 /* install a pde for temporary double map of bottom of VA */
 884         movl    R(_KPTphys), %eax
 885         xorl    %ebx, %ebx
 886         movl    $NKPT, %ecx
 887         fillkpt(R(_IdlePTD), $PG_RW)
 888
 889 /* install pde's for pt's */
 890         movl    R(_KPTphys), %eax
 891         movl    $KPTDI, %ebx
 892         movl    $NKPT, %ecx
 893         fillkpt(R(_IdlePTD), $PG_RW)
 894
 895 /* install a pde recursively mapping page directory as a page table */
 896         movl    R(_IdlePTD), %eax
 897         movl    $PTDPTDI, %ebx
 898         movl    $1,%ecx
 899         fillkpt(R(_IdlePTD), $PG_RW)
 900
 901         ret
 902
 903 #ifdef BDE_DEBUGGER
 904 bdb_prepare_paging:
 905         cmpl    $0,R(_bdb_exists)
 906         je      bdb_prepare_paging_exit
 907
 908         subl    $6,%esp
 909
 910         /*
 911          * Copy and convert debugger entries from the bootstrap gdt and idt
 912          * to the kernel gdt and idt.  Everything is still in low memory.
 913          * Tracing continues to work after paging is enabled because the
 914          * low memory addresses remain valid until everything is relocated.
 915          * However, tracing through the setidt() that initializes the trace
 916          * trap will crash.
 917          */
 918         sgdt    (%esp)
 919         movl    2(%esp),%esi            /* base address of bootstrap gdt */
 920         movl    $R(_gdt),%edi
 921         movl    %edi,2(%esp)            /* prepare to load kernel gdt */
 922         movl    $8*18/4,%ecx
 923         cld
 924         rep                             /* copy gdt */
 925         movsl
 926         movl    $R(_gdt),-8+2(%edi)     /* adjust gdt self-ptr */
 927         movb    $0x92,-8+5(%edi)
 928         lgdt    (%esp)
 929
 930         sidt    (%esp)
 931         movl    2(%esp),%esi            /* base address of current idt */
 932         movl    8+4(%esi),%eax          /* convert dbg descriptor to ... */
 933         movw    8(%esi),%ax
 934         movl    %eax,R(bdb_dbg_ljmp+1)  /* ... immediate offset ... */
 935         movl    8+2(%esi),%eax
 936         movw    %ax,R(bdb_dbg_ljmp+5)   /* ... and selector for ljmp */
 937         movl    24+4(%esi),%eax         /* same for bpt descriptor */
 938         movw    24(%esi),%ax
 939         movl    %eax,R(bdb_bpt_ljmp+1)
 940         movl    24+2(%esi),%eax
 941         movw    %ax,R(bdb_bpt_ljmp+5)
 942         movl    R(_idt),%edi
 943         movl    %edi,2(%esp)            /* prepare to load kernel idt */
 944         movl    $8*4/4,%ecx
 945         cld
 946         rep                             /* copy idt */
 947         movsl
 948         lidt    (%esp)
 949
 950         addl    $6,%esp
 951
 952 bdb_prepare_paging_exit:
 953         ret
 954
 955 /* Relocate debugger gdt entries and gdt and idt pointers. */
 956 bdb_commit_paging:
 957         cmpl    $0,_bdb_exists
 958         je      bdb_commit_paging_exit
 959
 960         movl    $_gdt+8*9,%eax          /* adjust slots 9-17 */
 961         movl    $9,%ecx
 962 reloc_gdt:
 963         movb    $KERNBASE>>24,7(%eax)   /* top byte of base addresses, was 0, */
 964         addl    $8,%eax                 /* now KERNBASE>>24 */
 965         loop    reloc_gdt
 966
 967         subl    $6,%esp
 968         sgdt    (%esp)
 969         addl    $KERNBASE,2(%esp)
 970         lgdt    (%esp)
 971         sidt    (%esp)
 972         addl    $KERNBASE,2(%esp)
 973         lidt    (%esp)
 974         addl    $6,%esp
 975
 976         int     $3
 977
 978 bdb_commit_paging_exit:
 979         ret
 980
 981 #endif /* BDE_DEBUGGER */