release/scripts/driver-copy2.awk

   1 #!/usr/bin/awk -f
   2 #
   3 # Copyright (c) 2000  "HOSOKAWA, Tatsumi" <hosokawa@FreeBSD.org>
   4 # Copyright (c) 2002  Ruslan Ermilov <ru@FreeBSD.org>
   5 # All rights reserved.
   6 #
   7 # Redistribution and use in source and binary forms, with or without
   8 # modification, are permitted provided that the following conditions
   9 # are met:
  10 # 1. Redistributions of source code must retain the above copyright
  11 #    notice, this list of conditions and the following disclaimer.
  12 # 2. Redistributions in binary form must reproduce the above copyright
  13 #    notice, this list of conditions and the following disclaimer in the
  14 #    documentation and/or other materials provided with the distribution.
  15 #
  16 # THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  17 # ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  18 # IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  19 # ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  20 # FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  21 # DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  22 # OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  23 # HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  24 # LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  25 # OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  26 # SUCH DAMAGE.
  27 #
  28 # $FreeBSD: src/release/scripts/driver-copy2.awk,v 1.2.2.1 2002/08/08 08:38:18 ru Exp $
  29 #
  30
  31 function usage()
  32 {
  33         print "usage: driver-copy2.awk config_file src_ko_dir dst_ko_dir" > "/dev/stderr";
  34         exit 1;
  35 }
  36
  37 function err(eval, fmt, what)
  38 {
  39         printf "driver-copy2.awk: " fmt "\n", what > "/dev/stderr";
  40         exit eval;
  41 }
  42
  43 function readconfig()
  44 {
  45         while ((r = (getline < config)) > 0) {
  46                 sub("#.*$", "");
  47                 if (sub(/^[[:alnum:]_]+[ \t]+[[:alnum:]_]+[ \t]+[0-9]+[ \t]+[[:alnum:]_]+[ \t]+\".*\"[ \t]*$/, "&")) {
  48                         sub(/[ \t]+/, "#");
  49                         sub(/[ \t]+/, "#");
  50                         sub(/[ \t]+/, "#");
  51                         sub(/[ \t]+/, "#");
  52                         sub(/\"/, "");
  53                         sub(/\"/, "");
  54                         split($0, arg, "#");
  55                         flp[arg[2]] = arg[3];
  56                         dsc[arg[2]] = arg[5];
  57                 }
  58         }
  59         if (r == -1)
  60                 err(1, "error reading %s", config);
  61         close(config);
  62 }
  63
  64 BEGIN {
  65         if (ARGC != 4)
  66                 usage();
  67
  68         config = ARGV[1];
  69         srcdir = ARGV[2];
  70         dstdir = ARGV[3];
  71
  72         readconfig();
  73
  74         if (system("test -d " srcdir) != 0)
  75                 err(1, "cannot find %s directory", srcdir);
  76         if (system("test -d " dstdir) != 0)
  77                 err(1, "cannot find %s directory", dstdir);
  78
  79         for (f in flp) {
  80                 if (flp[f] == 1) {
  81                         print f ": There's nothing to do with driver on first floppy." > "/dev/stderr";
  82                 } else if (flp[f] == 2) {
  83                         srcfile = srcdir "/" f ".ko";
  84                         dstfile = dstdir "/" f ".ko";
  85                         dscfile = dstdir "/" f ".dsc";
  86                         print "Copying " f ".ko to " dstdir > "/dev/stderr";
  87                         if (system("cp " srcfile " " dstfile) != 0)
  88                                 exit 1;
  89                         printf "%s", dsc[f] > dscfile;
  90                         close(dscfile);
  91                 } else if (flp[f] == 3) {
  92                         # third driver floppy (not yet implemented)
  93                         err(1, "%s: 3rd driver floppy support is not implemented", f);
  94                 }
  95         }
  96 }