sbin/devd/token.l

   1 %{
   2 /*-
   3  * DEVD (Device action daemon)
   4  *
   5  * Copyright (c) 2002 M. Warner Losh <imp@freebsd.org>.
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  *
  29  * $FreeBSD: src/sbin/devd/token.l,v 1.7 2008/03/21 20:38:28 imp Exp $
  30  * $DragonFly: src/sbin/devd/token.l,v 1.1 2008/10/03 00:26:21 hasso Exp $
  31  */
  32
  33 #include <ctype.h>
  34 #include <stdlib.h>
  35 #include <string.h>
  36 #include <syslog.h>
  37 #include "devd.h"
  38 #include "y.tab.h"
  39
  40 int lineno = 1;
  41 #define YY_NO_UNPUT
  42
  43 static void
  44 update_lineno(const char *cp)
  45 {
  46         while (*cp)
  47                 if (*cp++ == '\n')
  48                         lineno++;
  49 }
  50
  51 %}
  52
  53 %%
  54
  55 [ \t]+                  ;
  56 \n                      lineno++;
  57 ;                       { return SEMICOLON; }
  58 #.*$                    ;
  59 \/\/.*$                 ;
  60 \/\*([^*]|(\*+([^*\/])))*\*+\/ { update_lineno(yytext); }
  61 \{                      { return BEGINBLOCK; }
  62 \}                      { return ENDBLOCK; }
  63 [0-9]+                  { yylval.i = atoi(yytext); return NUMBER; }
  64 \"[^"]+\"               {
  65                                 int len = strlen(yytext) - 2;
  66                                 char *walker;
  67                                 int i;
  68                                 update_lineno(yytext);
  69                                 if ((yylval.str = (char *) malloc(len + 1)) == NULL)
  70                                         goto out;
  71                                 walker = yylval.str;
  72                                 for (i = 1; i <= len; i++) {
  73                                         if (yytext[i] == '\\' &&
  74                                             yytext[i + 1] == '\n') {
  75                                                 i += 2;
  76                                                 while(isspace(yytext[i]))
  77                                                         i++;
  78                                         }
  79                                         *walker++ = yytext[i];
  80                                 }
  81                                 *walker++ = '\0';
  82                         out:;
  83                                 return STRING;
  84                         }
  85
  86
  87 options                 { return OPTIONS; }
  88 set                     { return SET; }
  89 directory               { return DIRECTORY; }
  90 pid-file                { return PID_FILE; }
  91 attach                  { return ATTACH; }
  92 detach                  { return DETACH; }
  93 device-name             { return DEVICE_NAME; }
  94 media-type              { return MEDIA_TYPE; }
  95 class                   { return CLASS; }
  96 subdevice               { return SUBDEVICE; }
  97 action                  { return ACTION; }
  98 match                   { return MATCH; }
  99 nomatch                 { return NOMATCH; }
 100 notify                  { return NOTIFY; }
 101 [A-Za-z][A-Za-z0-9_-]*  {
 102                                 yylval.str = strdup(yytext);
 103                                 return ID;
 104                         }
 105 %%
 106
 107 void
 108 yyerror(const char *s)
 109 {
 110         syslog(LOG_ERR, "line %d: %s%s %s.\n", lineno, yytext, yytext?":":"", s);
 111 }