sys/platform/vkernel/i386/swtch.s

   1 /*
   2  * Copyright (c) 2003,2004 The DragonFly Project.  All rights reserved.
   3  *
   4  * This code is derived from software contributed to The DragonFly Project
   5  * by Matthew Dillon <dillon@backplane.com>
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  *
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in
  15  *    the documentation and/or other materials provided with the
  16  *    distribution.
  17  * 3. Neither the name of The DragonFly Project nor the names of its
  18  *    contributors may be used to endorse or promote products derived
  19  *    from this software without specific, prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  22  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  23  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  24  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  25  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  26  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  27  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  28  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  29  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  30  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  31  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  * Copyright (c) 1990 The Regents of the University of California.
  35  * All rights reserved.
  36  *
  37  * This code is derived from software contributed to Berkeley by
  38  * William Jolitz.
  39  *
  40  * Redistribution and use in source and binary forms, with or without
  41  * modification, are permitted provided that the following conditions
  42  * are met:
  43  * 1. Redistributions of source code must retain the above copyright
  44  *    notice, this list of conditions and the following disclaimer.
  45  * 2. Redistributions in binary form must reproduce the above copyright
  46  *    notice, this list of conditions and the following disclaimer in the
  47  *    documentation and/or other materials provided with the distribution.
  48  * 3. All advertising materials mentioning features or use of this software
  49  *    must display the following acknowledgement:
  50  *      This product includes software developed by the University of
  51  *      California, Berkeley and its contributors.
  52  * 4. Neither the name of the University nor the names of its contributors
  53  *    may be used to endorse or promote products derived from this software
  54  *    without specific prior written permission.
  55  *
  56  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  57  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  58  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  59  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  60  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  61  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  62  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  63  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  64  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  65  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  66  * SUCH DAMAGE.
  67  *
  68  * $FreeBSD: src/sys/i386/i386/swtch.s,v 1.89.2.10 2003/01/23 03:36:24 ps Exp $
  69  * $DragonFly: src/sys/platform/vkernel/i386/swtch.s,v 1.1 2007/01/02 04:24:25 dillon Exp $
  70  */
  71
  72 #include "use_npx.h"
  73
  74 #include <sys/rtprio.h>
  75
  76 #include <machine/asmacros.h>
  77 #include <machine/segments.h>
  78
  79 #include <machine/pmap.h>
  80 #include <machine/lock.h>
  81
  82 #include "assym.s"
  83
  84 #if defined(SMP)
  85 #define MPLOCKED        lock ;
  86 #else
  87 #define MPLOCKED
  88 #endif
  89
  90         .data
  91
  92         .globl  panic
  93
  94 #if defined(SWTCH_OPTIM_STATS)
  95         .globl  swtch_optim_stats, tlb_flush_count
  96 swtch_optim_stats:      .long   0               /* number of _swtch_optims */
  97 tlb_flush_count:        .long   0
  98 #endif
  99
 100         .text
 101
 102
 103 /*
 104  * cpu_heavy_switch(next_thread)
 105  *
 106  *      Switch from the current thread to a new thread.  This entry
 107  *      is normally called via the thread->td_switch function, and will
 108  *      only be called when the current thread is a heavy weight process.
 109  *
 110  *      Some instructions have been reordered to reduce pipeline stalls.
 111  *
 112  *      YYY disable interrupts once giant is removed.
 113  */
 114 ENTRY(cpu_heavy_switch)
 115         /*
 116          * Save general regs
 117          */
 118         movl    PCPU(curthread),%ecx
 119         movl    (%esp),%eax                     /* (reorder optimization) */
 120         movl    TD_PCB(%ecx),%edx               /* EDX = PCB */
 121         movl    %eax,PCB_EIP(%edx)              /* return PC may be modified */
 122         movl    %ebx,PCB_EBX(%edx)
 123         movl    %esp,PCB_ESP(%edx)
 124         movl    %ebp,PCB_EBP(%edx)
 125         movl    %esi,PCB_ESI(%edx)
 126         movl    %edi,PCB_EDI(%edx)
 127         movl    %gs,PCB_GS(%edx)
 128
 129         movl    %ecx,%ebx                       /* EBX = curthread */
 130         movl    TD_PROC(%ecx),%ecx
 131         movl    PCPU(cpuid), %eax
 132         movl    P_VMSPACE(%ecx), %ecx           /* ECX = vmspace */
 133         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%ecx)
 134
 135         /*
 136          * Push the LWKT switch restore function, which resumes a heavy
 137          * weight process.  Note that the LWKT switcher is based on
 138          * TD_SP, while the heavy weight process switcher is based on
 139          * PCB_ESP.  TD_SP is usually two ints pushed relative to
 140          * PCB_ESP.  We push the flags for later restore by cpu_heavy_restore.
 141          */
 142         pushfl
 143         pushl   $cpu_heavy_restore
 144         movl    %esp,TD_SP(%ebx)
 145
 146         /*
 147          * Save debug regs if necessary
 148          */
 149         movb    PCB_FLAGS(%edx),%al
 150         andb    $PCB_DBREGS,%al
 151         jz      1f                              /* no, skip over */
 152         movl    %dr7,%eax                       /* yes, do the save */
 153         movl    %eax,PCB_DR7(%edx)
 154         andl    $0x0000fc00, %eax               /* disable all watchpoints */
 155         movl    %eax,%dr7
 156         movl    %dr6,%eax
 157         movl    %eax,PCB_DR6(%edx)
 158         movl    %dr3,%eax
 159         movl    %eax,PCB_DR3(%edx)
 160         movl    %dr2,%eax
 161         movl    %eax,PCB_DR2(%edx)
 162         movl    %dr1,%eax
 163         movl    %eax,PCB_DR1(%edx)
 164         movl    %dr0,%eax
 165         movl    %eax,PCB_DR0(%edx)
 166 1:
 167
 168 #if NNPX > 0
 169         /*
 170          * Save the FP state if we have used the FP.  Note that calling
 171          * npxsave will NULL out PCPU(npxthread).
 172          */
 173         cmpl    %ebx,PCPU(npxthread)
 174         jne     1f
 175         pushl   TD_SAVEFPU(%ebx)
 176         call    npxsave                 /* do it in a big C function */
 177         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 178 1:
 179 #endif  /* NNPX > 0 */
 180
 181         /*
 182          * Switch to the next thread, which was passed as an argument
 183          * to cpu_heavy_switch().  Due to the eflags and switch-restore
 184          * function we pushed, the argument is at 12(%esp).  Set the current
 185          * thread, load the stack pointer, and 'ret' into the switch-restore
 186          * function.
 187          *
 188          * The switch restore function expects the new thread to be in %eax
 189          * and the old one to be in %ebx.
 190          *
 191          * There is a one-instruction window where curthread is the new
 192          * thread but %esp still points to the old thread's stack, but
 193          * we are protected by a critical section so it is ok.
 194          */
 195         movl    12(%esp),%eax           /* EAX = newtd, EBX = oldtd */
 196         movl    %eax,PCPU(curthread)
 197         movl    TD_SP(%eax),%esp
 198         ret
 199
 200 /*
 201  *  cpu_exit_switch()
 202  *
 203  *      The switch function is changed to this when a thread is going away
 204  *      for good.  We have to ensure that the MMU state is not cached, and
 205  *      we don't bother saving the existing thread state before switching.
 206  *
 207  *      At this point we are in a critical section and this cpu owns the
 208  *      thread's token, which serves as an interlock until the switchout is
 209  *      complete.
 210  */
 211 ENTRY(cpu_exit_switch)
 212         /*
 213          * Get us out of the vmspace
 214          */
 215         movl    IdlePTD,%ecx
 216         movl    %cr3,%eax
 217         cmpl    %ecx,%eax
 218         je      1f
 219         movl    %ecx,%cr3
 220 1:
 221         movl    PCPU(curthread),%ebx
 222         /*
 223          * Switch to the next thread.  RET into the restore function, which
 224          * expects the new thread in EAX and the old in EBX.
 225          *
 226          * There is a one-instruction window where curthread is the new
 227          * thread but %esp still points to the old thread's stack, but
 228          * we are protected by a critical section so it is ok.
 229          */
 230         movl    4(%esp),%eax
 231         movl    %eax,PCPU(curthread)
 232         movl    TD_SP(%eax),%esp
 233         ret
 234
 235 /*
 236  * cpu_heavy_restore()  (current thread in %eax on entry)
 237  *
 238  *      Restore the thread after an LWKT switch.  This entry is normally
 239  *      called via the LWKT switch restore function, which was pulled
 240  *      off the thread stack and jumped to.
 241  *
 242  *      This entry is only called if the thread was previously saved
 243  *      using cpu_heavy_switch() (the heavy weight process thread switcher),
 244  *      or when a new process is initially scheduled.  The first thing we
 245  *      do is clear the TDF_RUNNING bit in the old thread and set it in the
 246  *      new thread.
 247  *
 248  *      NOTE: The process may be in any state, not necessarily SRUN, because
 249  *      a preemption switch may interrupt the process and then return via
 250  *      cpu_heavy_restore.
 251  *
 252  *      YYY theoretically we do not have to restore everything here, a lot
 253  *      of this junk can wait until we return to usermode.  But for now
 254  *      we restore everything.
 255  *
 256  *      YYY the PCB crap is really crap, it makes startup a bitch because
 257  *      we can't switch away.
 258  *
 259  *      YYY note: spl check is done in mi_switch when it splx()'s.
 260  */
 261
 262 ENTRY(cpu_heavy_restore)
 263         popfl
 264         movl    TD_PCB(%eax),%edx               /* EDX = PCB */
 265         movl    TD_PROC(%eax),%ecx
 266
 267 #if defined(SWTCH_OPTIM_STATS)
 268         incl    _swtch_optim_stats
 269 #endif
 270         /*
 271          * Tell the pmap that our cpu is using the VMSPACE now.  We cannot
 272          * safely test/reload %cr3 until after we have set the bit in the
 273          * pmap (remember, we do not hold the MP lock in the switch code).
 274          */
 275         movl    P_VMSPACE(%ecx), %ecx           /* ECX = vmspace */
 276         movl    PCPU(cpuid), %esi
 277         MPLOCKED btsl   %esi, VM_PMAP+PM_ACTIVE(%ecx)
 278
 279         /*
 280          * Restore the MMU address space.  If it is the same as the last
 281          * thread we don't have to invalidate the tlb (i.e. reload cr3).
 282          * YYY which naturally also means that the PM_ACTIVE bit had better
 283          * already have been set before we set it above, check? YYY
 284          */
 285         movl    %cr3,%esi
 286         movl    PCB_CR3(%edx),%ecx
 287         cmpl    %esi,%ecx
 288         je      4f
 289 #if defined(SWTCH_OPTIM_STATS)
 290         decl    _swtch_optim_stats
 291         incl    _tlb_flush_count
 292 #endif
 293         movl    %ecx,%cr3
 294 4:
 295         /*
 296          * Clear TDF_RUNNING flag in old thread only after cleaning up
 297          * %cr3.  The target thread is already protected by being TDF_RUNQ
 298          * so setting TDF_RUNNING isn't as big a deal.
 299          */
 300         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 301         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 302
 303         /*
 304          * Deal with the PCB extension, restore the private tss
 305          */
 306         movl    PCB_EXT(%edx),%edi      /* check for a PCB extension */
 307         movl    $1,%ebx                 /* maybe mark use of a private tss */
 308         testl   %edi,%edi
 309         jnz     2f
 310
 311         /*
 312          * Going back to the common_tss.  We may need to update TSS_ESP0
 313          * which sets the top of the supervisor stack when entering from
 314          * usermode.  The PCB is at the top of the stack but we need another
 315          * 16 bytes to take vm86 into account.
 316          */
 317         leal    -16(%edx),%ebx
 318         movl    %ebx, PCPU(common_tss) + TSS_ESP0
 319
 320         cmpl    $0,PCPU(private_tss)    /* don't have to reload if      */
 321         je      3f                      /* already using the common TSS */
 322
 323         subl    %ebx,%ebx               /* unmark use of private tss */
 324
 325         /*
 326          * Get the address of the common TSS descriptor for the ltr.
 327          * There is no way to get the address of a segment-accessed variable
 328          * so we store a self-referential pointer at the base of the per-cpu
 329          * data area and add the appropriate offset.
 330          */
 331         movl    $gd_common_tssd, %edi
 332         addl    %fs:0, %edi
 333
 334         /*
 335          * Move the correct TSS descriptor into the GDT slot, then reload
 336          * ltr.
 337          */
 338 2:
 339         movl    %ebx,PCPU(private_tss)          /* mark/unmark private tss */
 340         movl    PCPU(tss_gdt), %ebx             /* entry in GDT */
 341         movl    0(%edi), %eax
 342         movl    %eax, 0(%ebx)
 343         movl    4(%edi), %eax
 344         movl    %eax, 4(%ebx)
 345         movl    $GPROC0_SEL*8, %esi             /* GSEL(entry, SEL_KPL) */
 346         ltr     %si
 347
 348 3:
 349         /*
 350          * Restore general registers.
 351          */
 352         movl    PCB_EBX(%edx),%ebx
 353         movl    PCB_ESP(%edx),%esp
 354         movl    PCB_EBP(%edx),%ebp
 355         movl    PCB_ESI(%edx),%esi
 356         movl    PCB_EDI(%edx),%edi
 357         movl    PCB_EIP(%edx),%eax
 358         movl    %eax,(%esp)
 359
 360         /*
 361          * Restore the user LDT if we have one
 362          */
 363         cmpl    $0, PCB_USERLDT(%edx)
 364         jnz     1f
 365         movl    _default_ldt,%eax
 366         cmpl    PCPU(currentldt),%eax
 367         je      2f
 368         lldt    _default_ldt
 369         movl    %eax,PCPU(currentldt)
 370         jmp     2f
 371 1:      pushl   %edx
 372         call    set_user_ldt
 373         popl    %edx
 374 2:
 375         /*
 376          * Restore the user TLS if we have one
 377          */
 378         pushl   %edx
 379         call    set_user_TLS
 380         popl    %edx
 381         /*
 382          * Restore the %gs segment register, which must be done after
 383          * loading the user LDT.  Since user processes can modify the
 384          * register via procfs, this may result in a fault which is
 385          * detected by checking the fault address against cpu_switch_load_gs
 386          * in i386/i386/trap.c
 387          */
 388         .globl  cpu_switch_load_gs
 389 cpu_switch_load_gs:
 390         movl    PCB_GS(%edx),%gs
 391
 392         /*
 393          * Restore the DEBUG register state if necessary.
 394          */
 395         movb    PCB_FLAGS(%edx),%al
 396         andb    $PCB_DBREGS,%al
 397         jz      1f                              /* no, skip over */
 398         movl    PCB_DR6(%edx),%eax              /* yes, do the restore */
 399         movl    %eax,%dr6
 400         movl    PCB_DR3(%edx),%eax
 401         movl    %eax,%dr3
 402         movl    PCB_DR2(%edx),%eax
 403         movl    %eax,%dr2
 404         movl    PCB_DR1(%edx),%eax
 405         movl    %eax,%dr1
 406         movl    PCB_DR0(%edx),%eax
 407         movl    %eax,%dr0
 408         movl    %dr7,%eax                /* load dr7 so as not to disturb */
 409         andl    $0x0000fc00,%eax         /*   reserved bits               */
 410         pushl   %ebx
 411         movl    PCB_DR7(%edx),%ebx
 412         andl    $~0x0000fc00,%ebx
 413         orl     %ebx,%eax
 414         popl    %ebx
 415         movl    %eax,%dr7
 416 1:
 417
 418         ret
 419
 420 /*
 421  * savectx(pcb)
 422  *
 423  * Update pcb, saving current processor state.
 424  */
 425 ENTRY(savectx)
 426         /* fetch PCB */
 427         movl    4(%esp),%ecx
 428
 429         /* caller's return address - child won't execute this routine */
 430         movl    (%esp),%eax
 431         movl    %eax,PCB_EIP(%ecx)
 432         movl    %ebx,PCB_EBX(%ecx)
 433         movl    %esp,PCB_ESP(%ecx)
 434         movl    %ebp,PCB_EBP(%ecx)
 435         movl    %esi,PCB_ESI(%ecx)
 436         movl    %edi,PCB_EDI(%ecx)
 437         movl    %gs,PCB_GS(%ecx)
 438
 439 #if NNPX > 0
 440         /*
 441          * If npxthread == NULL, then the npx h/w state is irrelevant and the
 442          * state had better already be in the pcb.  This is true for forks
 443          * but not for dumps (the old book-keeping with FP flags in the pcb
 444          * always lost for dumps because the dump pcb has 0 flags).
 445          *
 446          * If npxthread != NULL, then we have to save the npx h/w state to
 447          * npxthread's pcb and copy it to the requested pcb, or save to the
 448          * requested pcb and reload.  Copying is easier because we would
 449          * have to handle h/w bugs for reloading.  We used to lose the
 450          * parent's npx state for forks by forgetting to reload.
 451          */
 452         movl    PCPU(npxthread),%eax
 453         testl   %eax,%eax
 454         je      1f
 455
 456         pushl   %ecx                    /* target pcb */
 457         movl    TD_SAVEFPU(%eax),%eax   /* originating savefpu area */
 458         pushl   %eax
 459
 460         pushl   %eax
 461         call    npxsave
 462         addl    $4,%esp
 463
 464         popl    %eax
 465         popl    %ecx
 466
 467         pushl   $PCB_SAVEFPU_SIZE
 468         leal    PCB_SAVEFPU(%ecx),%ecx
 469         pushl   %ecx
 470         pushl   %eax
 471         call    bcopy
 472         addl    $12,%esp
 473 #endif  /* NNPX > 0 */
 474
 475 1:
 476         ret
 477
 478 /*
 479  * cpu_idle_restore()   (current thread in %eax on entry) (one-time execution)
 480  *
 481  *      Don't bother setting up any regs other then %ebp so backtraces
 482  *      don't die.  This restore function is used to bootstrap into the
 483  *      cpu_idle() LWKT only, after that cpu_lwkt_*() will be used for
 484  *      switching.
 485  *
 486  *      Clear TDF_RUNNING in old thread only after we've cleaned up %cr3.
 487  *
 488  *      If we are an AP we have to call ap_init() before jumping to
 489  *      cpu_idle().  ap_init() will synchronize with the BP and finish
 490  *      setting up various ncpu-dependant globaldata fields.  This may
 491  *      happen on UP as well as SMP if we happen to be simulating multiple
 492  *      cpus.
 493  */
 494 ENTRY(cpu_idle_restore)
 495         /* cli */
 496         movl    $0,%ebp
 497         pushl   $0
 498         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 499         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 500 #ifdef SMP
 501         cmpl    $0,PCPU(cpuid)
 502         je      1f
 503         call    ap_init
 504 1:
 505 #endif
 506         /* sti */
 507         jmp     cpu_idle
 508
 509 /*
 510  * cpu_kthread_restore() (current thread is %eax on entry) (one-time execution)
 511  *
 512  *      Don't bother setting up any regs other then %ebp so backtraces
 513  *      don't die.  This restore function is used to bootstrap into an
 514  *      LWKT based kernel thread only.  cpu_lwkt_switch() will be used
 515  *      after this.
 516  *
 517  *      Since all of our context is on the stack we are reentrant and
 518  *      we can release our critical section and enable interrupts early.
 519  */
 520 ENTRY(cpu_kthread_restore)
 521         /*sti*/
 522         movl    TD_PCB(%eax),%edx
 523         movl    $0,%ebp
 524         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 525         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 526         subl    $TDPRI_CRIT,TD_PRI(%eax)
 527         popl    %eax            /* kthread exit function */
 528         pushl   PCB_EBX(%edx)   /* argument to ESI function */
 529         pushl   %eax            /* set exit func as return address */
 530         movl    PCB_ESI(%edx),%eax
 531         jmp     *%eax
 532
 533 /*
 534  * cpu_lwkt_switch()
 535  *
 536  *      Standard LWKT switching function.  Only non-scratch registers are
 537  *      saved and we don't bother with the MMU state or anything else.
 538  *
 539  *      This function is always called while in a critical section.
 540  *
 541  *      There is a one-instruction window where curthread is the new
 542  *      thread but %esp still points to the old thread's stack, but
 543  *      we are protected by a critical section so it is ok.
 544  *
 545  *      YYY BGL, SPL
 546  */
 547 ENTRY(cpu_lwkt_switch)
 548         pushl   %ebp    /* note: GDB hacked to locate ebp relative to td_sp */
 549         pushl   %ebx
 550         movl    PCPU(curthread),%ebx
 551         pushl   %esi
 552         pushl   %edi
 553         pushfl
 554         /* warning: adjust movl into %eax below if you change the pushes */
 555
 556 #if NNPX > 0
 557         /*
 558          * Save the FP state if we have used the FP.  Note that calling
 559          * npxsave will NULL out PCPU(npxthread).
 560          *
 561          * We have to deal with the FP state for LWKT threads in case they
 562          * happen to get preempted or block while doing an optimized
 563          * bzero/bcopy/memcpy.
 564          */
 565         cmpl    %ebx,PCPU(npxthread)
 566         jne     1f
 567         pushl   TD_SAVEFPU(%ebx)
 568         call    npxsave                 /* do it in a big C function */
 569         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 570 1:
 571 #endif  /* NNPX > 0 */
 572
 573         movl    4+20(%esp),%eax         /* switch to this thread */
 574         pushl   $cpu_lwkt_restore
 575         movl    %esp,TD_SP(%ebx)
 576         movl    %eax,PCPU(curthread)
 577         movl    TD_SP(%eax),%esp
 578
 579         /*
 580          * eax contains new thread, ebx contains old thread.
 581          */
 582         ret
 583
 584 /*
 585  * cpu_lwkt_restore()   (current thread in %eax on entry)
 586  *
 587  *      Standard LWKT restore function.  This function is always called
 588  *      while in a critical section.
 589  *
 590  *      Warning: due to preemption the restore function can be used to
 591  *      'return' to the original thread.  Interrupt disablement must be
 592  *      protected through the switch so we cannot run splz here.
 593  */
 594 ENTRY(cpu_lwkt_restore)
 595         andl    $~TDF_RUNNING,TD_FLAGS(%ebx)
 596         orl     $TDF_RUNNING,TD_FLAGS(%eax)
 597         popfl
 598         popl    %edi
 599         popl    %esi
 600         popl    %ebx
 601         popl    %ebp
 602         ret
 603