lib/libc/x86_64/gen/setjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 4. Neither the name of the University nor the names of its contributors
  17  *    may be used to endorse or promote products derived from this software
  18  *    without specific prior written permission.
  19  *
  20  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  21  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  22  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  23  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  24  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  25  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  26  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  27  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  28  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  29  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  30  * SUCH DAMAGE.
  31  *
  32  * @(#)setjmp.s 5.1 (Berkeley) 4/23/90
  33  * $FreeBSD: src/lib/libc/amd64/gen/setjmp.S,v 1.29 2008/11/02 01:10:54 peter Exp $
  34  */
  35
  36 #include <machine/asm.h>
  37
  38 /*
  39  * C library -- _setjmp, _longjmp
  40  *
  41  *      longjmp(a,v)
  42  * will generate a "return(v)" from the last call to
  43  *      setjmp(a)
  44  * by restoring registers from the environment 'a'.
  45  * The previous signal state is restored.
  46  */
  47
  48 #include "SYS.h"
  49
  50 ENTRY(setjmp)
  51         pushq   %rdi
  52         movq    %rdi,%rcx
  53         movq    $1,%rdi                 /* SIG_BLOCK       */
  54         movq    $0,%rsi                 /* (sigset_t*)set  */
  55         leaq    72(%rcx),%rdx           /* 9,10; (sigset_t*)oset */
  56         call    PIC_PLT(CNAME(_sigprocmask))
  57         popq    %rdi
  58         movq    %rdi,%rcx
  59         movq    0(%rsp),%rdx            /* retval */
  60         movq    %rdx, 0(%rcx)           /* 0; retval */
  61         movq    %rbx, 8(%rcx)           /* 1; rbx */
  62         movq    %rsp,16(%rcx)           /* 2; rsp */
  63         movq    %rbp,24(%rcx)           /* 3; rbp */
  64         movq    %r12,32(%rcx)           /* 4; r12 */
  65         movq    %r13,40(%rcx)           /* 5; r13 */
  66         movq    %r14,48(%rcx)           /* 6; r14 */
  67         movq    %r15,56(%rcx)           /* 7; r15 */
  68         fnstcw  64(%rcx)                /* 8; fpu cw */
  69         stmxcsr 68(%rcx)                /*    and mxcsr */
  70         xorq    %rax,%rax
  71         ret
  72 END(setjmp)
  73
  74         .weak CNAME(longjmp)
  75         .set CNAME(longjmp),CNAME(__longjmp)
  76 ENTRY(__longjmp)
  77         pushq   %rdi
  78         pushq   %rsi
  79         movq    %rdi,%rdx
  80         movq    $3,%rdi                 /* SIG_SETMASK     */
  81         leaq    72(%rdx),%rsi           /* (sigset_t*)set  */
  82         movq    $0,%rdx                 /* (sigset_t*)oset */
  83         call    PIC_PLT(CNAME(_sigprocmask))
  84         popq    %rsi
  85         popq    %rdi                    /* jmpbuf */
  86         movq    %rdi,%rdx
  87         /* Restore the mxcsr, but leave exception flags intact. */
  88         stmxcsr -4(%rsp)
  89         movl    68(%rdx),%eax
  90         andl    $0xffffffc0,%eax
  91         movl    -4(%rsp),%edi
  92         andl    $0x3f,%edi
  93         xorl    %eax,%edi
  94         movl    %edi,-4(%rsp)
  95         ldmxcsr -4(%rsp)
  96         movq    %rsi,%rax               /* retval */
  97         movq    0(%rdx),%rcx
  98         movq    8(%rdx),%rbx
  99         movq    16(%rdx),%rsp
 100         movq    24(%rdx),%rbp
 101         movq    32(%rdx),%r12
 102         movq    40(%rdx),%r13
 103         movq    48(%rdx),%r14
 104         movq    56(%rdx),%r15
 105         fldcw   64(%rdx)
 106         testq   %rax,%rax
 107         jnz     1f
 108         incq    %rax
 109 1:      movq    %rcx,0(%rsp)
 110         ret
 111 END(__longjmp)