usr.sbin/config/lang.l

   1 %{
   2 /*-
   3  * Copyright (c) 1980, 1993
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  * 3. All advertising materials mentioning features or use of this software
  15  *    must display the following acknowledgement:
  16  *      This product includes software developed by the University of
  17  *      California, Berkeley and its contributors.
  18  * 4. Neither the name of the University nor the names of its contributors
  19  *    may be used to endorse or promote products derived from this software
  20  *    without specific prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  *      @(#)lang.l      8.1 (Berkeley) 6/6/93
  35  * $FreeBSD: src/usr.sbin/config/lang.l,v 1.27 1999/11/09 07:20:22 peter Exp $
  36  * $DragonFly: src/usr.sbin/config/lang.l,v 1.11 2006/10/23 18:01:13 dillon Exp $
  37  */
  38
  39 #include <ctype.h>
  40 #include <string.h>
  41 #include "y.tab.h"
  42 #include "config.h"
  43
  44 #define YY_NO_UNPUT
  45
  46 /*
  47  * Key word table
  48  */
  49
  50 struct kt {
  51         const char *kt_name;
  52         int kt_val;
  53 } key_words[] = {
  54         { "at",         AT },
  55         { "bus",        BUS },
  56         { "conflicts",  CONFLICTS },
  57         { "config",     CONFIG },
  58         { "controller", CONTROLLER },
  59         { "cpu",        CPU },
  60         { "cpu_arch",   CPU_ARCH },
  61         { "device",     DEVICE },
  62         { "disable",    DISABLE },
  63         { "disk",       DISK },
  64         { "drive",      DRIVE },
  65         { "drq",        DRQ },
  66         { "flags",      FLAGS },
  67         { "ident",      IDENT },
  68         { "iomem",      IOMEM },
  69         { "iosiz",      IOSIZ },
  70         { "irq",        IRQ },
  71         { "machine",    ARCH }, /* MACHINE is defined in /sys/param.h */
  72         { "makeoptions", MAKEOPTIONS },
  73         { "maxusers",   MAXUSERS },
  74         { "nexus",      NEXUS },
  75         { "option",     OPTIONS },
  76         { "options",    OPTIONS },
  77         { "port",       PORT },
  78         { "pseudo-device",PSEUDO_DEVICE },
  79         { "tape",       TAPE },
  80         { "target",     TARGET },
  81         { "unit",       UNIT },
  82         { 0, 0 },
  83 };
  84
  85
  86 int kw_lookup(char *);
  87 int octal(char *);
  88 int hex(char *);
  89
  90 %}
  91 WORD    [A-Za-z_][-A-Za-z_]*
  92 ID      [A-Za-z_][-A-Za-z_0-9]*
  93 %START NONUM TOEOL
  94 %%
  95 <NONUM>{WORD}   {
  96                         int i;
  97
  98                         BEGIN 0;
  99                         if ((i = kw_lookup(yytext)) == -1)
 100                         {
 101                                 yylval.str = strdup(yytext);
 102                                 return(ID);
 103                         }
 104                         return(i);
 105                 }
 106 <INITIAL>{WORD}/[0-9]* {
 107                         int i;
 108
 109                         if ((i = kw_lookup(yytext)) == -1)
 110                                 REJECT;
 111                         if (i == CONTROLLER || i == DEVICE || i == DISK || i == TAPE ||
 112                             i == PSEUDO_DEVICE || i == AT)
 113                                 BEGIN NONUM;
 114                         return(i);
 115                 }
 116 <INITIAL>{ID}   {
 117                         BEGIN 0;
 118                         yylval.str = strdup(yytext);
 119                         return(ID);
 120                 }
 121 \\\"[^"]+\\\"   {
 122                         BEGIN 0;
 123                         yytext[yyleng-2] = '"';
 124                         yytext[yyleng-1] = '\0';
 125                         yylval.str = strdup(yytext + 1);
 126                         return(ID);
 127                 }
 128 \"[^"]+\"       {
 129                         BEGIN 0;
 130                         yytext[yyleng-1] = '\0';
 131                         yylval.str = strdup(yytext + 1);
 132                         return(ID);
 133                 }
 134 <TOEOL>[^# \t\n]*       {
 135                         BEGIN 0;
 136                         yylval.str = strdup(yytext);
 137                         return(ID);
 138                 }
 139 0[0-7]*         {
 140                         yylval.val = octal(yytext);
 141                         return(NUMBER);
 142                 }
 143 0x[0-9a-fA-F]+  {
 144                         yylval.val = hex(yytext);
 145                         return(NUMBER);
 146                 }
 147 -?[1-9][0-9]*   {
 148                         yylval.val = atoi(yytext);
 149                         return(NUMBER);
 150                 }
 151 [0-9]"."[0-9]*  {
 152                         yylval.val = (int)(60 * atof(yytext) + 0.5);
 153                         return(FPNUMBER);
 154                 }
 155 "?"             {
 156                         yylval.val = -1;
 157                         return(NUMBER);
 158                 }
 159 \n/[ \t]        {
 160                         yyline++;
 161                 }
 162 \n              {
 163                         yyline++;
 164                         return(SEMICOLON);
 165                 }
 166 #.*             {       /* Ignored (comment) */;        }
 167 [ \t\f]*        {       /* Ignored (white space) */;    }
 168 ";"             {       return(SEMICOLON);              }
 169 ","             {       return(COMMA);                  }
 170 "="             {       BEGIN TOEOL; return(EQUALS);    }
 171 "@"             {       return(AT);                     }
 172 .               {       return(yytext[0]);              }
 173
 174 %%
 175 /*
 176  * kw_lookup
 177  *      Look up a string in the keyword table.  Returns a -1 if the
 178  *      string is not a keyword otherwise it returns the keyword number
 179  */
 180
 181 int
 182 kw_lookup(char *word)
 183 {
 184         struct kt *kp;
 185
 186         for (kp = key_words; kp->kt_name != NULL; kp++)
 187                 if (!strcmp(word, kp->kt_name))
 188                         return(kp->kt_val);
 189         return(-1);
 190 }
 191
 192 /*
 193  * Number conversion routines
 194  */
 195
 196 int
 197 octal(char *str)
 198 {
 199         int num;
 200
 201         sscanf(str, "%o", &num);
 202         return(num);
 203 }
 204
 205 int
 206 hex(char *str)
 207 {
 208         int num;
 209
 210         sscanf(str + 2, "%x", &num);
 211         return(num);
 212 }