Merge branch 'vendor/GCC44'
[dragonfly.git] / contrib / gcc-4.4 / libstdc++-v3 / configure.ac
1 # Process this file with autoreconf to produce a configure script.
2
3 AC_PREREQ(2.59)
4 AC_INIT(package-unused, version-unused,, libstdc++)
5 AC_CONFIG_SRCDIR(src/ios.cc)
6 AC_CONFIG_HEADER(config.h)
7
8 # This works around the fact that libtool configuration may change LD
9 # for this particular configuration, but some shells, instead of
10 # keeping the changes in LD private, export them just because LD is
11 # exported.  Only used at the end of this file.
12 ### am handles this now?  ORIGINAL_LD_FOR_MULTILIBS=$LD
13
14 # For libtool versioning info, format is CURRENT:REVISION:AGE
15 libtool_VERSION=6:13:0
16 AC_SUBST(libtool_VERSION)
17
18 # Find the rest of the source tree framework.
19 AM_ENABLE_MULTILIB(, ..)
20
21 # Gets build, host, target, *_vendor, *_cpu, *_os, etc.
22 #
23 # You will slowly go insane if you do not grok the following fact:  when
24 # building v3 as part of the compiler, the top-level /target/ becomes the
25 # library's /host/.  configure then causes --target to default to --host,
26 # exactly like any other package using autoconf.  Therefore, 'target' and
27 # 'host' will always be the same.  This makes sense both for native and
28 # cross compilers, just think about it for a little while.  :-)
29 #
30 # Also, if v3 is being configured as part of a cross compiler, the top-level
31 # configure script will pass the "real" host as $with_cross_host.
32 #
33 # Do not delete or change the following two lines.  For why, see
34 # http://gcc.gnu.org/ml/libstdc++/2003-07/msg00451.html
35 AC_CANONICAL_SYSTEM
36 target_alias=${target_alias-$host_alias}
37
38 # Handy for debugging:
39 #AC_MSG_NOTICE($build / $host / $target / $host_alias / $target_alias); sleep 5
40
41 if test "$build" != "$host"; then
42   # We are being configured with some form of cross compiler.
43   GLIBCXX_IS_NATIVE=false
44   case "$host","$target" in
45     # Darwin crosses can use the host system's libraries and headers,
46     # because of the fat library support.  Of course, it must be the
47     # same version of Darwin on both sides.  Allow the user to
48     # just say --target=foo-darwin without a version number to mean
49     # "the version on this system".
50       *-*-darwin*,*-*-darwin*)
51         hostos=`echo $host | sed 's/.*-darwin/darwin/'`
52         targetos=`echo $target | sed 's/.*-darwin/darwin/'`
53         if test $hostos = $targetos -o $targetos = darwin ; then
54           GLIBCXX_IS_NATIVE=true
55         fi
56         ;;
57
58       *)
59         GCC_NO_EXECUTABLES
60         ;;
61   esac
62 else
63   GLIBCXX_IS_NATIVE=true
64 fi
65
66 # Sets up automake.  Must come after AC_CANONICAL_SYSTEM.  Each of the
67 # following is magically included in AUTOMAKE_OPTIONS in each Makefile.am.
68 #  1.x:  minimum required version
69 #  no-define:  PACKAGE and VERSION will not be #define'd in config.h (a bunch
70 #              of other PACKAGE_* variables will, however, and there's nothing
71 #              we can do about that; they come from AC_INIT).
72 #  foreign:  we don't follow the normal rules for GNU packages (no COPYING
73 #            file in the top srcdir, etc, etc), so stop complaining.
74 #  no-dependencies:  turns off auto dependency generation (just for now)
75 #  -Wall:  turns on all automake warnings...
76 #  -Wno-portability:  ...except this one, since GNU make is now required.
77 AM_INIT_AUTOMAKE([1.9.3 no-define foreign no-dependencies no-dist -Wall -Wno-portability -Wno-override])
78 AH_TEMPLATE(PACKAGE, [Name of package])
79 AH_TEMPLATE(VERSION, [Version number of package])
80
81 # Runs configure.host, finds CC, CXX, and assorted other critical bits.  Sets
82 # up critical shell variables.
83 GLIBCXX_CONFIGURE
84
85 if test "x${with_newlib}" != "xyes"; then
86   AC_LIBTOOL_DLOPEN
87 fi
88 AM_PROG_LIBTOOL
89 AC_SUBST(enable_shared)
90 AC_SUBST(enable_static)
91
92 # Possibly disable most of the library.
93 ## TODO: Consider skipping unncessary tests altogether in this case, rather
94 ## than just ignoring the results.  Faster /and/ more correct, win win.
95 GLIBCXX_ENABLE_HOSTED
96
97 # Enable compiler support that doesn't require linking.
98 GLIBCXX_ENABLE_SJLJ_EXCEPTIONS
99 GLIBCXX_ENABLE_PCH($is_hosted)
100 GLIBCXX_ENABLE_THREADS
101 GLIBCXX_ENABLE_ATOMIC_BUILTINS
102
103 # Checks for compiler support that doesn't require linking.
104 GLIBCXX_CHECK_COMPILER_FEATURES
105
106 # Enable all the variable C++ runtime options that don't require linking.
107 GLIBCXX_ENABLE_CSTDIO
108 GLIBCXX_ENABLE_CLOCALE
109 GLIBCXX_ENABLE_ALLOCATOR
110 GLIBCXX_ENABLE_CHEADERS($c_model)  dnl c_model from configure.host
111 GLIBCXX_ENABLE_LONG_LONG([yes])
112 GLIBCXX_ENABLE_WCHAR_T([yes])
113 GLIBCXX_ENABLE_C99([yes])
114 GLIBCXX_ENABLE_CONCEPT_CHECKS([no])
115 GLIBCXX_ENABLE_DEBUG_FLAGS(["-g3 -O0"])
116 GLIBCXX_ENABLE_DEBUG([no])
117 GLIBCXX_ENABLE_PARALLEL([yes])
118 GLIBCXX_ENABLE_CXX_FLAGS
119 GLIBCXX_ENABLE_FULLY_DYNAMIC_STRING([no])
120
121 # Checks for operating systems support that doesn't require linking.
122 GLIBCXX_CHECK_SYSTEM_ERROR
123
124 # For the streamoff typedef.
125 GLIBCXX_CHECK_INT64_T
126
127 # For LFS support.
128 GLIBCXX_CHECK_LFS
129
130 # For showmanyc_helper().
131 AC_CHECK_HEADERS(sys/ioctl.h sys/filio.h)
132 GLIBCXX_CHECK_POLL
133 GLIBCXX_CHECK_S_ISREG_OR_S_IFREG
134
135 # For xsputn_2().
136 AC_CHECK_HEADERS(sys/uio.h)
137 GLIBCXX_CHECK_WRITEV
138
139 # For C99 support to TR1.
140 GLIBCXX_CHECK_C99_TR1
141
142 # For common values of EOF, SEEK_CUR, SEEK_END.
143 GLIBCXX_CHECK_STDIO_MACROS
144
145 # For gettimeofday support.
146 GLIBCXX_CHECK_GETTIMEOFDAY
147
148 # For clock_gettime, nanosleep and sched_yield support.
149 # NB: The default is [no], because otherwise it requires linking.
150 GLIBCXX_ENABLE_LIBSTDCXX_TIME([no])
151
152 # For gthread support
153 GLIBCXX_CHECK_GTHREADS
154
155 AC_LC_MESSAGES
156
157 # Check for available headers.
158 AC_CHECK_HEADERS([endian.h float.h fp.h ieeefp.h inttypes.h locale.h \
159 machine/endian.h machine/param.h nan.h stdint.h stdlib.h string.h \
160 strings.h sys/ipc.h sys/isa_defs.h sys/machine.h sys/param.h \
161 sys/resource.h sys/sem.h sys/stat.h sys/time.h sys/types.h unistd.h \
162 wchar.h wctype.h])
163
164 # Only do link tests if native. Else, hardcode.
165 if $GLIBCXX_IS_NATIVE; then
166
167   # We can do more elaborate tests that assume a working linker.
168   CANADIAN=no
169
170   GLIBCXX_CHECK_LINKER_FEATURES
171   GLIBCXX_CHECK_MATH_SUPPORT
172   GLIBCXX_CHECK_STDLIB_SUPPORT
173
174   # For /dev/random and /dev/urandom for TR1.
175   GLIBCXX_CHECK_RANDOM_TR1
176
177   # For TLS support.
178   GCC_CHECK_TLS
179
180   # For iconv support.
181   AM_ICONV
182
183 else
184
185   # This lets us hard-code the functionality we know we'll have in the cross
186   # target environment.  "Let" is a sugar-coated word placed on an especially
187   # dull and tedious hack, actually.
188   #
189   # Here's why GLIBCXX_CHECK_MATH_SUPPORT, and other autoconf macros
190   # that involve linking, can't be used:
191   #    "cannot open sim-crt0.o"
192   #    "cannot open crt0.o"
193   # etc.  All this is because there currently exists no unified, consistent
194   # way for top level CC information to be passed down to target directories:
195   # newlib includes, newlib linking info, libgloss versus newlib crt0.o, etc.
196   # When all of that is done, all of this hokey, excessive AC_DEFINE junk for
197   # crosses can be removed.
198
199   # If Canadian cross, then don't pick up tools from the build directory.
200   # Used only in GLIBCXX_EXPORT_INCLUDES.
201   if test -n "$with_cross_host" &&
202      test x"$build_alias" != x"$with_cross_host" &&
203      test x"$build" != x"$target";
204   then
205     CANADIAN=yes
206   else
207     CANADIAN=no
208   fi
209
210   # Construct crosses by hand, eliminating bits that need ld...
211   # GLIBCXX_CHECK_MATH_SUPPORT
212
213   # First, test for "known" system libraries.  We may be using newlib even
214   # on a hosted environment.
215   if test "x${with_newlib}" = "xyes"; then
216     os_include_dir="os/newlib"
217     AC_DEFINE(HAVE_HYPOT)
218
219     # GLIBCXX_CHECK_STDLIB_SUPPORT
220     AC_DEFINE(HAVE_STRTOF)        
221
222     AC_DEFINE(HAVE_ACOSF)
223     AC_DEFINE(HAVE_ASINF)
224     AC_DEFINE(HAVE_ATAN2F)
225     AC_DEFINE(HAVE_ATANF)
226     AC_DEFINE(HAVE_CEILF)
227     AC_DEFINE(HAVE_COSF)
228     AC_DEFINE(HAVE_COSHF)
229     AC_DEFINE(HAVE_EXPF)
230     AC_DEFINE(HAVE_FABSF)
231     AC_DEFINE(HAVE_FLOORF)
232     AC_DEFINE(HAVE_FMODF)
233     AC_DEFINE(HAVE_FREXPF)
234     AC_DEFINE(HAVE_LDEXPF)
235     AC_DEFINE(HAVE_LOG10F)
236     AC_DEFINE(HAVE_LOGF)
237     AC_DEFINE(HAVE_MODFF)
238     AC_DEFINE(HAVE_POWF)
239     AC_DEFINE(HAVE_SINF)
240     AC_DEFINE(HAVE_SINHF)
241     AC_DEFINE(HAVE_SQRTF)
242     AC_DEFINE(HAVE_TANF)
243     AC_DEFINE(HAVE_TANHF)
244
245     AC_DEFINE(HAVE_ICONV)
246   else
247     GLIBCXX_CROSSCONFIG
248   fi
249
250   # At some point, we should differentiate between architectures
251   # like x86, which have long double versions, and alpha/powerpc/etc.,
252   # which don't. For the time being, punt.
253   if test x"long_double_math_on_this_cpu" = x"yes"; then
254     AC_DEFINE(HAVE_ACOSL)
255     AC_DEFINE(HAVE_ASINL)
256     AC_DEFINE(HAVE_ATAN2L)
257     AC_DEFINE(HAVE_ATANL)
258     AC_DEFINE(HAVE_CEILL)
259     AC_DEFINE(HAVE_COSL)
260     AC_DEFINE(HAVE_COSHL)
261     AC_DEFINE(HAVE_EXPL)
262     AC_DEFINE(HAVE_FABSL)
263     AC_DEFINE(HAVE_FLOORL)
264     AC_DEFINE(HAVE_FMODL)
265     AC_DEFINE(HAVE_FREXPL)
266     AC_DEFINE(HAVE_LDEXPL)
267     AC_DEFINE(HAVE_LOG10L)
268     AC_DEFINE(HAVE_LOGL)
269     AC_DEFINE(HAVE_MODFL)
270     AC_DEFINE(HAVE_POWL)
271     AC_DEFINE(HAVE_SINCOSL)
272     AC_DEFINE(HAVE_SINL)
273     AC_DEFINE(HAVE_SINHL)
274     AC_DEFINE(HAVE_SQRTL)
275     AC_DEFINE(HAVE_TANL)
276     AC_DEFINE(HAVE_TANHL)
277   fi
278 fi
279
280 # Check for _Unwind_GetIPInfo.
281 GCC_CHECK_UNWIND_GETIPINFO
282
283
284 GCC_LINUX_FUTEX([AC_DEFINE(HAVE_LINUX_FUTEX, 1, [Define if futex syscall is available.])])
285
286 GCC_HEADER_STDINT(include/gstdint.h)
287
288 # This depends on GLIBCXX CHECK_LINKER_FEATURES, but without it assumes no.
289 GLIBCXX_ENABLE_SYMVERS([yes])
290 GLIBCXX_ENABLE_VISIBILITY([yes])
291
292 ac_ldbl_compat=no
293 case "$target" in
294   powerpc*-*-linux* | \
295   powerpc*-*-gnu* | \
296   sparc*-*-linux* | \
297   s390*-*-linux* | \
298   alpha*-*-linux*)
299   AC_TRY_COMPILE(, [
300 #if !defined __LONG_DOUBLE_128__ || (defined(__sparc__) && defined(__arch64__))
301 #error no need for long double compatibility
302 #endif
303   ], [ac_ldbl_compat=yes], [ac_ldbl_compat=no])
304   if test "$ac_ldbl_compat" = yes; then
305     AC_DEFINE([_GLIBCXX_LONG_DOUBLE_COMPAT],1,
306               [Define if compatibility should be provided for -mlong-double-64.])
307     port_specific_symbol_files="\$(top_srcdir)/config/os/gnu-linux/ldbl-extra.ver"
308   fi
309 esac
310 GLIBCXX_CONDITIONAL(GLIBCXX_LDBL_COMPAT, test $ac_ldbl_compat = yes)
311
312 # This depends on GLIBCXX_ENABLE_SYMVERS and GLIBCXX_IS_NATIVE.
313 GLIBCXX_CONFIGURE_TESTSUITE
314
315 # Propagate the target-specific source directories through the build chain.
316 ATOMICITY_SRCDIR=config/${atomicity_dir}
317 ATOMIC_WORD_SRCDIR=config/${atomic_word_dir}
318 ATOMIC_FLAGS=${atomic_flags}
319 CPU_DEFINES_SRCDIR=config/${cpu_defines_dir}
320 OS_INC_SRCDIR=config/${os_include_dir}
321 ERROR_CONSTANTS_SRCDIR=config/${error_constants_dir}
322 ABI_TWEAKS_SRCDIR=config/${abi_tweaks_dir}
323 AC_SUBST(ATOMICITY_SRCDIR)
324 AC_SUBST(ATOMIC_WORD_SRCDIR)
325 AC_SUBST(ATOMIC_FLAGS)
326 AC_SUBST(CPU_DEFINES_SRCDIR)
327 AC_SUBST(ABI_TWEAKS_SRCDIR)
328 AC_SUBST(OS_INC_SRCDIR)
329 AC_SUBST(ERROR_CONSTANTS_SRCDIR)
330
331
332 # Determine cross-compile flags and AM_CONDITIONALs.
333 #AC_SUBST(GLIBCXX_IS_NATIVE)
334 #AM_CONDITIONAL(CANADIAN, test $CANADIAN = yes)
335 GLIBCXX_EVALUATE_CONDITIONALS
336  
337 AC_CACHE_SAVE
338
339 if test ${multilib} = yes; then
340   multilib_arg="--enable-multilib"
341 else
342   multilib_arg=
343 fi
344
345 # Export all the install information.
346 GLIBCXX_EXPORT_INSTALL_INFO
347
348 # Export all the include and flag information to Makefiles.
349 GLIBCXX_EXPORT_INCLUDES
350 GLIBCXX_EXPORT_FLAGS
351
352 if test "$enable_shared" = yes; then
353   LIBSUPCXX_PICFLAGS="-prefer-pic"
354 else
355   LIBSUPCXX_PICFLAGS=
356 fi
357 AC_SUBST(LIBSUPCXX_PICFLAGS)
358
359 dnl In autoconf 2.5x, AC_OUTPUT is replaced by four AC_CONFIG_* macros,
360 dnl which can all be called multiple times as needed, plus one (different)
361 dnl AC_OUTPUT macro.  This one lists the files to be created:
362 AC_CONFIG_FILES( \
363   Makefile \
364   AC_FOREACH([DIR], glibcxx_SUBDIRS, [DIR/Makefile ])
365   )
366 AC_CONFIG_FILES([scripts/testsuite_flags],[chmod +x scripts/testsuite_flags])
367
368 dnl These commands are run at the end of config.status:
369 AC_CONFIG_COMMANDS([default],
370 [if test -n "$CONFIG_FILES"; then
371    # Multilibs need MULTISUBDIR defined correctly in certain makefiles so
372    # that multilib installs will end up installed in the correct place.
373    # The testsuite needs it for multilib-aware ABI baseline files.
374    # To work around this not being passed down from config-ml.in ->
375    # srcdir/Makefile.am -> srcdir/{src,libsupc++,...}/Makefile.am, manually
376    # append it here.  Only modify Makefiles that have just been created.
377    #
378    # Also, get rid of this simulated-VPATH thing that automake does.
379    cat > vpsed << \_EOF
380 s!`test -f '$<' || echo '$(srcdir)/'`!!
381 _EOF
382    for i in $SUBDIRS; do
383     case $CONFIG_FILES in
384      *${i}/Makefile*)
385        #echo "Adding MULTISUBDIR to $i/Makefile"
386        sed -f vpsed $i/Makefile > tmp
387        grep '^MULTISUBDIR =' Makefile >> tmp
388        mv tmp $i/Makefile
389        ;;
390     esac
391    done
392    rm vpsed
393  fi
394  (cd include && ${MAKE-make})
395 ],
396 [
397 # Variables needed in config.status (file generation) which aren't already
398 # passed by autoconf.
399 SUBDIRS="$SUBDIRS"
400 ])
401
402 dnl And this actually makes things happen:
403 AC_OUTPUT