lib/libc/x86_64/gen/rfork_thread.S

   1 /*-
   2  * Copyright (c) 2000 Peter Wemm <peter@FreeBSD.org>
   3  * Copyright (c) 2003 Alan L. Cox <alc@cs.rice.edu>
   4  * All rights reserved.
   5  *
   6  * Redistribution and use in source and binary forms, with or without
   7  * modification, are permitted provided that the following conditions
   8  * are met:
   9  * 1. Redistributions of source code must retain the above copyright
  10  *    notice, this list of conditions and the following disclaimer.
  11  * 2. Redistributions in binary form must reproduce the above copyright
  12  *    notice, this list of conditions and the following disclaimer in the
  13  *    documentation and/or other materials provided with the distribution.
  14  *
  15  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  16  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  17  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  18  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  19  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  20  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  21  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  22  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  23  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  24  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  25  * SUCH DAMAGE.
  26  *
  27  * $FreeBSD: src/lib/libc/amd64/gen/rfork_thread.S,v 1.2 2008/11/02 01:10:54 peter Exp $
  28  */
  29
  30 #include <machine/asm.h>
  31
  32 /*
  33  * With thanks to John Dyson for the original version of this.
  34  */
  35
  36 #include <SYS.h>
  37
  38 /*
  39  *              %edi   %rsi        %rdx       %rcx
  40  * rfork_thread(flags, stack_addr, start_fnc, start_arg);
  41  *
  42  * flags:               Flags to rfork system call.  See rfork(2).
  43  * stack_addr:          Top of stack for thread.
  44  * start_fnc:           Address of thread function to call in child.
  45  * start_arg:           Argument to pass to the thread function in child.
  46  */
  47
  48 ENTRY(rfork_thread)
  49         pushq   %rbx
  50         pushq   %r12
  51         movq    %rdx, %rbx
  52         movq    %rcx, %r12
  53
  54         /*
  55          * Prepare and execute the thread creation syscall
  56          */
  57         movq    $SYS_rfork, %rax
  58         KERNCALL
  59         jb      2f
  60
  61         /*
  62          * Check to see if we are in the parent or child
  63          */
  64         cmpl    $0, %edx
  65         jnz     1f
  66         popq    %r12
  67         popq    %rbx
  68         ret
  69
  70         /*
  71          * If we are in the child (new thread), then
  72          * set-up the call to the internal subroutine.  If it
  73          * returns, then call __exit.
  74          */
  75 1:
  76         movq    %rsi, %rsp
  77         movq    %r12, %rdi
  78         call    *%rbx
  79         movl    %eax, %edi
  80
  81         /*
  82          * Exit system call
  83          */
  84 #ifdef SYS_exit
  85         movq    $SYS_exit, %rax
  86 #else
  87         movq    $SYS_sys_exit, %rax
  88 #endif
  89         KERNCALL
  90
  91         /*
  92          * Branch here if the thread creation fails:
  93          */
  94 2:
  95         popq    %r12
  96         popq    %rbx
  97 #ifdef PIC
  98         movq    PIC_GOT(HIDENAME(cerror)), %rdx
  99         jmp     *%rdx
 100 #else
 101         jmp     HIDENAME(cerror)
 102 #endif
 103 END(rfork_thread)