sys/i386/i386/in_cksum2.s

   1 /*
   2  * Copyright (c) 2003 Matthew Dillon <dillon@backplane.com>
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  * $DragonFly: src/sys/i386/i386/Attic/in_cksum2.s,v 1.2 2004/02/21 06:37:07 dillon Exp $
  27  */
  28
  29 #include <machine/asmacros.h>           /* miscellaneous asm macros */
  30 #include <machine/apicreg.h>
  31 #include <machine/specialreg.h>
  32
  33 #include "assym.s"
  34
  35         .text
  36
  37         /*
  38          * asm_ones32(32bitalignedbuffer, numberof32bitwords)
  39          *
  40          * Returns the 32 bit one complement partial checksum.  This is
  41          * basically a 1's complement checksum without the inversion (~)
  42          * at the end.  A 32 bit value is returned.  If the caller is
  43          * calculating a 16 bit 1's complement checksum the caller must
  44          * collapse the 32 bit return value via:
  45          *
  46          *      result = (result >> 16) + (result & 0xFFFF)
  47          *      if (result > 0xFFFF)
  48          *          result -= 0xFFFF;   <<< same as (result + 1) & 0xFFFF
  49          *                                  within the range of result.
  50          * Note that worst case 0xFFFFFFFF + 0xFFFFFFFF = 0xFFFFFFFE + CARRY,
  51          * so no double-carry ever occurs.
  52          */
  53         .p2align 4
  54 ENTRY(asm_ones32)
  55         movl    4(%esp),%edx    /* %edx = buffer pointer */
  56         movl    8(%esp),%ecx    /* %ecx = counter */
  57         subl    %eax,%eax       /* %eax = checksum */
  58         cmpl    $5,%ecx
  59         jl      2f
  60 1:
  61         subl    $5,%ecx
  62         addl    (%edx),%eax
  63         adcl    4(%edx),%eax
  64         adcl    8(%edx),%eax
  65         adcl    12(%edx),%eax
  66         adcl    16(%edx),%eax
  67         adcl    $0,%eax
  68         addl    $20,%edx
  69         cmpl    $5,%ecx
  70         jge     1b
  71 2:
  72         testl   %ecx,%ecx
  73         je      4f
  74 3:
  75         addl    (%edx),%eax
  76         adcl    $0,%eax
  77         addl    $4,%edx
  78         decl    %ecx
  79         jnz     3b
  80 4:
  81         ret