Remove forgotten backslash.
[dragonfly.git] / share / examples / rconfig / hammer.sh
1 #!/bin/csh
2 #
3 # This will format a new machine with a BOOT+HAMMER setup and install
4 # the live CD.  You would boot the live CD, dhclient your network up,
5 # then run 'rconfig :hammer', assuming you have a rconfig server on the
6 # LAN.  Alternately fetch the script from a known location and just run it.
7 #
8 # ad6s1a will be setup as a small UFS /boot.  ad6s1d will be setup as
9 # HAMMER with all remaining disk space.  Pseudo file-systems will be
10 # created for /var, /usr, etc (giving them separate inode spaces and
11 # backup domains).
12 #
13 # WARNING: HAMMER filesystems (and pseudo-filesystems) must be
14 # occassionally pruned and reblocked.  'man hammer' for more information.
15
16 set disk = "ad6"
17
18 # For safety this only runs on a CD- or PXE-booted machine
19 #
20 df / | egrep -q '^(*.cd|.+:)'
21 if ( $status > 0 ) then
22     echo "This program formats your disk and you didn't run it from"
23     echo "a CD or NFS boot!"
24     exit 1
25 endif
26
27 echo "This program formats disk ${disk}!  Hit ^C now or its gone."
28 foreach i ( 10 9 8 7 6 5 4 3 2 1 )
29     echo -n " $i"
30     sleep 1
31 end
32 echo ""
33
34 # Unmount any prior mounts on /mnt, reverse order to unwind
35 # sub-directory mounts.
36 #
37 foreach i ( `df | fgrep /mnt | awk '{ print $6; }' | tail -r` )
38     echo "UMOUNT $i"
39     umount $i
40 end
41
42 # Set our disk here
43 #
44 sleep 1
45 set echo
46
47 # Format and label the disk.  
48 #
49 #       'a' small UFS boot
50 #       'd' HAMMER filesystem
51 #
52 #       Use PFSs for backup domain separation
53 #
54 dd if=/dev/zero of=/dev/${disk} bs=32k count=16
55 fdisk -IB ${disk}
56 disklabel64 -r -w ${disk}s1 auto
57 disklabel64 -B ${disk}s1
58 disklabel64 ${disk}s1 > /tmp/label
59
60 cat >> /tmp/label << EOF
61   a: 768m 0 4.2BSD
62   b: 2g * swap
63   d: * * HAMMER
64 EOF
65 disklabel64 -R ${disk}s1 /tmp/label
66
67 # Create file systems
68 newfs /dev/${disk}s1a
69 newfs_hammer -L ROOT /dev/${disk}s1d
70
71 # Mount it
72 #
73 mount_hammer /dev/${disk}s1d /mnt
74 mkdir /mnt/boot
75 mount /dev/${disk}s1a /mnt/boot
76
77 # Create PFS mount points for nullfs.
78 #
79 # Do the mounts manually so we can install the system, setup
80 # the fstab later on.
81 mkdir /mnt/pfs
82
83 hammer pfs-master /mnt/pfs/usr
84 hammer pfs-master /mnt/pfs/usr.obj
85 hammer pfs-master /mnt/pfs/var
86 hammer pfs-master /mnt/pfs/var.crash
87 hammer pfs-master /mnt/pfs/var.tmp
88 hammer pfs-master /mnt/pfs/tmp
89 hammer pfs-master /mnt/pfs/home
90
91 mkdir /mnt/usr
92 mkdir /mnt/var
93 mkdir /mnt/tmp
94 mkdir /mnt/home
95
96 mount_null /mnt/pfs/usr /mnt/usr
97 mount_null /mnt/pfs/var /mnt/var
98 mount_null /mnt/pfs/tmp /mnt/tmp
99 mount_null /mnt/pfs/home /mnt/home
100
101 mkdir /mnt/usr/obj
102 mkdir /mnt/var/tmp
103 mkdir /mnt/var/crash
104
105 mount_null /mnt/pfs/var.tmp /mnt/var/tmp
106 mount_null /mnt/pfs/var.crash /mnt/var/crash
107 mount_null /mnt/pfs/usr.obj /mnt/usr/obj
108
109 chmod 1777 /mnt/tmp
110 chmod 1777 /mnt/var/tmp
111
112 # Install the system from the live CD
113 #
114 cpdup -o / /mnt
115 cpdup -o /boot /mnt/boot
116 cpdup -o /usr /mnt/usr
117 cpdup -o /var /mnt/var
118 cpdup -i0 /etc.hdd /mnt/etc
119
120 chflags -R nohistory /mnt/tmp
121 chflags -R nohistory /mnt/var/tmp
122 chflags -R nohistory /mnt/var/crash
123 chflags -R nohistory /mnt/usr/obj
124
125 # Create some directories to be used for NFS mounts later on.
126 # Edit as desired.
127 #
128 foreach i ( /proc /usr/doc /usr/src /repository /ftp /archive )
129     if ( ! -d /mnt$i ) then
130         mkdir /mnt$i
131     endif
132 end
133
134 cat > /mnt/etc/fstab << EOF
135 # Device                Mountpoint      FStype  Options         Dump    Pass#
136 /dev/${disk}s1d         /               hammer  rw              1       1
137 /dev/${disk}s1a         /boot           ufs     rw              1       1
138 /dev/${disk}s1b         none            swap    sw              0       0
139 /pfs/usr                /usr            null    rw              0       0
140 /pfs/var                /var            null    rw              0       0
141 /pfs/tmp                /tmp            null    rw              0       0
142 /pfs/home               /home           null    rw              0       0
143 /pfs/var.tmp            /var/tmp        null    rw              0       0
144 /pfs/usr.obj            /usr/obj        null    rw              0       0
145 /pfs/var.crash          /var/crash      null    rw              0       0
146 proc                    /proc           procfs  rw              0       0
147 # misc NFS mounts to get your test box access to 'stuff'
148 #crater:/repository     /repository     nfs     ro,intr,bg      0       0
149 #crater:/usr/doc        /usr/doc        nfs     ro,intr,bg      0       0
150 #crater:/ftp            /ftp            nfs     ro,intr,bg      0       0
151 #crater:/sources/HEAD   /usr/src        nfs     ro,intr,bg      0       0
152 #pkgbox:/archive        /archive        nfs     ro,intr,bg      0       0
153 EOF
154
155 # Because root is not on the boot partition we have to tell the loader
156 # to tell the kernel where root is.
157 #
158 cat > /mnt/boot/loader.conf << EOF
159 vfs.root.mountfrom="hammer:${disk}s1d"
160 EOF
161
162 # Setup interface, configuration, sshd
163 #
164 set ifc = `route -n get default | fgrep interface | awk '{ print $2; }'`
165 set ip = `ifconfig $ifc | fgrep inet | fgrep -v inet6 | awk '{ print $2; }'`
166 set lip = `echo $ip | awk -F . '{ print $4; }'`
167
168 echo -n "ifconfig_$ifc=" >> /mnt/etc/rc.conf
169 echo '"DHCP"' >> /mnt/etc/rc.conf
170 cat >> /mnt/etc/rc.conf << EOF
171 sshd_enable="YES"
172 dntpd_enable="YES"
173 hostname="test$lip.MYDOMAIN.XXX"
174 dumpdev="/dev/${disk}s1b"
175 EOF
176
177 # Misc sysctls
178 #
179 cat >> /mnt/etc/sysctl.conf << EOF
180 #net.inet.ip.portrange.first=4000
181 EOF
182
183 # Allow sshd root logins via dsa key only
184 #
185 fgrep 'PermitRootLogin without-password' /mnt/etc/ssh/sshd_config >& /dev/null
186 if ( $?status ) then
187     echo "PermitRootLogin without-password" >> /mnt/etc/ssh/sshd_config
188 endif
189
190 # additional loader.conf stuff
191 #cat >> /mnt/boot/loader.conf << EOF
192 #if_nfe_load="YES"
193 #EOF
194
195 # Get sshd working - auto install my key so I can login.
196 #
197 #mkdir -p /mnt/root/.ssh
198 #cat > /mnt/root/.ssh/authorized_keys << EOF
199 #ssh-dss ...
200 #EOF
201
202 if ( ! -f /mnt/etc/ssh/ssh_host_dsa_key ) then
203     cd /mnt/etc/ssh
204     ssh-keygen -t dsa -f ssh_host_dsa_key -N ""
205 endif
206
207 # take CD out and reboot
208