lib/libstand/x86_64/_setjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 4. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  *
  32  * $FreeBSD: head/lib/libstand/amd64/_setjmp.S 223695 2011-06-30 16:08:56Z dfr $
  33  */
  34
  35 /*
  36  * C library -- _setjmp, _longjmp
  37  *
  38  *      _longjmp(a,v)
  39  * will generate a "return(v)" from the last call to
  40  *      _setjmp(a)
  41  * by restoring registers from the environment 'a'.
  42  * The previous signal state is NOT restored.
  43  */
  44
  45 #include <machine/asm.h>
  46
  47 ENTRY(_setjmp)
  48         movq    %rdi,%rax
  49         movq    0(%rsp),%rdx            /* retval */
  50         movq    %rdx, 0(%rax)           /* 0; retval */
  51         movq    %rbx, 8(%rax)           /* 1; rbx */
  52         movq    %rsp,16(%rax)           /* 2; rsp */
  53         movq    %rbp,24(%rax)           /* 3; rbp */
  54         movq    %r12,32(%rax)           /* 4; r12 */
  55         movq    %r13,40(%rax)           /* 5; r13 */
  56         movq    %r14,48(%rax)           /* 6; r14 */
  57         movq    %r15,56(%rax)           /* 7; r15 */
  58         fnstcw  64(%rax)                /* 8; fpu cw */
  59         stmxcsr 68(%rax)                /*    and mxcsr */
  60         xorq    %rax,%rax
  61         ret
  62 END(_setjmp)
  63
  64         .weak   CNAME(_longjmp)
  65 ENTRY(_longjmp)
  66         movq    %rdi,%rdx
  67         /* Restore the mxcsr, but leave exception flags intact. */
  68         stmxcsr -4(%rsp)
  69         movl    68(%rdx),%eax
  70         andl    $0xffffffc0,%eax
  71         movl    -4(%rsp),%edi
  72         andl    $0x3f,%edi
  73         xorl    %eax,%edi
  74         movl    %edi,-4(%rsp)
  75         ldmxcsr -4(%rsp)
  76         movq    %rsi,%rax               /* retval */
  77         movq    0(%rdx),%rcx
  78         movq    8(%rdx),%rbx
  79         movq    16(%rdx),%rsp
  80         movq    24(%rdx),%rbp
  81         movq    32(%rdx),%r12
  82         movq    40(%rdx),%r13
  83         movq    48(%rdx),%r14
  84         movq    56(%rdx),%r15
  85         fldcw   64(%rdx)
  86         testq   %rax,%rax
  87         jnz     1f
  88         incq    %rax
  89 1:      movq    %rcx,0(%rsp)
  90         ret
  91 END(_longjmp)