sys/platform/pc32/i386/swtch.s

   1 /*
   2  * Copyright (c) 2003,2004 The DragonFly Project.  All rights reserved.
   3  *
   4  * This code is derived from software contributed to The DragonFly Project
   5  * by Matthew Dillon <dillon@backplane.com>
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  *
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in
  15  *    the documentation and/or other materials provided with the
  16  *    distribution.
  17  * 3. Neither the name of The DragonFly Project nor the names of its
  18  *    contributors may be used to endorse or promote products derived
  19  *    from this software without specific, prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  22  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  23  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  24  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  25  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  26  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  27  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  28  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  29  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  30  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  31  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  * Copyright (c) 1990 The Regents of the University of California.
  35  * All rights reserved.
  36  *
  37  * This code is derived from software contributed to Berkeley by
  38  * William Jolitz.
  39  *
  40  * Redistribution and use in source and binary forms, with or without
  41  * modification, are permitted provided that the following conditions
  42  * are met:
  43  * 1. Redistributions of source code must retain the above copyright
  44  *    notice, this list of conditions and the following disclaimer.
  45  * 2. Redistributions in binary form must reproduce the above copyright
  46  *    notice, this list of conditions and the following disclaimer in the
  47  *    documentation and/or other materials provided with the distribution.
  48  * 3. All advertising materials mentioning features or use of this software
  49  *    must display the following acknowledgement:
  50  *      This product includes software developed by the University of
  51  *      California, Berkeley and its contributors.
  52  * 4. Neither the name of the University nor the names of its contributors
  53  *    may be used to endorse or promote products derived from this software
  54  *    without specific prior written permission.
  55  *
  56  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  57  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  58  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  59  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  60  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  61  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  62  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  63  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  64  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  65  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  66  * SUCH DAMAGE.
  67  *
  68  * $FreeBSD: src/sys/i386/i386/swtch.s,v 1.89.2.10 2003/01/23 03:36:24 ps Exp $
  69  * $DragonFly: src/sys/platform/pc32/i386/swtch.s,v 1.43 2007/01/08 03:33:42 dillon Exp $
  70  */
  71
  72 #include "use_npx.h"
  73
  74 #include <sys/rtprio.h>
  75
  76 #include <machine/asmacros.h>
  77 #include <machine/segments.h>
  78
  79 #include <machine/pmap.h>
  80 #include <machine_base/apic/apicreg.h>
  81 #include <machine/lock.h>
  82
  83 #include "assym.s"
  84
  85 #if defined(SMP)
  86 #define MPLOCKED        lock ;
  87 #else
  88 #define MPLOCKED
  89 #endif
  90
  91         .data
  92
  93         .globl  panic
  94
  95 #if defined(SWTCH_OPTIM_STATS)
  96         .globl  swtch_optim_stats, tlb_flush_count
  97 swtch_optim_stats:      .long   0               /* number of _swtch_optims */
  98 tlb_flush_count:        .long   0
  99 #endif
 100
 101         .text
 102
 103
 104 /*
 105  * cpu_heavy_switch(next_thread)
 106  *
 107  *      Switch from the current thread to a new thread.  This entry
 108  *      is normally called via the thread->td_switch function, and will
 109  *      only be called when the current thread is a heavy weight process.
 110  *
 111  *      Some instructions have been reordered to reduce pipeline stalls.
 112  *
 113  *      YYY disable interrupts once giant is removed.
 114  */
 115 ENTRY(cpu_heavy_switch)
 116         /*
 117          * Save general regs
 118          */
 119         movl    PCPU(curthread),%ecx
 120         movl    (%esp),%eax                     /* (reorder optimization) */
 121         movl    TD_PCB(%ecx),%edx               /* EDX = PCB */
 122         movl    %eax,PCB_EIP(%edx)              /* return PC may be modified */
 123         movl    %ebx,PCB_EBX(%edx)
 124         movl    %esp,PCB_ESP(%edx)
 125         movl    %ebp,PCB_EBP(%edx)
 126         movl    %esi,PCB_ESI(%edx)
 127         movl    %edi,PCB_EDI(%edx)
 128
 129         movl    %ecx,%ebx                       /* EBX = curthread */
 130         movl    TD_PROC(%ecx),%ecx
 131         movl    PCPU(cpuid), %eax
 132         movl    P_VMSPACE(%ecx), %ecx           /* ECX = vmspace */
 133         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%ecx)
 134
 135         /*
 136          * Push the LWKT switch restore function, which resumes a heavy
 137          * weight process.  Note that the LWKT switcher is based on
 138          * TD_SP, while the heavy weight process switcher is based on
 139          * PCB_ESP.  TD_SP is usually two ints pushed relative to
 140          * PCB_ESP.  We push the flags for later restore by cpu_heavy_restore.
 141          */
 142         pushfl
 143         pushl   $cpu_heavy_restore
 144         movl    %esp,TD_SP(%ebx)
 145
 146         /*
 147          * Save debug regs if necessary
 148          */
 149         movb    PCB_FLAGS(%edx),%al
 150         andb    $PCB_DBREGS,%al
 151         jz      1f                              /* no, skip over */
 152         movl    %dr7,%eax                       /* yes, do the save */
 153         movl    %eax,PCB_DR7(%edx)
 154         andl    $0x0000fc00, %eax               /* disable all watchpoints */
 155         movl    %eax,%dr7
 156         movl    %dr6,%eax
 157         movl    %eax,PCB_DR6(%edx)
 158         movl    %dr3,%eax
 159         movl    %eax,PCB_DR3(%edx)
 160         movl    %dr2,%eax
 161         movl    %eax,PCB_DR2(%edx)
 162         movl    %dr1,%eax
 163         movl    %eax,PCB_DR1(%edx)
 164         movl    %dr0,%eax
 165         movl    %eax,PCB_DR0(%edx)
 166 1:
 167
 168 #if NNPX > 0
 169         /*
 170          * Save the FP state if we have used the FP.  Note that calling
 171          * npxsave will NULL out PCPU(npxthread).
 172          */
 173         cmpl    %ebx,PCPU(npxthread)
 174         jne     1f
 175         pushl   TD_SAVEFPU(%ebx)
 176         call    npxsave                 /* do it in a big C function */
 177         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 178 1:
 179 #endif  /* NNPX > 0 */
 180
 181         /*
 182          * Switch to the next thread, which was passed as an argument
 183          * to cpu_heavy_switch().  Due to the eflags and switch-restore
 184          * function we pushed, the argument is at 12(%esp).  Set the current
 185          * thread, load the stack pointer, and 'ret' into the switch-restore
 186          * function.
 187          *
 188          * The switch restore function expects the new thread to be in %eax
 189          * and the old one to be in %ebx.
 190          *
 191          * There is a one-instruction window where curthread is the new
 192          * thread but %esp still points to the old thread's stack, but
 193          * we are protected by a critical section so it is ok.
 194          */
 195         movl    12(%esp),%eax           /* EAX = newtd, EBX = oldtd */
 196         movl    %eax,PCPU(curthread)
 197         movl    TD_SP(%eax),%esp
 198         ret
 199
 200 /*
 201  *  cpu_exit_switch()
 202  *
 203  *      The switch function is changed to this when a thread is going away
 204  *      for good.  We have to ensure that the MMU state is not cached, and
 205  *      we don't bother saving the existing thread state before switching.
 206  *
 207  *      At this point we are in a critical section and this cpu owns the
 208  *      thread's token, which serves as an interlock until the switchout is
 209  *      complete.
 210  */
 211 ENTRY(cpu_exit_switch)
 212         /*
 213          * Get us out of the vmspace
 214          */
 215         movl    IdlePTD,%ecx
 216         movl    %cr3,%eax
 217         cmpl    %ecx,%eax
 218         je      1f
 219         movl    %ecx,%cr3
 220 1:
 221         movl    PCPU(curthread),%ebx
 222         /*
 223          * Switch to the next thread.  RET into the restore function, which
 224          * expects the new thread in EAX and the old in EBX.
 225          *
 226          * There is a one-instruction window where curthread is the new
 227          * thread but %esp still points to the old thread's stack, but
 228          * we are protected by a critical section so it is ok.
 229          */
 230         movl    4(%esp),%eax
 231         movl    %eax,PCPU(curthread)
 232         movl    TD_SP(%eax),%esp
 233         ret
 234
 235 /*
 236  * cpu_heavy_restore()  (current thread in %eax on entry)
 237  *
 238  *      Restore the thread after an LWKT switch.  This entry is normally
 239  *      called via the LWKT switch restore function, which was pulled
 240  *      off the thread stack and jumped to.
 241  *
 242  *      This entry is only called if the thread was previously saved
 243  *      using cpu_heavy_switch() (the heavy weight process thread switcher),
 244  *      or when a new process is initially scheduled.  The first thing we
 245  *      do is clear the TDF_RUNNING bit in the old thread and set it in the
 246  *      new thread.
 247  *
 248  *      NOTE: The process may be in any state, not necessarily SRUN, because
 249  *      a preemption switch may interrupt the process and then return via
 250  *      cpu_heavy_restore.
 251  *
 252  *      YYY theoretically we do not have to restore everything here, a lot
 253  *      of this junk can wait until we return to usermode.  But for now
 254  *      we restore everything.
 255  *
 256  *      YYY the PCB crap is really crap, it makes startup a bitch because
 257  *      we can't switch away.
 258  *
 259  *      YYY note: spl check is done in mi_switch when it splx()'s.
 260  */
 261
 262 ENTRY(cpu_heavy_restore)
 263         popfl
 264         movl    TD_PCB(%eax),%edx               /* EDX = PCB */
 265         movl    TD_PROC(%eax),%ecx
 266
 267 #if defined(SWTCH_OPTIM_STATS)
 268         incl    _swtch_optim_stats
 269 #endif
 270         /*
 271          * Tell the pmap that our cpu is using the VMSPACE now.  We cannot
 272          * safely test/reload %cr3 until after we have set the bit in the
 273          * pmap (remember, we do not hold the MP lock in the switch code).
 274          */
 275         movl    P_VMSPACE(%ecx), %ecx           /* ECX = vmspace */
 276         movl    PCPU(cpuid), %esi
 277         MPLOCKED btsl   %esi, VM_PMAP+PM_ACTIVE(%ecx)
 278
 279         /*
 280          * Restore the MMU address space.  If it is the same as the last
 281          * thread we don't have to invalidate the tlb (i.e. reload cr3).
 282          * YYY which naturally also means that the PM_ACTIVE bit had better
 283          * already have been set before we set it above, check? YYY
 284          */
 285         movl    %cr3,%esi
 286         movl    PCB_CR3(%edx),%ecx
 287         cmpl    %esi,%ecx
 288         je      4f
 289 #if defined(SWTCH_OPTIM_STATS)
 290         decl    _swtch_optim_stats
 291         incl    _tlb_flush_count
 292 #endif
 293         movl    %ecx,%cr3
 294 4:
 295         /*
 296          * Clear TDF_RUNNING flag in old thread only after cleaning up
 297          * %cr3.  The target thread is already protected by being TDF_RUNQ
 298          * so setting TDF_RUNNING isn't as big a deal.
 299          */
 300         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 301         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 302
 303         /*
 304          * Deal with the PCB extension, restore the private tss
 305          */
 306         movl    PCB_EXT(%edx),%edi      /* check for a PCB extension */
 307         movl    $1,%ebx                 /* maybe mark use of a private tss */
 308         testl   %edi,%edi
 309         jnz     2f
 310
 311         /*
 312          * Going back to the common_tss.  We may need to update TSS_ESP0
 313          * which sets the top of the supervisor stack when entering from
 314          * usermode.  The PCB is at the top of the stack but we need another
 315          * 16 bytes to take vm86 into account.
 316          */
 317         leal    -16(%edx),%ebx
 318         movl    %ebx, PCPU(common_tss) + TSS_ESP0
 319
 320         cmpl    $0,PCPU(private_tss)    /* don't have to reload if      */
 321         je      3f                      /* already using the common TSS */
 322
 323         subl    %ebx,%ebx               /* unmark use of private tss */
 324
 325         /*
 326          * Get the address of the common TSS descriptor for the ltr.
 327          * There is no way to get the address of a segment-accessed variable
 328          * so we store a self-referential pointer at the base of the per-cpu
 329          * data area and add the appropriate offset.
 330          */
 331         movl    $gd_common_tssd, %edi
 332         addl    %fs:0, %edi
 333
 334         /*
 335          * Move the correct TSS descriptor into the GDT slot, then reload
 336          * ltr.
 337          */
 338 2:
 339         movl    %ebx,PCPU(private_tss)          /* mark/unmark private tss */
 340         movl    PCPU(tss_gdt), %ebx             /* entry in GDT */
 341         movl    0(%edi), %eax
 342         movl    %eax, 0(%ebx)
 343         movl    4(%edi), %eax
 344         movl    %eax, 4(%ebx)
 345         movl    $GPROC0_SEL*8, %esi             /* GSEL(entry, SEL_KPL) */
 346         ltr     %si
 347
 348 3:
 349         /*
 350          * Restore general registers.
 351          */
 352         movl    PCB_EBX(%edx),%ebx
 353         movl    PCB_ESP(%edx),%esp
 354         movl    PCB_EBP(%edx),%ebp
 355         movl    PCB_ESI(%edx),%esi
 356         movl    PCB_EDI(%edx),%edi
 357         movl    PCB_EIP(%edx),%eax
 358         movl    %eax,(%esp)
 359
 360         /*
 361          * Restore the user LDT if we have one
 362          */
 363         cmpl    $0, PCB_USERLDT(%edx)
 364         jnz     1f
 365         movl    _default_ldt,%eax
 366         cmpl    PCPU(currentldt),%eax
 367         je      2f
 368         lldt    _default_ldt
 369         movl    %eax,PCPU(currentldt)
 370         jmp     2f
 371 1:      pushl   %edx
 372         call    set_user_ldt
 373         popl    %edx
 374 2:
 375         /*
 376          * Restore the user TLS if we have one
 377          */
 378         pushl   %edx
 379         call    set_user_TLS
 380         popl    %edx
 381
 382         /*
 383          * Restore the DEBUG register state if necessary.
 384          */
 385         movb    PCB_FLAGS(%edx),%al
 386         andb    $PCB_DBREGS,%al
 387         jz      1f                              /* no, skip over */
 388         movl    PCB_DR6(%edx),%eax              /* yes, do the restore */
 389         movl    %eax,%dr6
 390         movl    PCB_DR3(%edx),%eax
 391         movl    %eax,%dr3
 392         movl    PCB_DR2(%edx),%eax
 393         movl    %eax,%dr2
 394         movl    PCB_DR1(%edx),%eax
 395         movl    %eax,%dr1
 396         movl    PCB_DR0(%edx),%eax
 397         movl    %eax,%dr0
 398         movl    %dr7,%eax                /* load dr7 so as not to disturb */
 399         andl    $0x0000fc00,%eax         /*   reserved bits               */
 400         pushl   %ebx
 401         movl    PCB_DR7(%edx),%ebx
 402         andl    $~0x0000fc00,%ebx
 403         orl     %ebx,%eax
 404         popl    %ebx
 405         movl    %eax,%dr7
 406 1:
 407
 408         ret
 409
 410 /*
 411  * savectx(pcb)
 412  *
 413  * Update pcb, saving current processor state.
 414  */
 415 ENTRY(savectx)
 416         /* fetch PCB */
 417         movl    4(%esp),%ecx
 418
 419         /* caller's return address - child won't execute this routine */
 420         movl    (%esp),%eax
 421         movl    %eax,PCB_EIP(%ecx)
 422
 423         movl    %cr3,%eax
 424         movl    %eax,PCB_CR3(%ecx)
 425
 426         movl    %ebx,PCB_EBX(%ecx)
 427         movl    %esp,PCB_ESP(%ecx)
 428         movl    %ebp,PCB_EBP(%ecx)
 429         movl    %esi,PCB_ESI(%ecx)
 430         movl    %edi,PCB_EDI(%ecx)
 431
 432 #if NNPX > 0
 433         /*
 434          * If npxthread == NULL, then the npx h/w state is irrelevant and the
 435          * state had better already be in the pcb.  This is true for forks
 436          * but not for dumps (the old book-keeping with FP flags in the pcb
 437          * always lost for dumps because the dump pcb has 0 flags).
 438          *
 439          * If npxthread != NULL, then we have to save the npx h/w state to
 440          * npxthread's pcb and copy it to the requested pcb, or save to the
 441          * requested pcb and reload.  Copying is easier because we would
 442          * have to handle h/w bugs for reloading.  We used to lose the
 443          * parent's npx state for forks by forgetting to reload.
 444          */
 445         movl    PCPU(npxthread),%eax
 446         testl   %eax,%eax
 447         je      1f
 448
 449         pushl   %ecx                    /* target pcb */
 450         movl    TD_SAVEFPU(%eax),%eax   /* originating savefpu area */
 451         pushl   %eax
 452
 453         pushl   %eax
 454         call    npxsave
 455         addl    $4,%esp
 456
 457         popl    %eax
 458         popl    %ecx
 459
 460         pushl   $PCB_SAVEFPU_SIZE
 461         leal    PCB_SAVEFPU(%ecx),%ecx
 462         pushl   %ecx
 463         pushl   %eax
 464         call    bcopy
 465         addl    $12,%esp
 466 #endif  /* NNPX > 0 */
 467
 468 1:
 469         ret
 470
 471 /*
 472  * cpu_idle_restore()   (current thread in %eax on entry) (one-time execution)
 473  *
 474  *      Don't bother setting up any regs other then %ebp so backtraces
 475  *      don't die.  This restore function is used to bootstrap into the
 476  *      cpu_idle() LWKT only, after that cpu_lwkt_*() will be used for
 477  *      switching.
 478  *
 479  *      Clear TDF_RUNNING in old thread only after we've cleaned up %cr3.
 480  *
 481  *      If we are an AP we have to call ap_init() before jumping to
 482  *      cpu_idle().  ap_init() will synchronize with the BP and finish
 483  *      setting up various ncpu-dependant globaldata fields.  This may
 484  *      happen on UP as well as SMP if we happen to be simulating multiple
 485  *      cpus.
 486  */
 487 ENTRY(cpu_idle_restore)
 488         /* cli */
 489         movl    IdlePTD,%ecx
 490         movl    $0,%ebp
 491         pushl   $0
 492         movl    %ecx,%cr3
 493         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 494         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 495 #ifdef SMP
 496         cmpl    $0,PCPU(cpuid)
 497         je      1f
 498         call    ap_init
 499 1:
 500 #endif
 501         sti
 502         jmp     cpu_idle
 503
 504 /*
 505  * cpu_kthread_restore() (current thread is %eax on entry) (one-time execution)
 506  *
 507  *      Don't bother setting up any regs other then %ebp so backtraces
 508  *      don't die.  This restore function is used to bootstrap into an
 509  *      LWKT based kernel thread only.  cpu_lwkt_switch() will be used
 510  *      after this.
 511  *
 512  *      Since all of our context is on the stack we are reentrant and
 513  *      we can release our critical section and enable interrupts early.
 514  */
 515 ENTRY(cpu_kthread_restore)
 516         sti
 517         movl    IdlePTD,%ecx
 518         movl    TD_PCB(%eax),%edx
 519         movl    $0,%ebp
 520         movl    %ecx,%cr3
 521         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 522         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 523         subl    $TDPRI_CRIT,TD_PRI(%eax)
 524         popl    %eax            /* kthread exit function */
 525         pushl   PCB_EBX(%edx)   /* argument to ESI function */
 526         pushl   %eax            /* set exit func as return address */
 527         movl    PCB_ESI(%edx),%eax
 528         jmp     *%eax
 529
 530 /*
 531  * cpu_lwkt_switch()
 532  *
 533  *      Standard LWKT switching function.  Only non-scratch registers are
 534  *      saved and we don't bother with the MMU state or anything else.
 535  *
 536  *      This function is always called while in a critical section.
 537  *
 538  *      There is a one-instruction window where curthread is the new
 539  *      thread but %esp still points to the old thread's stack, but
 540  *      we are protected by a critical section so it is ok.
 541  *
 542  *      YYY BGL, SPL
 543  */
 544 ENTRY(cpu_lwkt_switch)
 545         pushl   %ebp    /* note: GDB hacked to locate ebp relative to td_sp */
 546         pushl   %ebx
 547         movl    PCPU(curthread),%ebx
 548         pushl   %esi
 549         pushl   %edi
 550         pushfl
 551         /* warning: adjust movl into %eax below if you change the pushes */
 552
 553 #if NNPX > 0
 554         /*
 555          * Save the FP state if we have used the FP.  Note that calling
 556          * npxsave will NULL out PCPU(npxthread).
 557          *
 558          * We have to deal with the FP state for LWKT threads in case they
 559          * happen to get preempted or block while doing an optimized
 560          * bzero/bcopy/memcpy.
 561          */
 562         cmpl    %ebx,PCPU(npxthread)
 563         jne     1f
 564         pushl   TD_SAVEFPU(%ebx)
 565         call    npxsave                 /* do it in a big C function */
 566         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 567 1:
 568 #endif  /* NNPX > 0 */
 569
 570         movl    4+20(%esp),%eax         /* switch to this thread */
 571         pushl   $cpu_lwkt_restore
 572         movl    %esp,TD_SP(%ebx)
 573         movl    %eax,PCPU(curthread)
 574         movl    TD_SP(%eax),%esp
 575
 576         /*
 577          * eax contains new thread, ebx contains old thread.
 578          */
 579         ret
 580
 581 /*
 582  * cpu_lwkt_restore()   (current thread in %eax on entry)
 583  *
 584  *      Standard LWKT restore function.  This function is always called
 585  *      while in a critical section.
 586  *
 587  *      Warning: due to preemption the restore function can be used to
 588  *      'return' to the original thread.  Interrupt disablement must be
 589  *      protected through the switch so we cannot run splz here.
 590  *
 591  *      YYY we theoretically do not need to load IdlePTD into cr3, but if
 592  *      so we need a way to detect when the PTD we are using is being
 593  *      deleted due to a process exiting.
 594  */
 595 ENTRY(cpu_lwkt_restore)
 596         movl    IdlePTD,%ecx    /* YYY borrow but beware desched/cpuchg/exit */
 597         movl    %cr3,%edx
 598         cmpl    %ecx,%edx
 599         je      1f
 600         movl    %ecx,%cr3
 601 1:
 602         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 603         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 604         popfl
 605         popl    %edi
 606         popl    %esi
 607         popl    %ebx
 608         popl    %ebp
 609         ret
 610