lib/libc/amd64/gen/setjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  * @(#)setjmp.s 5.1 (Berkeley) 4/23/90
  37  * $FreeBSD: src/lib/libc/amd64/gen/setjmp.S,v 1.26 2003/06/02 22:37:53 peter Exp $
  38  * $DragonFly: src/lib/libc/amd64/gen/setjmp.S,v 1.1 2004/02/02 05:43:14 dillon Exp $
  39  */
  40
  41 #include <machine/asm.h>
  42
  43 /*
  44  * C library -- _setjmp, _longjmp
  45  *
  46  *      longjmp(a,v)
  47  * will generate a "return(v)" from the last call to
  48  *      setjmp(a)
  49  * by restoring registers from the environment 'a'.
  50  * The previous signal state is restored.
  51  */
  52
  53 #include "SYS.h"
  54
  55 ENTRY(setjmp)
  56         pushq   %rdi
  57         movq    %rdi,%rcx
  58         movq    $1,%rdi                 /* SIG_BLOCK       */
  59         movq    $0,%rsi                 /* (sigset_t*)set  */
  60         leaq    72(%rcx),%rdx           /* 9,10; (sigset_t*)oset */
  61         call    PIC_PLT(CNAME(_sigprocmask))
  62         popq    %rdi
  63         movq    %rdi,%rcx
  64         movq    0(%rsp),%rdx            /* retval */
  65         movq    %rdx, 0(%rcx)           /* 0; retval */
  66         movq    %rbx, 8(%rcx)           /* 1; rbx */
  67         movq    %rsp,16(%rcx)           /* 2; rsp */
  68         movq    %rbp,24(%rcx)           /* 3; rbp */
  69         movq    %r12,32(%rcx)           /* 4; r12 */
  70         movq    %r13,40(%rcx)           /* 5; r13 */
  71         movq    %r14,48(%rcx)           /* 6; r14 */
  72         movq    %r15,56(%rcx)           /* 7; r15 */
  73         fnstcw  64(%rcx)                /* 8; fpu cw */
  74         xorq    %rax,%rax
  75         ret
  76
  77         .weak CNAME(longjmp)
  78         .set CNAME(longjmp),CNAME(__longjmp)
  79 ENTRY(__longjmp)
  80         pushq   %rdi
  81         pushq   %rsi
  82         movq    %rdi,%rdx
  83         movq    $3,%rdi                 /* SIG_SETMASK     */
  84         leaq    72(%rdx),%rsi           /* (sigset_t*)set  */
  85         movq    $0,%rdx                 /* (sigset_t*)oset */
  86         call    PIC_PLT(CNAME(_sigprocmask))
  87         popq    %rsi
  88         popq    %rdi                    /* jmpbuf */
  89         movq    %rdi,%rdx
  90         movq    %rsi,%rax               /* retval */
  91         movq    0(%rdx),%rcx
  92         movq    8(%rdx),%rbx
  93         movq    16(%rdx),%rsp
  94         movq    24(%rdx),%rbp
  95         movq    32(%rdx),%r12
  96         movq    40(%rdx),%r13
  97         movq    48(%rdx),%r14
  98         movq    56(%rdx),%r15
  99         fninit
 100         fldcw   64(%rdx)
 101         testq   %rax,%rax
 102         jnz     1f
 103         incq    %rax
 104 1:      movq    %rcx,0(%rsp)
 105         ret