contrib/perl5/lib/Net/protoent.pm

   1 package Net::protoent;
   2 use strict;
   3
   4 BEGIN {
   5     use Exporter   ();
   6     use vars       qw(@EXPORT @EXPORT_OK %EXPORT_TAGS);
   7     @EXPORT      = qw(getprotobyname getprotobynumber getprotoent);
   8     @EXPORT_OK   = qw( $p_name @p_aliases $p_proto );
   9     %EXPORT_TAGS = ( FIELDS => [ @EXPORT_OK, @EXPORT ] );
  10 }
  11 use vars      @EXPORT_OK;
  12
  13 # Class::Struct forbids use of @ISA
  14 sub import { goto &Exporter::import }
  15
  16 use Class::Struct qw(struct);
  17 struct 'Net::protoent' => [
  18    name         => '$',
  19    aliases      => '@',
  20    proto        => '$',
  21 ];
  22
  23 sub populate (@) {
  24     return unless @_;
  25     my $pob = new();
  26     $p_name      =    $pob->[0]              = $_[0];
  27     @p_aliases   = @{ $pob->[1] } = split ' ', $_[1];
  28     $p_proto     =    $pob->[2]              = $_[2];
  29     return $pob;
  30 }
  31
  32 sub getprotoent      ( )  { populate(CORE::getprotoent()) }
  33 sub getprotobyname   ($)  { populate(CORE::getprotobyname(shift)) }
  34 sub getprotobynumber ($)  { populate(CORE::getprotobynumber(shift)) }
  35
  36 sub getproto ($;$) {
  37     no strict 'refs';
  38     return &{'getprotoby' . ($_[0]=~/^\d+$/ ? 'number' : 'name')}(@_);
  39 }
  40
  41 1;
  42
  43 __END__
  44
  45 =head1 NAME
  46
  47 Net::protoent - by-name interface to Perl's built-in getproto*() functions
  48
  49 =head1 SYNOPSIS
  50
  51  use Net::protoent;
  52  $p = getprotobyname(shift || 'tcp') || die "no proto";
  53  printf "proto for %s is %d, aliases are %s\n",
  54     $p->name, $p->proto, "@{$p->aliases}";
  55
  56  use Net::protoent qw(:FIELDS);
  57  getprotobyname(shift || 'tcp') || die "no proto";
  58  print "proto for $p_name is $p_proto, aliases are @p_aliases\n";
  59
  60 =head1 DESCRIPTION
  61
  62 This module's default exports override the core getprotoent(),
  63 getprotobyname(), and getnetbyport() functions, replacing them with
  64 versions that return "Net::protoent" objects.  They take default
  65 second arguments of "tcp".  This object has methods that return the
  66 similarly named structure field name from the C's protoent structure
  67 from F<netdb.h>; namely name, aliases, and proto.  The aliases method
  68 returns an array reference, the rest scalars.
  69
  70 You may also import all the structure fields directly into your namespace
  71 as regular variables using the :FIELDS import tag.  (Note that this still
  72 overrides your core functions.)  Access these fields as variables named
  73 with a preceding C<p_>.  Thus, C<$proto_obj-E<gt>name()> corresponds to
  74 $p_name if you import the fields.  Array references are available as
  75 regular array variables, so for example C<@{ $proto_obj-E<gt>aliases()
  76 }> would be simply @p_aliases.
  77
  78 The getproto() function is a simple front-end that forwards a numeric
  79 argument to getprotobyport(), and the rest to getprotobyname().
  80
  81 To access this functionality without the core overrides,
  82 pass the C<use> an empty import list, and then access
  83 function functions with their full qualified names.
  84 On the other hand, the built-ins are still available
  85 via the C<CORE::> pseudo-package.
  86
  87 =head1 NOTE
  88
  89 While this class is currently implemented using the Class::Struct
  90 module to build a struct-like class, you shouldn't rely upon this.
  91
  92 =head1 AUTHOR
  93
  94 Tom Christiansen