sys/i386/isa/ipl.s

   1 /*-
   2  * Copyright (c) 1989, 1990 William F. Jolitz.
   3  * Copyright (c) 1990 The Regents of the University of California.
   4  * All rights reserved.
   5  *
   6  * This code is derived from software contributed to Berkeley by
   7  * William Jolitz.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. All advertising materials mentioning features or use of this software
  18  *    must display the following acknowledgement:
  19  *      This product includes software developed by the University of
  20  *      California, Berkeley and its contributors.
  21  * 4. Neither the name of the University nor the names of its contributors
  22  *    may be used to endorse or promote products derived from this software
  23  *    without specific prior written permission.
  24  *
  25  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  26  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  27  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  28  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  29  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  30  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  31  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  32  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  33  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  34  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  35  * SUCH DAMAGE.
  36  *
  37  *      @(#)ipl.s
  38  *
  39  * $FreeBSD: src/sys/i386/isa/ipl.s,v 1.32.2.3 2002/05/16 16:03:56 bde Exp $
  40  * $DragonFly: src/sys/i386/isa/Attic/ipl.s,v 1.8 2003/07/10 04:47:54 dillon Exp $
  41  */
  42
  43
  44 /*
  45  * AT/386
  46  * Vector interrupt control section
  47  *
  48  *  *_imask     - Interrupt masks for various spl*() functions
  49  *  ipending    - Pending interrupts (set when a masked interrupt occurs)
  50  */
  51
  52         .data
  53         ALIGN_DATA
  54
  55 /* current priority (all off) */
  56
  57         .globl  tty_imask
  58 tty_imask:      .long   SWI_TTY_MASK
  59         .globl  bio_imask
  60 bio_imask:      .long   SWI_CLOCK_MASK | SWI_CAMBIO_MASK
  61         .globl  net_imask
  62 net_imask:      .long   SWI_NET_MASK | SWI_CAMNET_MASK
  63         .globl  cam_imask
  64 cam_imask:      .long   SWI_CAMBIO_MASK | SWI_CAMNET_MASK
  65         .globl  soft_imask
  66 soft_imask:     .long   SWI_MASK
  67         .globl  softnet_imask
  68 softnet_imask:  .long   SWI_NET_MASK
  69         .globl  softtty_imask
  70 softtty_imask:  .long   SWI_TTY_MASK
  71
  72         .text
  73
  74         /*
  75          * DORETI
  76          *
  77          * Handle return from interrupts, traps and syscalls.  This function
  78          * checks the cpl for unmasked pending interrupts (fast, normal, or
  79          * soft) and schedules them if appropriate, then irets.
  80          */
  81         SUPERALIGN_TEXT
  82         .type   doreti,@function
  83 doreti:
  84         FAKE_MCOUNT(bintr)              /* init "from" bintr -> doreti */
  85         popl    %eax                    /* cpl to restore */
  86         movl    PCPU(curthread),%ebx
  87         cli                             /* interlock with TDPRI_CRIT */
  88         movl    %eax,TD_CPL(%ebx)       /* save cpl being restored */
  89         cmpl    $TDPRI_CRIT,TD_PRI(%ebx) /* can't unpend if in critical sec */
  90         jge     5f
  91         addl    $TDPRI_CRIT,TD_PRI(%ebx) /* force all ints to pending */
  92 doreti_next:
  93         sti                             /* allow new interrupts */
  94         movl    %eax,%ecx               /* cpl being restored */
  95         notl    %ecx
  96         cli                             /* disallow YYY remove */
  97 #ifdef SMP
  98         testl   $AST_IPIQ,PCPU(astpending)
  99         jnz     doreti_ipiq
 100 #endif
 101         testl   PCPU(fpending),%ecx     /* check for an unmasked fast int */
 102         jnz     doreti_fast
 103
 104         testl   PCPU(ipending),%ecx
 105         jnz     doreti_intr
 106         testl   $AST_PENDING,PCPU(astpending) /* any pending ASTs? */
 107         jz      2f
 108         testl   $PSL_VM,TF_EFLAGS(%esp)
 109         jz      1f
 110         cmpl    $1,in_vm86call          /* YYY make per 'cpu' */
 111         jnz     doreti_ast2
 112 1:
 113         testb   $SEL_RPL_MASK,TF_CS(%esp)
 114         jnz     doreti_ast2
 115 2:
 116         /*
 117          * Nothing left to do, finish up.  Interrupts are still disabled.
 118          */
 119         subl    $TDPRI_CRIT,TD_PRI(%ebx)        /* interlocked with cli */
 120         testl   %eax,%eax
 121         jnz     5f
 122         movl    $0,PCPU(reqpri)
 123 5:
 124         decl    PCPU(intr_nesting_level)
 125         MEXITCOUNT
 126         .globl  doreti_popl_fs
 127         .globl  doreti_popl_es
 128         .globl  doreti_popl_ds
 129         .globl  doreti_iret
 130         .globl  doreti_syscall_ret
 131 doreti_syscall_ret:
 132 doreti_popl_fs:
 133         popl    %fs
 134 doreti_popl_es:
 135         popl    %es
 136 doreti_popl_ds:
 137         popl    %ds
 138         popal
 139         addl    $8,%esp
 140 doreti_iret:
 141         iret
 142
 143         ALIGN_TEXT
 144         .globl  doreti_iret_fault
 145 doreti_iret_fault:
 146         subl    $8,%esp
 147         pushal
 148         pushl   %ds
 149         .globl  doreti_popl_ds_fault
 150 doreti_popl_ds_fault:
 151         pushl   %es
 152         .globl  doreti_popl_es_fault
 153 doreti_popl_es_fault:
 154         pushl   %fs
 155         .globl  doreti_popl_fs_fault
 156 doreti_popl_fs_fault:
 157         movl    $0,TF_ERR(%esp) /* XXX should be the error code */
 158         movl    $T_PROTFLT,TF_TRAPNO(%esp)
 159         jmp     alltraps_with_regs_pushed
 160
 161         /*
 162          * FAST interrupt pending
 163          */
 164         ALIGN_TEXT
 165 doreti_fast:
 166         andl    PCPU(fpending),%ecx     /* only check fast ints */
 167         bsfl    %ecx, %ecx              /* locate the next dispatchable int */
 168         btrl    %ecx, PCPU(fpending)    /* is it really still pending? */
 169         jnc     doreti_next
 170         pushl   %eax                    /* YYY cpl (expected by frame) */
 171 #ifdef SMP
 172         pushl   %ecx                    /* save ecx */
 173         call    try_mplock
 174         popl    %ecx
 175         testl   %eax,%eax
 176         jz      1f
 177 #endif
 178         call    *fastunpend(,%ecx,4)    /* MP lock successful */
 179 #ifdef SMP
 180         call    rel_mplock
 181 #endif
 182         popl    %eax
 183         jmp     doreti_next
 184 1:
 185         btsl    %ecx, PCPU(fpending)    /* oops, couldn't get the MP lock */
 186         popl    %eax
 187         orl     PCPU(fpending),%eax
 188         jmp     doreti_next
 189
 190         /*
 191          *  INTR interrupt pending
 192          *
 193          *  Temporarily back-out our critical section to allow the interrupt
 194          *  preempt us.
 195          */
 196         ALIGN_TEXT
 197 doreti_intr:
 198         andl    PCPU(ipending),%ecx     /* only check normal ints */
 199         bsfl    %ecx, %ecx              /* locate the next dispatchable int */
 200         btrl    %ecx, PCPU(ipending)    /* is it really still pending? */
 201         jnc     doreti_next
 202         pushl   %eax
 203         pushl   %ecx
 204         subl    $TDPRI_CRIT,TD_PRI(%ebx) /* so we can preempt */
 205         call    sched_ithd              /* YYY must pull in imasks */
 206         addl    $TDPRI_CRIT,TD_PRI(%ebx)
 207         addl    $4,%esp
 208         popl    %eax
 209         jmp     doreti_next
 210
 211         /*
 212          * AST pending
 213          *
 214          * Temporarily back-out our critical section because trap() can be
 215          * a long-winded call, and we want to be more syscall-like.
 216          *
 217          * YYY If we came in from user mode (doreti_ast1) we can call
 218          * lwkt_switch *RIGHT* *NOW* to deal with interrupts more quickly,
 219          * but should still fall through to the trap code to properly
 220          * reschedule.
 221          */
 222 #if 0
 223 doreti_ast1:
 224         andl    $~AST_PENDING,PCPU(astpending)
 225         sti
 226         movl    %eax,%esi               /* save cpl (can't use stack) */
 227         movl    $T_ASTFLT,TF_TRAPNO(%esp)
 228         decl    PCPU(intr_nesting_level) /* syscall-like, not interrupt-like */
 229         subl    $TDPRI_CRIT,TD_PRI(%ebx)
 230         call    lwkt_switch
 231         jmp     1f
 232 #endif
 233 doreti_ast2:
 234         andl    $~AST_PENDING,PCPU(astpending)
 235         sti
 236         movl    %eax,%esi               /* save cpl (can't use stack) */
 237         movl    $T_ASTFLT,TF_TRAPNO(%esp)
 238         decl    PCPU(intr_nesting_level) /* syscall-like, not interrupt-like */
 239         subl    $TDPRI_CRIT,TD_PRI(%ebx)
 240 1:      call    trap
 241         addl    $TDPRI_CRIT,TD_PRI(%ebx)
 242         incl    PCPU(intr_nesting_level)
 243         movl    %esi,%eax               /* restore cpl for loop */
 244         jmp     doreti_next
 245
 246 #ifdef SMP
 247         /*
 248          * IPIQ message pending
 249          */
 250 doreti_ipiq:
 251         andl    $~AST_IPIQ,PCPU(astpending)
 252         call    lwkt_process_ipiq
 253         movl    TD_CPL(%ebx),%eax       /* retrieve cpl again for loop */
 254         jmp     doreti_next
 255
 256 #endif
 257
 258         /*
 259          * SPLZ() a C callable procedure to dispatch any unmasked pending
 260          *        interrupts regardless of critical section nesting.  ASTs
 261          *        are not dispatched.
 262          *
 263          *      YYY at the moment I leave us in a critical section so as
 264          *      not to have to mess with the cpls which will soon be obsolete.
 265          */
 266         SUPERALIGN_TEXT
 267
 268 ENTRY(splz)
 269         pushfl
 270         pushl   %ebx
 271         movl    PCPU(curthread),%ebx
 272         movl    TD_CPL(%ebx),%eax
 273         addl    $TDPRI_CRIT,TD_PRI(%ebx)
 274
 275 splz_next:
 276         cli
 277         movl    %eax,%ecx               /* ecx = ~CPL */
 278         notl    %ecx
 279 #ifdef SMP
 280         testl   $AST_IPIQ,PCPU(astpending)
 281         jnz     splz_ipiq
 282 #endif
 283         testl   PCPU(fpending),%ecx     /* check for an unmasked fast int */
 284         jnz     splz_fast
 285
 286         testl   PCPU(ipending),%ecx
 287         jnz     splz_intr
 288
 289         subl    $TDPRI_CRIT,TD_PRI(%ebx)
 290         testl   %eax,%eax
 291         jnz     5f
 292         movl    $0,PCPU(reqpri)
 293 5:
 294         popl    %ebx
 295         popfl
 296         ret
 297
 298         /*
 299          * FAST interrupt pending
 300          */
 301         ALIGN_TEXT
 302 splz_fast:
 303         andl    PCPU(fpending),%ecx     /* only check fast ints */
 304         bsfl    %ecx, %ecx              /* locate the next dispatchable int */
 305         btrl    %ecx, PCPU(fpending)    /* is it really still pending? */
 306         jnc     splz_next
 307         pushl   %eax
 308 #ifdef SMP
 309         pushl   %ecx
 310         call    try_mplock
 311         popl    %ecx
 312         testl   %eax,%eax
 313         jz      1f
 314 #endif
 315         call    *fastunpend(,%ecx,4)
 316 #ifdef SMP
 317         call    rel_mplock
 318 #endif
 319         popl    %eax
 320         jmp     splz_next
 321 1:
 322         btsl    %ecx, PCPU(fpending)    /* oops, couldn't get the MP lock */
 323         popl    %eax
 324         orl     PCPU(fpending),%eax
 325         jmp     splz_next
 326
 327         /*
 328          *  INTR interrupt pending
 329          *
 330          *  Temporarily back-out our critical section to allow the interrupt
 331          *  preempt us.
 332          */
 333         ALIGN_TEXT
 334 splz_intr:
 335         andl    PCPU(ipending),%ecx     /* only check normal ints */
 336         bsfl    %ecx, %ecx              /* locate the next dispatchable int */
 337         btrl    %ecx, PCPU(ipending)    /* is it really still pending? */
 338         jnc     splz_next
 339         sti
 340         pushl   %eax
 341         pushl   %ecx
 342         subl    $TDPRI_CRIT,TD_PRI(%ebx)
 343         call    sched_ithd              /* YYY must pull in imasks */
 344         addl    $TDPRI_CRIT,TD_PRI(%ebx)
 345         addl    $4,%esp
 346         popl    %eax
 347         jmp     splz_next
 348
 349 #ifdef SMP
 350 splz_ipiq:
 351         andl    $~AST_IPIQ,PCPU(astpending)
 352         pushl   %eax
 353         call    lwkt_process_ipiq
 354         popl    %eax
 355         jmp     splz_next
 356 #endif
 357
 358         /*
 359          * APIC/ICU specific ipl functions provide masking and unmasking
 360          * calls for userland.
 361          */
 362
 363 #ifdef APIC_IO
 364 #include "i386/isa/apic_ipl.s"
 365 #else
 366 #include "i386/isa/icu_ipl.s"
 367 #endif /* APIC_IO */