lib/libm/i386/s_remquol.S

   1 /*-
   2  * Copyright (c) 2005-2008 David Schultz <das@FreeBSD.ORG>
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  *
  14  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  15  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  16  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  17  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  18  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  19  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  20  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  21  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  22  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  23  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  24  * SUCH DAMAGE.
  25  *
  26  * $FreeBSD: head/lib/msun/i387/s_remquol.S 217108 2011-01-07 16:13:12Z kib $
  27  */
  28
  29 /*
  30  * Based on public-domain remainder routine by J.T. Conklin <jtc@NetBSD.org>.
  31  */
  32
  33 #include <machine/asm.h>
  34
  35 ENTRY(remquol)
  36         fldt    16(%esp)
  37         fldt    4(%esp)
  38 1:      fprem1
  39         fstsw   %ax
  40         sahf
  41         jp      1b
  42         fstp    %st(1)
  43 /* Extract the three low-order bits of the quotient from C0,C3,C1. */
  44         shrl    $6,%eax
  45         movl    %eax,%ecx
  46         andl    $0x108,%eax
  47         rorl    $7,%eax
  48         orl     %eax,%ecx
  49         roll    $4,%eax
  50         orl     %ecx,%eax
  51         andl    $7,%eax
  52 /* Negate the quotient bits if x*y<0.  Avoid using an unpredictable branch. */
  53         movl    24(%esp),%ecx
  54         xorl    12(%esp),%ecx
  55         movsx   %cx,%ecx
  56         sarl    $16,%ecx
  57         sarl    $16,%ecx
  58         xorl    %ecx,%eax
  59         andl    $1,%ecx
  60         addl    %ecx,%eax
  61 /* Store the quotient and return. */
  62         movl    28(%esp),%ecx
  63         movl    %eax,(%ecx)
  64         ret
  65 END(remquol)
  66
  67         .section .note.GNU-stack,"",%progbits