sys/platform/pc32/apic/apic_vector.s

   1 /*
   2  *      from: vector.s, 386BSD 0.1 unknown origin
   3  * $FreeBSD: src/sys/i386/isa/apic_vector.s,v 1.47.2.5 2001/09/01 22:33:38 tegge Exp $
   4  * $DragonFly: src/sys/platform/pc32/apic/apic_vector.s,v 1.35 2007/01/08 03:33:42 dillon Exp $
   5  */
   6
   7 #include "use_npx.h"
   8 #include "opt_auto_eoi.h"
   9
  10 #include <machine/asmacros.h>
  11 #include <machine/lock.h>
  12 #include <machine/psl.h>
  13 #include <machine/trap.h>
  14
  15 #include <machine_base/icu/icu.h>
  16 #include <bus/isa/i386/isa.h>
  17
  18 #include "assym.s"
  19
  20 #include "apicreg.h"
  21 #include "apic_ipl.h"
  22 #include <machine/smp.h>
  23 #include <machine_base/isa/intr_machdep.h>
  24
  25 /* convert an absolute IRQ# into a bitmask */
  26 #define IRQ_LBIT(irq_num)       (1 << (irq_num))
  27
  28 /* make an index into the IO APIC from the IRQ# */
  29 #define REDTBL_IDX(irq_num)     (0x10 + ((irq_num) * 2))
  30
  31 #ifdef SMP
  32 #define MPLOCKED     lock ;
  33 #else
  34 #define MPLOCKED
  35 #endif
  36
  37 /*
  38  * Push an interrupt frame in a format acceptable to doreti, reload
  39  * the segment registers for the kernel.
  40  */
  41 #define PUSH_FRAME                                                      \
  42         pushl   $0 ;            /* dummy error code */                  \
  43         pushl   $0 ;            /* dummy trap type */                   \
  44         pushl   $0 ;            /* dummy xflags type */                 \
  45         pushal ;                                                        \
  46         pushl   %ds ;           /* save data and extra segments ... */  \
  47         pushl   %es ;                                                   \
  48         pushl   %fs ;                                                   \
  49         pushl   %gs ;                                                   \
  50         mov     $KDSEL,%ax ;                                            \
  51         mov     %ax,%ds ;                                               \
  52         mov     %ax,%es ;                                               \
  53         mov     %ax,%gs ;                                               \
  54         mov     $KPSEL,%ax ;                                            \
  55         mov     %ax,%fs ;                                               \
  56
  57 #define PUSH_DUMMY                                                      \
  58         pushfl ;                /* phys int frame / flags */            \
  59         pushl %cs ;             /* phys int frame / cs */               \
  60         pushl   12(%esp) ;      /* original caller eip */               \
  61         pushl   $0 ;            /* dummy error code */                  \
  62         pushl   $0 ;            /* dummy trap type */                   \
  63         pushl   $0 ;            /* dummy xflags type */                 \
  64         subl    $13*4,%esp ;    /* pushal + 4 seg regs (dummy) + CPL */ \
  65
  66 /*
  67  * Warning: POP_FRAME can only be used if there is no chance of a
  68  * segment register being changed (e.g. by procfs), which is why syscalls
  69  * have to use doreti.
  70  */
  71 #define POP_FRAME                                                       \
  72         popl    %gs ;                                                   \
  73         popl    %fs ;                                                   \
  74         popl    %es ;                                                   \
  75         popl    %ds ;                                                   \
  76         popal ;                                                         \
  77         addl    $3*4,%esp ;     /* dummy xflags, trap & error codes */  \
  78
  79 #define POP_DUMMY                                                       \
  80         addl    $19*4,%esp ;                                            \
  81
  82 #define IOAPICADDR(irq_num) CNAME(int_to_apicintpin) + 16 * (irq_num) + 8
  83 #define REDIRIDX(irq_num) CNAME(int_to_apicintpin) + 16 * (irq_num) + 12
  84
  85 #define MASK_IRQ(irq_num)                                               \
  86         APIC_IMASK_LOCK ;                       /* into critical reg */ \
  87         testl   $IRQ_LBIT(irq_num), apic_imen ;                         \
  88         jne     7f ;                    /* masked, don't mask */        \
  89         orl     $IRQ_LBIT(irq_num), apic_imen ; /* set the mask bit */  \
  90         movl    IOAPICADDR(irq_num), %ecx ;     /* ioapic addr */       \
  91         movl    REDIRIDX(irq_num), %eax ;       /* get the index */     \
  92         movl    %eax, (%ecx) ;                  /* write the index */   \
  93         movl    IOAPIC_WINDOW(%ecx), %eax ;     /* current value */     \
  94         orl     $IOART_INTMASK, %eax ;          /* set the mask */      \
  95         movl    %eax, IOAPIC_WINDOW(%ecx) ;     /* new value */         \
  96 7: ;                                            /* already masked */    \
  97         APIC_IMASK_UNLOCK ;                                             \
  98
  99 /*
 100  * Test to see whether we are handling an edge or level triggered INT.
 101  *  Level-triggered INTs must still be masked as we don't clear the source,
 102  *  and the EOI cycle would cause redundant INTs to occur.
 103  */
 104 #define MASK_LEVEL_IRQ(irq_num)                                         \
 105         testl   $IRQ_LBIT(irq_num), apic_pin_trigger ;                  \
 106         jz      9f ;                            /* edge, don't mask */  \
 107         MASK_IRQ(irq_num) ;                                             \
 108 9: ;                                                                    \
 109
 110 /*
 111  * Test to see if the source is currntly masked, clear if so.
 112  */
 113 #define UNMASK_IRQ(irq_num)                                     \
 114         cmpl    $0,%eax ;                                               \
 115         jnz     8f ;                                                    \
 116         APIC_IMASK_LOCK ;                       /* into critical reg */ \
 117         testl   $IRQ_LBIT(irq_num), apic_imen ;                         \
 118         je      7f ;                    /* bit clear, not masked */     \
 119         andl    $~IRQ_LBIT(irq_num), apic_imen ;/* clear mask bit */    \
 120         movl    IOAPICADDR(irq_num),%ecx ;      /* ioapic addr */       \
 121         movl    REDIRIDX(irq_num), %eax ;       /* get the index */     \
 122         movl    %eax,(%ecx) ;                   /* write the index */   \
 123         movl    IOAPIC_WINDOW(%ecx),%eax ;      /* current value */     \
 124         andl    $~IOART_INTMASK,%eax ;          /* clear the mask */    \
 125         movl    %eax,IOAPIC_WINDOW(%ecx) ;      /* new value */         \
 126 7: ;                                                                    \
 127         APIC_IMASK_UNLOCK ;                                             \
 128 8: ;                                                                    \
 129
 130 #ifdef APIC_IO
 131
 132 /*
 133  * Fast interrupt call handlers run in the following sequence:
 134  *
 135  *      - Push the trap frame required by doreti
 136  *      - Mask the interrupt and reenable its source
 137  *      - If we cannot take the interrupt set its fpending bit and
 138  *        doreti.  Note that we cannot mess with mp_lock at all
 139  *        if we entered from a critical section!
 140  *      - If we can take the interrupt clear its fpending bit,
 141  *        call the handler, then unmask and doreti.
 142  *
 143  * YYY can cache gd base opitner instead of using hidden %fs prefixes.
 144  */
 145
 146 #define FAST_INTR(irq_num, vec_name)                                    \
 147         .text ;                                                         \
 148         SUPERALIGN_TEXT ;                                               \
 149 IDTVEC(vec_name) ;                                                      \
 150         PUSH_FRAME ;                                                    \
 151         FAKE_MCOUNT(15*4(%esp)) ;                                       \
 152         MASK_LEVEL_IRQ(irq_num) ;                                       \
 153         movl    $0, lapic_eoi ;                                         \
 154         movl    PCPU(curthread),%ebx ;                                  \
 155         movl    $0,%eax ;       /* CURRENT CPL IN FRAME (REMOVED) */    \
 156         pushl   %eax ;                                                  \
 157         cmpl    $TDPRI_CRIT,TD_PRI(%ebx) ;                              \
 158         jl      2f ;                                                    \
 159 1: ;                                                                    \
 160         /* in critical section, make interrupt pending */               \
 161         /* set the pending bit and return, leave interrupt masked */    \
 162         orl     $IRQ_LBIT(irq_num),PCPU(fpending) ;                     \
 163         orl     $RQF_INTPEND,PCPU(reqflags) ;                           \
 164         jmp     5f ;                                                    \
 165 2: ;                                                                    \
 166         /* clear pending bit, run handler */                            \
 167         andl    $~IRQ_LBIT(irq_num),PCPU(fpending) ;                    \
 168         pushl   $irq_num ;                                              \
 169         call    ithread_fast_handler ;   /* returns 0 to unmask */      \
 170         addl    $4, %esp ;                                              \
 171         UNMASK_IRQ(irq_num) ;                                           \
 172 5: ;                                                                    \
 173         MEXITCOUNT ;                                                    \
 174         jmp     doreti ;                                                \
 175
 176 /*
 177  * Slow interrupt call handlers run in the following sequence:
 178  *
 179  *      - Push the trap frame required by doreti.
 180  *      - Mask the interrupt and reenable its source.
 181  *      - If we cannot take the interrupt set its ipending bit and
 182  *        doreti.  In addition to checking for a critical section
 183  *        and cpl mask we also check to see if the thread is still
 184  *        running.  Note that we cannot mess with mp_lock at all
 185  *        if we entered from a critical section!
 186  *      - If we can take the interrupt clear its ipending bit
 187  *        and schedule the thread.  Leave interrupts masked and doreti.
 188  *
 189  *      Note that calls to sched_ithd() are made with interrupts enabled
 190  *      and outside a critical section.  YYY sched_ithd may preempt us
 191  *      synchronously (fix interrupt stacking).
 192  *
 193  *      YYY can cache gd base pointer instead of using hidden %fs
 194  *      prefixes.
 195  */
 196
 197 #define SLOW_INTR(irq_num, vec_name, maybe_extra_ipending)              \
 198         .text ;                                                         \
 199         SUPERALIGN_TEXT ;                                               \
 200 IDTVEC(vec_name) ;                                                      \
 201         PUSH_FRAME ;                                                    \
 202         maybe_extra_ipending ;                                          \
 203 ;                                                                       \
 204         MASK_LEVEL_IRQ(irq_num) ;                                       \
 205         incl    PCPU(cnt) + V_INTR ;                                    \
 206         movl    $0, lapic_eoi ;                                         \
 207         movl    PCPU(curthread),%ebx ;                                  \
 208         movl    $0,%eax ;       /* CURRENT CPL IN FRAME (REMOVED) */    \
 209         pushl   %eax ;          /* cpl do restore */                    \
 210         cmpl    $TDPRI_CRIT,TD_PRI(%ebx) ;                              \
 211         jl      2f ;                                                    \
 212 1: ;                                                                    \
 213         /* set the pending bit and return, leave the interrupt masked */ \
 214         orl     $IRQ_LBIT(irq_num), PCPU(ipending) ;                    \
 215         orl     $RQF_INTPEND,PCPU(reqflags) ;                           \
 216         jmp     5f ;                                                    \
 217 2: ;                                                                    \
 218         /* set running bit, clear pending bit, run handler */           \
 219         andl    $~IRQ_LBIT(irq_num), PCPU(ipending) ;                   \
 220         sti ;                                                           \
 221         pushl   $irq_num ;                                              \
 222         call    sched_ithd ;                                            \
 223         addl    $4,%esp ;                                               \
 224 5: ;                                                                    \
 225         MEXITCOUNT ;                                                    \
 226         jmp     doreti ;                                                \
 227
 228 /*
 229  * Wrong interrupt call handlers.  We program these into APIC vectors
 230  * that should otherwise never occur.  For example, we program the SLOW
 231  * vector for irq N with this when we program the FAST vector with the
 232  * real interrupt.
 233  *
 234  * XXX for now all we can do is EOI it.  We can't call do_wrongintr
 235  * (yet) because we could be in a critical section.
 236  */
 237 #define WRONGINTR(irq_num,vec_name)                                     \
 238         .text ;                                                         \
 239         SUPERALIGN_TEXT  ;                                              \
 240 IDTVEC(vec_name) ;                                                      \
 241         PUSH_FRAME ;                                                    \
 242         movl    $0, lapic_eoi ; /* End Of Interrupt to APIC */          \
 243         /*pushl $irq_num ;*/                                            \
 244         /*call  do_wrongintr ;*/                                        \
 245         /*addl  $4,%esp ;*/                                             \
 246         POP_FRAME ;                                                     \
 247         iret  ;                                                         \
 248
 249 #endif
 250
 251 /*
 252  * Handle "spurious INTerrupts".
 253  * Notes:
 254  *  This is different than the "spurious INTerrupt" generated by an
 255  *   8259 PIC for missing INTs.  See the APIC documentation for details.
 256  *  This routine should NOT do an 'EOI' cycle.
 257  */
 258         .text
 259         SUPERALIGN_TEXT
 260         .globl Xspuriousint
 261 Xspuriousint:
 262
 263         /* No EOI cycle used here */
 264
 265         iret
 266
 267
 268 /*
 269  * Handle TLB shootdowns.
 270  */
 271         .text
 272         SUPERALIGN_TEXT
 273         .globl  Xinvltlb
 274 Xinvltlb:
 275         pushl   %eax
 276
 277         movl    %cr3, %eax              /* invalidate the TLB */
 278         movl    %eax, %cr3
 279
 280         ss                              /* stack segment, avoid %ds load */
 281         movl    $0, lapic_eoi           /* End Of Interrupt to APIC */
 282
 283         popl    %eax
 284         iret
 285
 286
 287 /*
 288  * Executed by a CPU when it receives an Xcpustop IPI from another CPU,
 289  *
 290  *  - Signals its receipt.
 291  *  - Waits for permission to restart.
 292  *  - Processing pending IPIQ events while waiting.
 293  *  - Signals its restart.
 294  */
 295
 296         .text
 297         SUPERALIGN_TEXT
 298         .globl Xcpustop
 299 Xcpustop:
 300         pushl   %ebp
 301         movl    %esp, %ebp
 302         pushl   %eax
 303         pushl   %ecx
 304         pushl   %edx
 305         pushl   %ds                     /* save current data segment */
 306         pushl   %fs
 307
 308         movl    $KDSEL, %eax
 309         mov     %ax, %ds                /* use KERNEL data segment */
 310         movl    $KPSEL, %eax
 311         mov     %ax, %fs
 312
 313         movl    $0, lapic_eoi           /* End Of Interrupt to APIC */
 314
 315         movl    PCPU(cpuid), %eax
 316         imull   $PCB_SIZE, %eax
 317         leal    CNAME(stoppcbs)(%eax), %eax
 318         pushl   %eax
 319         call    CNAME(savectx)          /* Save process context */
 320         addl    $4, %esp
 321
 322
 323         movl    PCPU(cpuid), %eax
 324
 325         /*
 326          * Indicate that we have stopped and loop waiting for permission
 327          * to start again.  We must still process IPI events while in a
 328          * stopped state.
 329          */
 330         MPLOCKED
 331         btsl    %eax, stopped_cpus      /* stopped_cpus |= (1<<id) */
 332 1:
 333         andl    $~RQF_IPIQ,PCPU(reqflags)
 334         pushl   %eax
 335         call    lwkt_smp_stopped
 336         popl    %eax
 337         btl     %eax, started_cpus      /* while (!(started_cpus & (1<<id))) */
 338         jnc     1b
 339
 340         MPLOCKED
 341         btrl    %eax, started_cpus      /* started_cpus &= ~(1<<id) */
 342         MPLOCKED
 343         btrl    %eax, stopped_cpus      /* stopped_cpus &= ~(1<<id) */
 344
 345         test    %eax, %eax
 346         jnz     2f
 347
 348         movl    CNAME(cpustop_restartfunc), %eax
 349         test    %eax, %eax
 350         jz      2f
 351         movl    $0, CNAME(cpustop_restartfunc)  /* One-shot */
 352
 353         call    *%eax
 354 2:
 355         popl    %fs
 356         popl    %ds                     /* restore previous data segment */
 357         popl    %edx
 358         popl    %ecx
 359         popl    %eax
 360         movl    %ebp, %esp
 361         popl    %ebp
 362         iret
 363
 364         /*
 365          * For now just have one ipiq IPI, but what we really want is
 366          * to have one for each source cpu to the APICs don't get stalled
 367          * backlogging the requests.
 368          */
 369         .text
 370         SUPERALIGN_TEXT
 371         .globl Xipiq
 372 Xipiq:
 373         PUSH_FRAME
 374         movl    $0, lapic_eoi           /* End Of Interrupt to APIC */
 375         FAKE_MCOUNT(15*4(%esp))
 376
 377         movl    PCPU(curthread),%ebx
 378         cmpl    $TDPRI_CRIT,TD_PRI(%ebx)
 379         jge     1f
 380         subl    $8,%esp                 /* make same as interrupt frame */
 381         incl    PCPU(intr_nesting_level)
 382         addl    $TDPRI_CRIT,TD_PRI(%ebx)
 383         call    lwkt_process_ipiq_frame
 384         subl    $TDPRI_CRIT,TD_PRI(%ebx)
 385         decl    PCPU(intr_nesting_level)
 386         addl    $8,%esp
 387         pushl   $0                      /* CPL for frame (REMOVED) */
 388         MEXITCOUNT
 389         jmp     doreti
 390 1:
 391         orl     $RQF_IPIQ,PCPU(reqflags)
 392         MEXITCOUNT
 393         POP_FRAME
 394         iret
 395
 396 #ifdef APIC_IO
 397
 398 MCOUNT_LABEL(bintr)
 399         FAST_INTR(0,apic_fastintr0)
 400         FAST_INTR(1,apic_fastintr1)
 401         FAST_INTR(2,apic_fastintr2)
 402         FAST_INTR(3,apic_fastintr3)
 403         FAST_INTR(4,apic_fastintr4)
 404         FAST_INTR(5,apic_fastintr5)
 405         FAST_INTR(6,apic_fastintr6)
 406         FAST_INTR(7,apic_fastintr7)
 407         FAST_INTR(8,apic_fastintr8)
 408         FAST_INTR(9,apic_fastintr9)
 409         FAST_INTR(10,apic_fastintr10)
 410         FAST_INTR(11,apic_fastintr11)
 411         FAST_INTR(12,apic_fastintr12)
 412         FAST_INTR(13,apic_fastintr13)
 413         FAST_INTR(14,apic_fastintr14)
 414         FAST_INTR(15,apic_fastintr15)
 415         FAST_INTR(16,apic_fastintr16)
 416         FAST_INTR(17,apic_fastintr17)
 417         FAST_INTR(18,apic_fastintr18)
 418         FAST_INTR(19,apic_fastintr19)
 419         FAST_INTR(20,apic_fastintr20)
 420         FAST_INTR(21,apic_fastintr21)
 421         FAST_INTR(22,apic_fastintr22)
 422         FAST_INTR(23,apic_fastintr23)
 423
 424         /* YYY what is this garbage? */
 425
 426         SLOW_INTR(0,apic_slowintr0,)
 427         SLOW_INTR(1,apic_slowintr1,)
 428         SLOW_INTR(2,apic_slowintr2,)
 429         SLOW_INTR(3,apic_slowintr3,)
 430         SLOW_INTR(4,apic_slowintr4,)
 431         SLOW_INTR(5,apic_slowintr5,)
 432         SLOW_INTR(6,apic_slowintr6,)
 433         SLOW_INTR(7,apic_slowintr7,)
 434         SLOW_INTR(8,apic_slowintr8,)
 435         SLOW_INTR(9,apic_slowintr9,)
 436         SLOW_INTR(10,apic_slowintr10,)
 437         SLOW_INTR(11,apic_slowintr11,)
 438         SLOW_INTR(12,apic_slowintr12,)
 439         SLOW_INTR(13,apic_slowintr13,)
 440         SLOW_INTR(14,apic_slowintr14,)
 441         SLOW_INTR(15,apic_slowintr15,)
 442         SLOW_INTR(16,apic_slowintr16,)
 443         SLOW_INTR(17,apic_slowintr17,)
 444         SLOW_INTR(18,apic_slowintr18,)
 445         SLOW_INTR(19,apic_slowintr19,)
 446         SLOW_INTR(20,apic_slowintr20,)
 447         SLOW_INTR(21,apic_slowintr21,)
 448         SLOW_INTR(22,apic_slowintr22,)
 449         SLOW_INTR(23,apic_slowintr23,)
 450
 451         WRONGINTR(0,apic_wrongintr0)
 452         WRONGINTR(1,apic_wrongintr1)
 453         WRONGINTR(2,apic_wrongintr2)
 454         WRONGINTR(3,apic_wrongintr3)
 455         WRONGINTR(4,apic_wrongintr4)
 456         WRONGINTR(5,apic_wrongintr5)
 457         WRONGINTR(6,apic_wrongintr6)
 458         WRONGINTR(7,apic_wrongintr7)
 459         WRONGINTR(8,apic_wrongintr8)
 460         WRONGINTR(9,apic_wrongintr9)
 461         WRONGINTR(10,apic_wrongintr10)
 462         WRONGINTR(11,apic_wrongintr11)
 463         WRONGINTR(12,apic_wrongintr12)
 464         WRONGINTR(13,apic_wrongintr13)
 465         WRONGINTR(14,apic_wrongintr14)
 466         WRONGINTR(15,apic_wrongintr15)
 467         WRONGINTR(16,apic_wrongintr16)
 468         WRONGINTR(17,apic_wrongintr17)
 469         WRONGINTR(18,apic_wrongintr18)
 470         WRONGINTR(19,apic_wrongintr19)
 471         WRONGINTR(20,apic_wrongintr20)
 472         WRONGINTR(21,apic_wrongintr21)
 473         WRONGINTR(22,apic_wrongintr22)
 474         WRONGINTR(23,apic_wrongintr23)
 475 MCOUNT_LABEL(eintr)
 476
 477 #endif
 478
 479         .data
 480
 481 /* variables used by stop_cpus()/restart_cpus()/Xcpustop */
 482         .globl stopped_cpus, started_cpus
 483 stopped_cpus:
 484         .long   0
 485 started_cpus:
 486         .long   0
 487
 488         .globl CNAME(cpustop_restartfunc)
 489 CNAME(cpustop_restartfunc):
 490         .long 0
 491
 492         .globl  apic_pin_trigger
 493 apic_pin_trigger:
 494         .long   0
 495
 496         .text
 497