libexec/rtld-aout/i386/mdprologue.S

   1 /*
   2  * Copyright (c) 1993 Paul Kranenburg
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Paul Kranenburg.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/libexec/rtld-aout/i386/mdprologue.S,v 1.9 1999/08/28 00:10:08 peter Exp $
  31  */
  32
  33 /*
  34  * i386 run-time link editor entry points.
  35  */
  36
  37 #include <sys/syscall.h>
  38
  39         .text
  40         .globl  _binder, _binder_entry
  41
  42 /*
  43  *      _rtl(int version, struct crt_ldso *crtp)
  44  */
  45
  46 _rtl:                                   # crt0 calls us here
  47         pushl   %ebp                    # Allocate stack frame
  48         movl    %esp,%ebp
  49         pushl   %ebx
  50
  51         call    1f                      # PIC function prologue
  52 1:
  53         popl    %ebx
  54         addl    $_GLOBAL_OFFSET_TABLE_+[.-1b],%ebx
  55
  56         movl    12(%ebp),%eax           # Extract data from interface structure
  57         movl    (%eax),%eax             # base address of ld.so (first field)
  58                                         # setup arguments for rtld()
  59         movl    (%ebx),%ecx             # 1st entry in GOT is our __DYNAMIC
  60         addl    %eax,%ecx               #   add load address
  61         pushl   %ecx                    # 3rd arg
  62         pushl   12(%ebp)                # 2nd arg == &crt.
  63         pushl   8(%ebp)                 # 1st arg == version
  64         addl    _rtld@GOT(%ebx),%eax    # relocate address of function
  65         call    %eax                    # _rtld(version, crtp, DYNAMIC)
  66         addl    $12,%esp                # pop arguments
  67
  68         popl    %ebx
  69         leave                           # remove stack frame
  70         ret
  71
  72  # First call to a procedure generally comes through here for
  73  # binding.
  74
  75 _binder_entry:
  76         pushl   %ebp                    # setup a stack frame
  77         movl    %esp,%ebp
  78         pusha                           # save all regs
  79
  80         xorl    %eax,%eax               # clear
  81         movl    4(%ebp),%esi            # return address in PLT
  82         movw    (%esi),%ax              # get hold of relocation number
  83         subl    $6,%esi                 # make it point to the jmpslot
  84
  85         pushl   %eax                    # pushd arguments
  86         pushl   %esi                    #
  87         call    _binder@PLT             # _binder(rpc, index)
  88         addl    $8,%esp                 # pop arguments
  89         movl    %eax,4(%ebp)            # return value from _binder() == actual
  90                                         #  address of function
  91         popa                            # restore regs
  92         leave                           # remove our stack frame
  93         ret