lib/libc/amd64/string/bcopy.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from locore.s.
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  * 1. Redistributions of source code must retain the above copyright
  11  *    notice, this list of conditions and the following disclaimer.
  12  * 2. Redistributions in binary form must reproduce the above copyright
  13  *    notice, this list of conditions and the following disclaimer in the
  14  *    documentation and/or other materials provided with the distribution.
  15  * 3. Neither the name of the University nor the names of its contributors
  16  *    may be used to endorse or promote products derived from this software
  17  *    without specific prior written permission.
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  20  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  21  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  22  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  23  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  24  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  25  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  26  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  27  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  28  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  29  * SUCH DAMAGE.
  30  *
  31  * $NetBSD: bcopy.S,v 1.2 2003/08/07 16:42:36 agc Exp $
  32  * $FreeBSD: src/lib/libc/amd64/string/bcopy.S,v 1.3 2008/11/02 01:10:54 peter Exp $
  33  */
  34
  35 #include <machine/asm.h>
  36
  37         /*
  38          * (ov)bcopy (src,dst,cnt)
  39          *  ws@tools.de     (Wolfgang Solfrank, TooLs GmbH) +49-228-985800
  40          */
  41
  42 #ifdef MEMCOPY
  43 ENTRY(memcpy)
  44 #else
  45 #ifdef MEMMOVE
  46 ENTRY(memmove)
  47 #else
  48 ENTRY(bcopy)
  49 #endif
  50 #endif
  51 #if defined(MEMCOPY) || defined(MEMMOVE)
  52         movq    %rdi,%rax       /* return dst */
  53 #else
  54         xchgq   %rdi,%rsi
  55 #endif
  56         movq    %rdx,%rcx
  57         movq    %rdi,%r8
  58         subq    %rsi,%r8
  59         cmpq    %rcx,%r8        /* overlapping? */
  60         jb      1f
  61         cld                     /* nope, copy forwards. */
  62         shrq    $3,%rcx         /* copy by words */
  63         rep
  64         movsq
  65         movq    %rdx,%rcx
  66         andq    $7,%rcx         /* any bytes left? */
  67         rep
  68         movsb
  69         ret
  70 1:
  71         addq    %rcx,%rdi       /* copy backwards. */
  72         addq    %rcx,%rsi
  73         std
  74         andq    $7,%rcx         /* any fractional bytes? */
  75         decq    %rdi
  76         decq    %rsi
  77         rep
  78         movsb
  79         movq    %rdx,%rcx       /* copy remainder by words */
  80         shrq    $3,%rcx
  81         subq    $7,%rsi
  82         subq    $7,%rdi
  83         rep
  84         movsq
  85         cld
  86         ret
  87 #ifdef MEMCOPY
  88 END(memcpy)
  89 #else
  90 #ifdef MEMMOVE
  91 END(memmove)
  92 #else
  93 END(bcopy)
  94 #endif
  95 #endif