binutils: Import binutils 2.21.1 files on vendor branch
[dragonfly.git] / contrib / binutils-2.21 / ld / ldlex.l
1 %option nounput
2
3 %{
4
5 /* Copyright 1991, 1992, 1993, 1994, 1995, 1996, 1997, 1998, 1999,
6    2000, 2001, 2002, 2003, 2004, 2005, 2006, 2007, 2008, 2009
7    Free Software Foundation, Inc.
8    Written by Steve Chamberlain of Cygnus Support.
9
10    This file is part of the GNU Binutils.
11
12    This program is free software; you can redistribute it and/or modify
13    it under the terms of the GNU General Public License as published by
14    the Free Software Foundation; either version 3 of the License, or
15    (at your option) any later version.
16
17    This program is distributed in the hope that it will be useful,
18    but WITHOUT ANY WARRANTY; without even the implied warranty of
19    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
20    GNU General Public License for more details.
21
22    You should have received a copy of the GNU General Public License
23    along with this program; if not, write to the Free Software
24    Foundation, Inc., 51 Franklin Street - Fifth Floor, Boston,
25    MA 02110-1301, USA.  */
26
27 #include "bfd.h"
28 #include "safe-ctype.h"
29 #include "bfdlink.h"
30 #include "ld.h"
31 #include "ldmisc.h"
32 #include "ldexp.h"
33 #include "ldlang.h"
34 #include <ldgram.h>
35 #include "ldfile.h"
36 #include "ldlex.h"
37 #include "ldmain.h"
38 #include "libiberty.h"
39
40 /* The type of top-level parser input.
41    yylex and yyparse (indirectly) both check this.  */
42 input_type parser_input;
43
44 /* Line number in the current input file.
45    (FIXME Actually, it doesn't appear to get reset for each file?)  */
46 unsigned int lineno = 1;
47
48 /* The string we are currently lexing, or NULL if we are reading a
49    file.  */
50 const char *lex_string = NULL;
51
52 /* Support for flex reading from more than one input file (stream).
53    `include_stack' is flex's input state for each open file;
54    `file_name_stack' is the file names.  `lineno_stack' is the current
55    line numbers.
56
57    If `include_stack_ptr' is 0, we haven't started reading anything yet.
58    Otherwise, stack elements 0 through `include_stack_ptr - 1' are valid.  */
59
60 #undef YY_INPUT
61 #define YY_INPUT(buf,result,max_size) result = yy_input (buf, max_size)
62
63 #ifndef YY_NO_UNPUT
64 #define YY_NO_UNPUT
65 #endif
66
67 #define MAX_INCLUDE_DEPTH 10
68 static YY_BUFFER_STATE include_stack[MAX_INCLUDE_DEPTH];
69 static const char *file_name_stack[MAX_INCLUDE_DEPTH];
70 static unsigned int lineno_stack[MAX_INCLUDE_DEPTH];
71 static unsigned int include_stack_ptr = 0;
72 static int vers_node_nesting = 0;
73
74 static int yy_input (char *, int);
75 static void comment (void);
76 static void lex_warn_invalid (char *where, char *what);
77
78 /* STATES
79         EXPRESSION      definitely in an expression
80         SCRIPT          definitely in a script
81         BOTH            either EXPRESSION or SCRIPT
82         DEFSYMEXP       in an argument to -defsym
83         MRI             in an MRI script
84         VERS_START      starting a Sun style mapfile
85         VERS_SCRIPT     a Sun style mapfile
86         VERS_NODE       a node within a Sun style mapfile
87 */
88 #define RTOKEN(x)  {  yylval.token = x; return x; }
89
90 /* Some versions of flex want this.  */
91 #ifndef yywrap
92 int yywrap (void) { return 1; }
93 #endif
94 %}
95
96 %a 4000
97 %o 5000
98
99 CMDFILENAMECHAR   [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\-\~]
100 CMDFILENAMECHAR1  [_a-zA-Z0-9\/\.\\_\+\$\:\[\]\\\,\=\&\!\<\>\~]
101 FILENAMECHAR1   [_a-zA-Z\/\.\\\$\_\~]
102 SYMBOLCHARN     [_a-zA-Z\/\.\\\$\_\~0-9]
103 FILENAMECHAR    [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~]
104 WILDCHAR        [_a-zA-Z0-9\/\.\-\_\+\=\$\:\[\]\\\,\~\?\*\^\!]
105 WHITE           [ \t\n\r]+
106
107 NOCFILENAMECHAR [_a-zA-Z0-9\/\.\-\_\+\$\:\[\]\\\~]
108
109 V_TAG [.$_a-zA-Z][._a-zA-Z0-9]*
110 V_IDENTIFIER [*?.$_a-zA-Z\[\]\-\!\^\\]([*?.$_a-zA-Z0-9\[\]\-\!\^\\]|::)*
111
112 %s SCRIPT
113 %s EXPRESSION
114 %s BOTH
115 %s DEFSYMEXP
116 %s MRI
117 %s VERS_START
118 %s VERS_SCRIPT
119 %s VERS_NODE
120 %%
121
122   if (parser_input != input_selected)
123     {
124       /* The first token of the input determines the initial parser state.  */
125       input_type t = parser_input;
126       parser_input = input_selected;
127       switch (t)
128         {
129         case input_script: return INPUT_SCRIPT; break;
130         case input_mri_script: return INPUT_MRI_SCRIPT; break;
131         case input_version_script: return INPUT_VERSION_SCRIPT; break;
132         case input_dynamic_list: return INPUT_DYNAMIC_LIST; break;
133         case input_defsym: return INPUT_DEFSYM; break;
134         default: abort ();
135         }
136     }
137
138 <BOTH,SCRIPT,EXPRESSION,VERS_START,VERS_NODE,VERS_SCRIPT>"/*"   { comment (); }
139
140
141 <DEFSYMEXP>"-"                  { RTOKEN('-');}
142 <DEFSYMEXP>"+"                  { RTOKEN('+');}
143 <DEFSYMEXP>{FILENAMECHAR1}{SYMBOLCHARN}*   { yylval.name = xstrdup (yytext); return NAME; }
144 <DEFSYMEXP>"="                  { RTOKEN('='); }
145
146 <MRI,EXPRESSION>"$"([0-9A-Fa-f])+ {
147                                 yylval.integer = bfd_scan_vma (yytext + 1, 0, 16);
148                                 yylval.bigint.str = NULL;
149                                 return INT;
150                         }
151
152 <MRI,EXPRESSION>([0-9A-Fa-f])+(H|h|X|x|B|b|O|o|D|d) {
153                                    int ibase ;
154                                    switch (yytext[yyleng - 1]) {
155                                     case 'X':
156                                     case 'x':
157                                     case 'H':
158                                     case 'h':
159                                      ibase = 16;
160                                      break;
161                                     case 'O':
162                                     case 'o':
163                                      ibase = 8;
164                                      break;
165                                     case 'B':
166                                     case 'b':
167                                      ibase = 2;
168                                      break;
169                                     default:
170                                      ibase = 10;
171                                    }
172                                    yylval.integer = bfd_scan_vma (yytext, 0,
173                                                                   ibase);
174                                    yylval.bigint.str = NULL;
175                                    return INT;
176                                  }
177 <SCRIPT,DEFSYMEXP,MRI,BOTH,EXPRESSION>((("$"|0[xX])([0-9A-Fa-f])+)|(([0-9])+))(M|K|m|k)? {
178                                   char *s = yytext;
179                                   int ibase = 0;
180
181                                   if (*s == '$')
182                                     {
183                                       ++s;
184                                       ibase = 16;
185                                     }
186                                   yylval.integer = bfd_scan_vma (s, 0, ibase);
187                                   yylval.bigint.str = NULL;
188                                   if (yytext[yyleng - 1] == 'M'
189                                       || yytext[yyleng - 1] == 'm')
190                                     {
191                                       yylval.integer *= 1024 * 1024;
192                                     }
193                                   else if (yytext[yyleng - 1] == 'K'
194                                       || yytext[yyleng - 1]=='k')
195                                     {
196                                       yylval.integer *= 1024;
197                                     }
198                                   else if (yytext[0] == '0'
199                                            && (yytext[1] == 'x'
200                                                || yytext[1] == 'X'))
201                                     {
202                                       yylval.bigint.str = xstrdup (yytext + 2);
203                                     }
204                                   return INT;
205                                 }
206 <BOTH,SCRIPT,EXPRESSION,MRI>"]"         { RTOKEN(']');}
207 <BOTH,SCRIPT,EXPRESSION,MRI>"["         { RTOKEN('[');}
208 <BOTH,SCRIPT,EXPRESSION,MRI>"<<="       { RTOKEN(LSHIFTEQ);}
209 <BOTH,SCRIPT,EXPRESSION,MRI>">>="       { RTOKEN(RSHIFTEQ);}
210 <BOTH,SCRIPT,EXPRESSION,MRI>"||"        { RTOKEN(OROR);}
211 <BOTH,SCRIPT,EXPRESSION,MRI>"=="        { RTOKEN(EQ);}
212 <BOTH,SCRIPT,EXPRESSION,MRI>"!="        { RTOKEN(NE);}
213 <BOTH,SCRIPT,EXPRESSION,MRI>">="        { RTOKEN(GE);}
214 <BOTH,SCRIPT,EXPRESSION,MRI>"<="        { RTOKEN(LE);}
215 <BOTH,SCRIPT,EXPRESSION,MRI>"<<"        { RTOKEN(LSHIFT);}
216 <BOTH,SCRIPT,EXPRESSION,MRI>">>"        { RTOKEN(RSHIFT);}
217 <BOTH,SCRIPT,EXPRESSION,MRI>"+="        { RTOKEN(PLUSEQ);}
218 <BOTH,SCRIPT,EXPRESSION,MRI>"-="        { RTOKEN(MINUSEQ);}
219 <BOTH,SCRIPT,EXPRESSION,MRI>"*="        { RTOKEN(MULTEQ);}
220 <BOTH,SCRIPT,EXPRESSION,MRI>"/="        { RTOKEN(DIVEQ);}
221 <BOTH,SCRIPT,EXPRESSION,MRI>"&="        { RTOKEN(ANDEQ);}
222 <BOTH,SCRIPT,EXPRESSION,MRI>"|="        { RTOKEN(OREQ);}
223 <BOTH,SCRIPT,EXPRESSION,MRI>"&&"        { RTOKEN(ANDAND);}
224 <BOTH,SCRIPT,EXPRESSION,MRI>">"         { RTOKEN('>');}
225 <BOTH,SCRIPT,EXPRESSION,MRI>","         { RTOKEN(',');}
226 <BOTH,SCRIPT,EXPRESSION,MRI>"&"         { RTOKEN('&');}
227 <BOTH,SCRIPT,EXPRESSION,MRI>"|"         { RTOKEN('|');}
228 <BOTH,SCRIPT,EXPRESSION,MRI>"~"         { RTOKEN('~');}
229 <BOTH,SCRIPT,EXPRESSION,MRI>"!"         { RTOKEN('!');}
230 <BOTH,SCRIPT,EXPRESSION,MRI>"?"         { RTOKEN('?');}
231 <BOTH,SCRIPT,EXPRESSION,MRI>"*"         { RTOKEN('*');}
232 <BOTH,SCRIPT,EXPRESSION,MRI>"+"         { RTOKEN('+');}
233 <BOTH,SCRIPT,EXPRESSION,MRI>"-"         { RTOKEN('-');}
234 <BOTH,SCRIPT,EXPRESSION,MRI>"/"         { RTOKEN('/');}
235 <BOTH,SCRIPT,EXPRESSION,MRI>"%"         { RTOKEN('%');}
236 <BOTH,SCRIPT,EXPRESSION,MRI>"<"         { RTOKEN('<');}
237 <BOTH,SCRIPT,EXPRESSION,MRI>"="         { RTOKEN('=');}
238 <BOTH,SCRIPT,EXPRESSION,MRI>"}"         { RTOKEN('}') ; }
239 <BOTH,SCRIPT,EXPRESSION,MRI>"{"         { RTOKEN('{'); }
240 <BOTH,SCRIPT,EXPRESSION,MRI>")"         { RTOKEN(')');}
241 <BOTH,SCRIPT,EXPRESSION,MRI>"("         { RTOKEN('(');}
242 <BOTH,SCRIPT,EXPRESSION,MRI>":"         { RTOKEN(':'); }
243 <BOTH,SCRIPT,EXPRESSION,MRI>";"         { RTOKEN(';');}
244 <BOTH,SCRIPT>"MEMORY"                   { RTOKEN(MEMORY);}
245 <BOTH,SCRIPT>"REGION_ALIAS"             { RTOKEN(REGION_ALIAS);}
246 <BOTH,SCRIPT>"LD_FEATURE"               { RTOKEN(LD_FEATURE);}
247 <BOTH,SCRIPT,EXPRESSION>"ORIGIN"        { RTOKEN(ORIGIN);}
248 <BOTH,SCRIPT>"VERSION"                  { RTOKEN(VERSIONK);}
249 <EXPRESSION,BOTH,SCRIPT>"BLOCK"         { RTOKEN(BLOCK);}
250 <EXPRESSION,BOTH,SCRIPT>"BIND"          { RTOKEN(BIND);}
251 <BOTH,SCRIPT,EXPRESSION>"LENGTH"        { RTOKEN(LENGTH);}
252 <EXPRESSION,BOTH,SCRIPT>"ALIGN"         { RTOKEN(ALIGN_K);}
253 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_ALIGN"    { RTOKEN(DATA_SEGMENT_ALIGN);}
254 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_RELRO_END"        { RTOKEN(DATA_SEGMENT_RELRO_END);}
255 <EXPRESSION,BOTH,SCRIPT>"DATA_SEGMENT_END"      { RTOKEN(DATA_SEGMENT_END);}
256 <EXPRESSION,BOTH,SCRIPT>"ADDR"          { RTOKEN(ADDR);}
257 <EXPRESSION,BOTH,SCRIPT>"LOADADDR"      { RTOKEN(LOADADDR);}
258 <EXPRESSION,BOTH,SCRIPT>"ALIGNOF"       { RTOKEN(ALIGNOF); }
259 <EXPRESSION,BOTH>"MAX"                  { RTOKEN(MAX_K); }
260 <EXPRESSION,BOTH>"MIN"                  { RTOKEN(MIN_K); }
261 <EXPRESSION,BOTH,SCRIPT>"ASSERT"        { RTOKEN(ASSERT_K); }
262 <BOTH,SCRIPT>"ENTRY"                    { RTOKEN(ENTRY);}
263 <BOTH,SCRIPT,MRI>"EXTERN"               { RTOKEN(EXTERN);}
264 <EXPRESSION,BOTH,SCRIPT>"NEXT"          { RTOKEN(NEXT);}
265 <EXPRESSION,BOTH,SCRIPT>"sizeof_headers"        { RTOKEN(SIZEOF_HEADERS);}
266 <EXPRESSION,BOTH,SCRIPT>"SIZEOF_HEADERS"        { RTOKEN(SIZEOF_HEADERS);}
267 <EXPRESSION,BOTH,SCRIPT>"SEGMENT_START" { RTOKEN(SEGMENT_START);}
268 <BOTH,SCRIPT>"MAP"                      { RTOKEN(MAP);}
269 <EXPRESSION,BOTH,SCRIPT>"SIZEOF"        { RTOKEN(SIZEOF);}
270 <BOTH,SCRIPT>"TARGET"                   { RTOKEN(TARGET_K);}
271 <BOTH,SCRIPT>"SEARCH_DIR"               { RTOKEN(SEARCH_DIR);}
272 <BOTH,SCRIPT>"OUTPUT"                   { RTOKEN(OUTPUT);}
273 <BOTH,SCRIPT>"INPUT"                    { RTOKEN(INPUT);}
274 <EXPRESSION,BOTH,SCRIPT>"GROUP"         { RTOKEN(GROUP);}
275 <EXPRESSION,BOTH,SCRIPT>"AS_NEEDED"     { RTOKEN(AS_NEEDED);}
276 <EXPRESSION,BOTH,SCRIPT>"DEFINED"       { RTOKEN(DEFINED);}
277 <BOTH,SCRIPT>"CREATE_OBJECT_SYMBOLS"    { RTOKEN(CREATE_OBJECT_SYMBOLS);}
278 <BOTH,SCRIPT>"CONSTRUCTORS"             { RTOKEN( CONSTRUCTORS);}
279 <BOTH,SCRIPT>"FORCE_COMMON_ALLOCATION"  { RTOKEN(FORCE_COMMON_ALLOCATION);}
280 <BOTH,SCRIPT>"INHIBIT_COMMON_ALLOCATION" { RTOKEN(INHIBIT_COMMON_ALLOCATION);}
281 <BOTH,SCRIPT>"SECTIONS"                 { RTOKEN(SECTIONS);}
282 <BOTH,SCRIPT>"INSERT"                   { RTOKEN(INSERT_K);}
283 <BOTH,SCRIPT>"AFTER"                    { RTOKEN(AFTER);}
284 <BOTH,SCRIPT>"BEFORE"                   { RTOKEN(BEFORE);}
285 <BOTH,SCRIPT>"FILL"                     { RTOKEN(FILL);}
286 <BOTH,SCRIPT>"STARTUP"                  { RTOKEN(STARTUP);}
287 <BOTH,SCRIPT>"OUTPUT_FORMAT"            { RTOKEN(OUTPUT_FORMAT);}
288 <BOTH,SCRIPT>"OUTPUT_ARCH"              { RTOKEN( OUTPUT_ARCH);}
289 <BOTH,SCRIPT>"HLL"                      { RTOKEN(HLL);}
290 <BOTH,SCRIPT>"SYSLIB"                   { RTOKEN(SYSLIB);}
291 <BOTH,SCRIPT>"FLOAT"                    { RTOKEN(FLOAT);}
292 <BOTH,SCRIPT>"QUAD"                     { RTOKEN( QUAD);}
293 <BOTH,SCRIPT>"SQUAD"                    { RTOKEN( SQUAD);}
294 <BOTH,SCRIPT>"LONG"                     { RTOKEN( LONG);}
295 <BOTH,SCRIPT>"SHORT"                    { RTOKEN( SHORT);}
296 <BOTH,SCRIPT>"BYTE"                     { RTOKEN( BYTE);}
297 <BOTH,SCRIPT>"NOFLOAT"                  { RTOKEN(NOFLOAT);}
298 <EXPRESSION,BOTH,SCRIPT>"NOCROSSREFS"   { RTOKEN(NOCROSSREFS);}
299 <BOTH,SCRIPT>"OVERLAY"                  { RTOKEN(OVERLAY); }
300 <BOTH,SCRIPT>"SORT_BY_NAME"             { RTOKEN(SORT_BY_NAME); }
301 <BOTH,SCRIPT>"SORT_BY_ALIGNMENT"        { RTOKEN(SORT_BY_ALIGNMENT); }
302 <BOTH,SCRIPT>"SORT"                     { RTOKEN(SORT_BY_NAME); }
303 <EXPRESSION,BOTH,SCRIPT>"NOLOAD"        { RTOKEN(NOLOAD);}
304 <EXPRESSION,BOTH,SCRIPT>"DSECT"         { RTOKEN(DSECT);}
305 <EXPRESSION,BOTH,SCRIPT>"COPY"          { RTOKEN(COPY);}
306 <EXPRESSION,BOTH,SCRIPT>"INFO"          { RTOKEN(INFO);}
307 <EXPRESSION,BOTH,SCRIPT>"OVERLAY"       { RTOKEN(OVERLAY);}
308 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RO"    { RTOKEN(ONLY_IF_RO); }
309 <EXPRESSION,BOTH,SCRIPT>"ONLY_IF_RW"    { RTOKEN(ONLY_IF_RW); }
310 <EXPRESSION,BOTH,SCRIPT>"SPECIAL"       { RTOKEN(SPECIAL); }
311 <BOTH,SCRIPT>"o"                        { RTOKEN(ORIGIN);}
312 <BOTH,SCRIPT>"org"                      { RTOKEN(ORIGIN);}
313 <BOTH,SCRIPT>"l"                        { RTOKEN( LENGTH);}
314 <BOTH,SCRIPT>"len"                      { RTOKEN( LENGTH);}
315 <EXPRESSION,BOTH,SCRIPT>"INCLUDE"       { RTOKEN(INCLUDE);}
316 <BOTH,SCRIPT>"PHDRS"                    { RTOKEN (PHDRS); }
317 <EXPRESSION,BOTH,SCRIPT>"AT"            { RTOKEN(AT);}
318 <EXPRESSION,BOTH,SCRIPT>"SUBALIGN"      { RTOKEN(SUBALIGN);}
319 <EXPRESSION,BOTH,SCRIPT>"PROVIDE"       { RTOKEN(PROVIDE); }
320 <EXPRESSION,BOTH,SCRIPT>"PROVIDE_HIDDEN" { RTOKEN(PROVIDE_HIDDEN); }
321 <EXPRESSION,BOTH,SCRIPT>"KEEP"          { RTOKEN(KEEP); }
322 <EXPRESSION,BOTH,SCRIPT>"EXCLUDE_FILE"  { RTOKEN(EXCLUDE_FILE); }
323 <EXPRESSION,BOTH,SCRIPT>"CONSTANT"      { RTOKEN(CONSTANT);}
324 <MRI>"#".*\n?                   { ++ lineno; }
325 <MRI>"\n"                       { ++ lineno;  RTOKEN(NEWLINE); }
326 <MRI>"*".*                      { /* Mri comment line */ }
327 <MRI>";".*                      { /* Mri comment line */ }
328 <MRI>"END"                      { RTOKEN(ENDWORD); }
329 <MRI>"ALIGNMOD"                 { RTOKEN(ALIGNMOD);}
330 <MRI>"ALIGN"                    { RTOKEN(ALIGN_K);}
331 <MRI>"CHIP"                     { RTOKEN(CHIP); }
332 <MRI>"BASE"                     { RTOKEN(BASE); }
333 <MRI>"ALIAS"                    { RTOKEN(ALIAS); }
334 <MRI>"TRUNCATE"                 { RTOKEN(TRUNCATE); }
335 <MRI>"LOAD"                     { RTOKEN(LOAD); }
336 <MRI>"PUBLIC"                   { RTOKEN(PUBLIC); }
337 <MRI>"ORDER"                    { RTOKEN(ORDER); }
338 <MRI>"NAME"                     { RTOKEN(NAMEWORD); }
339 <MRI>"FORMAT"                   { RTOKEN(FORMAT); }
340 <MRI>"CASE"                     { RTOKEN(CASE); }
341 <MRI>"START"                    { RTOKEN(START); }
342 <MRI>"LIST".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
343 <MRI>"SECT"                     { RTOKEN(SECT); }
344 <EXPRESSION,BOTH,SCRIPT,MRI>"ABSOLUTE"                  { RTOKEN(ABSOLUTE); }
345 <MRI>"end"                      { RTOKEN(ENDWORD); }
346 <MRI>"alignmod"                 { RTOKEN(ALIGNMOD);}
347 <MRI>"align"                    { RTOKEN(ALIGN_K);}
348 <MRI>"chip"                     { RTOKEN(CHIP); }
349 <MRI>"base"                     { RTOKEN(BASE); }
350 <MRI>"alias"                    { RTOKEN(ALIAS); }
351 <MRI>"truncate"                 { RTOKEN(TRUNCATE); }
352 <MRI>"load"                     { RTOKEN(LOAD); }
353 <MRI>"public"                   { RTOKEN(PUBLIC); }
354 <MRI>"order"                    { RTOKEN(ORDER); }
355 <MRI>"name"                     { RTOKEN(NAMEWORD); }
356 <MRI>"format"                   { RTOKEN(FORMAT); }
357 <MRI>"case"                     { RTOKEN(CASE); }
358 <MRI>"extern"                   { RTOKEN(EXTERN); }
359 <MRI>"start"                    { RTOKEN(START); }
360 <MRI>"list".*                   { RTOKEN(LIST); /* LIST and ignore to end of line */ }
361 <MRI>"sect"                     { RTOKEN(SECT); }
362 <EXPRESSION,BOTH,SCRIPT,MRI>"absolute"                  { RTOKEN(ABSOLUTE); }
363
364 <MRI>{FILENAMECHAR1}{NOCFILENAMECHAR}*  {
365 /* Filename without commas, needed to parse mri stuff */
366                                  yylval.name = xstrdup (yytext);
367                                   return NAME;
368                                 }
369
370
371 <BOTH>{FILENAMECHAR1}{FILENAMECHAR}*    {
372                                  yylval.name = xstrdup (yytext);
373                                   return NAME;
374                                 }
375 <BOTH>"-l"{FILENAMECHAR}+ {
376                                   yylval.name = xstrdup (yytext + 2);
377                                   return LNAME;
378                                 }
379 <EXPRESSION>{FILENAMECHAR1}{NOCFILENAMECHAR}*   {
380                                  yylval.name = xstrdup (yytext);
381                                   return NAME;
382                                 }
383 <EXPRESSION>"-l"{NOCFILENAMECHAR}+ {
384                                   yylval.name = xstrdup (yytext + 2);
385                                   return LNAME;
386                                 }
387 <SCRIPT>{WILDCHAR}* {
388                 /* Annoyingly, this pattern can match comments, and we have
389                    longest match issues to consider.  So if the first two
390                    characters are a comment opening, put the input back and
391                    try again.  */
392                 if (yytext[0] == '/' && yytext[1] == '*')
393                   {
394                     yyless (2);
395                     comment ();
396                   }
397                 else
398                   {
399                     yylval.name = xstrdup (yytext);
400                     return NAME;
401                   }
402         }
403
404 <EXPRESSION,BOTH,SCRIPT,VERS_NODE>"\""[^\"]*"\"" {
405                                         /* No matter the state, quotes
406                                            give what's inside */
407                                         yylval.name = xstrdup (yytext + 1);
408                                         yylval.name[yyleng - 2] = 0;
409                                         return NAME;
410                                 }
411 <BOTH,SCRIPT,EXPRESSION>"\n"            { lineno++;}
412 <MRI,BOTH,SCRIPT,EXPRESSION>[ \t\r]+    { }
413
414 <VERS_NODE,VERS_SCRIPT>[:,;]    { return *yytext; }
415
416 <VERS_NODE>global               { RTOKEN(GLOBAL); }
417
418 <VERS_NODE>local                { RTOKEN(LOCAL); }
419
420 <VERS_NODE>extern               { RTOKEN(EXTERN); }
421
422 <VERS_NODE>{V_IDENTIFIER}       { yylval.name = xstrdup (yytext);
423                                   return VERS_IDENTIFIER; }
424
425 <VERS_SCRIPT>{V_TAG}            { yylval.name = xstrdup (yytext);
426                                   return VERS_TAG; }
427
428 <VERS_START>"{"                 { BEGIN(VERS_SCRIPT); return *yytext; }
429
430 <VERS_SCRIPT>"{"                { BEGIN(VERS_NODE);
431                                   vers_node_nesting = 0;
432                                   return *yytext;
433                                 }
434 <VERS_SCRIPT>"}"                { return *yytext; }
435 <VERS_NODE>"{"                  { vers_node_nesting++; return *yytext; }
436 <VERS_NODE>"}"                  { if (--vers_node_nesting < 0)
437                                     BEGIN(VERS_SCRIPT);
438                                   return *yytext;
439                                 }
440
441 <VERS_START,VERS_NODE,VERS_SCRIPT>[\n]          { lineno++; }
442
443 <VERS_START,VERS_NODE,VERS_SCRIPT>#.*           { /* Eat up comments */ }
444
445 <VERS_START,VERS_NODE,VERS_SCRIPT>[ \t\r]+      { /* Eat up whitespace */ }
446
447 <<EOF>> {
448   include_stack_ptr--;
449
450   if (include_stack_ptr == 0)
451   {
452     yyterminate ();
453   }
454   else
455   {
456     yy_switch_to_buffer (include_stack[include_stack_ptr]);
457   }
458
459   ldfile_input_filename = file_name_stack[include_stack_ptr - 1];
460   lineno = lineno_stack[include_stack_ptr];
461
462   return END;
463 }
464
465 <SCRIPT,MRI,VERS_START,VERS_SCRIPT,VERS_NODE>.  lex_warn_invalid (" in script", yytext);
466 <EXPRESSION,DEFSYMEXP,BOTH>.    lex_warn_invalid (" in expression", yytext);
467
468 %%
469 \f
470
471 /* Switch flex to reading script file NAME, open on FILE,
472    saving the current input info on the include stack.  */
473
474 void
475 lex_push_file (FILE *file, const char *name)
476 {
477   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
478     {
479       einfo ("%F:includes nested too deeply\n");
480     }
481   file_name_stack[include_stack_ptr] = name;
482   lineno_stack[include_stack_ptr] = lineno;
483   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
484
485   include_stack_ptr++;
486   lineno = 1;
487   yyin = file;
488   yy_switch_to_buffer (yy_create_buffer (yyin, YY_BUF_SIZE));
489 }
490
491 /* Return a newly created flex input buffer containing STRING,
492    which is SIZE bytes long.  */
493
494 static YY_BUFFER_STATE
495 yy_create_string_buffer (const char *string, size_t size)
496 {
497   YY_BUFFER_STATE b;
498
499   /* Calls to m-alloc get turned by sed into xm-alloc.  */
500   b = malloc (sizeof (struct yy_buffer_state));
501   b->yy_input_file = 0;
502   b->yy_buf_size = size;
503
504   /* yy_ch_buf has to be 2 characters longer than the size given because
505      we need to put in 2 end-of-buffer characters.  */
506   b->yy_ch_buf = malloc ((unsigned) (b->yy_buf_size + 3));
507
508   b->yy_ch_buf[0] = '\n';
509   strcpy (b->yy_ch_buf+1, string);
510   b->yy_ch_buf[size+1] = YY_END_OF_BUFFER_CHAR;
511   b->yy_ch_buf[size+2] = YY_END_OF_BUFFER_CHAR;
512   b->yy_n_chars = size+1;
513   b->yy_buf_pos = &b->yy_ch_buf[1];
514
515   b->yy_is_our_buffer = 1;
516   b->yy_is_interactive = 0;
517   b->yy_at_bol = 1;
518   b->yy_fill_buffer = 0;
519
520   /* flex 2.4.7 changed the interface.  FIXME: We should not be using
521      a flex internal interface in the first place!  */
522 #ifdef YY_BUFFER_NEW
523   b->yy_buffer_status = YY_BUFFER_NEW;
524 #else
525   b->yy_eof_status = EOF_NOT_SEEN;
526 #endif
527
528   return b;
529 }
530
531 /* Switch flex to reading from STRING, saving the current input info
532    on the include stack.  */
533
534 void
535 lex_redirect (const char *string)
536 {
537   YY_BUFFER_STATE tmp;
538
539   yy_init = 0;
540   if (include_stack_ptr >= MAX_INCLUDE_DEPTH)
541     {
542       einfo("%F: macros nested too deeply\n");
543     }
544   file_name_stack[include_stack_ptr] = "redirect";
545   lineno_stack[include_stack_ptr] = lineno;
546   include_stack[include_stack_ptr] = YY_CURRENT_BUFFER;
547   include_stack_ptr++;
548   lineno = 1;
549   tmp = yy_create_string_buffer (string, strlen (string));
550   yy_switch_to_buffer (tmp);
551 }
552 \f
553 /* Functions to switch to a different flex start condition,
554    saving the current start condition on `state_stack'.  */
555
556 static int state_stack[MAX_INCLUDE_DEPTH * 2];
557 static int *state_stack_p = state_stack;
558
559 void
560 ldlex_script (void)
561 {
562   *(state_stack_p)++ = yy_start;
563   BEGIN (SCRIPT);
564 }
565
566 void
567 ldlex_mri_script (void)
568 {
569   *(state_stack_p)++ = yy_start;
570   BEGIN (MRI);
571 }
572
573 void
574 ldlex_version_script (void)
575 {
576   *(state_stack_p)++ = yy_start;
577   BEGIN (VERS_START);
578 }
579
580 void
581 ldlex_version_file (void)
582 {
583   *(state_stack_p)++ = yy_start;
584   BEGIN (VERS_SCRIPT);
585 }
586
587 void
588 ldlex_defsym (void)
589 {
590   *(state_stack_p)++ = yy_start;
591   BEGIN (DEFSYMEXP);
592 }
593
594 void
595 ldlex_expression (void)
596 {
597   *(state_stack_p)++ = yy_start;
598   BEGIN (EXPRESSION);
599 }
600
601 void
602 ldlex_both (void)
603 {
604   *(state_stack_p)++ = yy_start;
605   BEGIN (BOTH);
606 }
607
608 void
609 ldlex_popstate (void)
610 {
611   yy_start = *(--state_stack_p);
612 }
613 \f
614
615 /* Place up to MAX_SIZE characters in BUF and return
616    either the number of characters read, or 0 to indicate EOF.  */
617
618 static int
619 yy_input (char *buf, int max_size)
620 {
621   int result = 0;
622   if (YY_CURRENT_BUFFER->yy_input_file)
623     {
624       if (yyin)
625         {
626           result = fread (buf, 1, max_size, yyin);
627           if (result < max_size && ferror (yyin))
628             einfo ("%F%P: read in flex scanner failed\n");
629         }
630     }
631   return result;
632 }
633
634 /* Eat the rest of a C-style comment.  */
635
636 static void
637 comment (void)
638 {
639   int c;
640
641   while (1)
642   {
643     c = input();
644     while (c != '*' && c != EOF)
645     {
646       if (c == '\n')
647         lineno++;
648       c = input();
649     }
650
651     if (c == '*')
652     {
653       c = input();
654       while (c == '*')
655        c = input();
656       if (c == '/')
657        break;                   /* found the end */
658     }
659
660     if (c == '\n')
661       lineno++;
662
663     if (c == EOF)
664     {
665       einfo( "%F%P: EOF in comment\n");
666       break;
667     }
668   }
669 }
670
671 /* Warn the user about a garbage character WHAT in the input
672    in context WHERE.  */
673
674 static void
675 lex_warn_invalid (char *where, char *what)
676 {
677   char buf[5];
678
679   /* If we have found an input file whose format we do not recognize,
680      and we are therefore treating it as a linker script, and we find
681      an invalid character, then most likely this is a real object file
682      of some different format.  Treat it as such.  */
683   if (ldfile_assumed_script)
684     {
685       bfd_set_error (bfd_error_file_not_recognized);
686       einfo ("%F%s: file not recognized: %E\n", ldfile_input_filename);
687     }
688
689   if (! ISPRINT (*what))
690     {
691       sprintf (buf, "\\%03o", *(unsigned char *) what);
692       what = buf;
693     }
694
695   einfo ("%P:%S: ignoring invalid character `%s'%s\n", what, where);
696 }