sys/platform/pc64/x86_64/swtch.s

   1 /*
   2  * Copyright (c) 2003,2004,2008 The DragonFly Project.  All rights reserved.
   3  * Copyright (c) 2008 Jordan Gordeev.
   4  *
   5  * This code is derived from software contributed to The DragonFly Project
   6  * by Matthew Dillon <dillon@backplane.com>
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  *
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in
  16  *    the documentation and/or other materials provided with the
  17  *    distribution.
  18  * 3. Neither the name of The DragonFly Project nor the names of its
  19  *    contributors may be used to endorse or promote products derived
  20  *    from this software without specific, prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  23  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  24  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  25  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  26  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  27  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  28  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  29  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  30  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  31  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  32  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  *
  35  * Copyright (c) 1990 The Regents of the University of California.
  36  * All rights reserved.
  37  *
  38  * This code is derived from software contributed to Berkeley by
  39  * William Jolitz.
  40  *
  41  * Redistribution and use in source and binary forms, with or without
  42  * modification, are permitted provided that the following conditions
  43  * are met:
  44  * 1. Redistributions of source code must retain the above copyright
  45  *    notice, this list of conditions and the following disclaimer.
  46  * 2. Redistributions in binary form must reproduce the above copyright
  47  *    notice, this list of conditions and the following disclaimer in the
  48  *    documentation and/or other materials provided with the distribution.
  49  * 3. All advertising materials mentioning features or use of this software
  50  *    must display the following acknowledgement:
  51  *      This product includes software developed by the University of
  52  *      California, Berkeley and its contributors.
  53  * 4. Neither the name of the University nor the names of its contributors
  54  *    may be used to endorse or promote products derived from this software
  55  *    without specific prior written permission.
  56  *
  57  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  58  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  59  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  60  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  61  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  62  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  63  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  64  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  65  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  66  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  67  * SUCH DAMAGE.
  68  *
  69  * $FreeBSD: src/sys/i386/i386/swtch.s,v 1.89.2.10 2003/01/23 03:36:24 ps Exp $
  70  */
  71
  72 //#include "use_npx.h"
  73
  74 #include <sys/rtprio.h>
  75
  76 #include <machine/asmacros.h>
  77 #include <machine/segments.h>
  78
  79 #include <machine/pmap.h>
  80 #if JG
  81 #include <machine_base/apic/apicreg.h>
  82 #endif
  83 #include <machine/lock.h>
  84
  85 #define CHECKNZ(expr, scratch_reg) \
  86         movq expr, scratch_reg; testq scratch_reg, scratch_reg; jnz 7f; int $3; 7:
  87
  88 #include "assym.s"
  89
  90 #if defined(SMP)
  91 #define MPLOCKED        lock ;
  92 #else
  93 #define MPLOCKED
  94 #endif
  95
  96         .data
  97
  98         .globl  panic
  99
 100 #if defined(SWTCH_OPTIM_STATS)
 101         .globl  swtch_optim_stats, tlb_flush_count
 102 swtch_optim_stats:      .long   0               /* number of _swtch_optims */
 103 tlb_flush_count:        .long   0
 104 #endif
 105
 106         .text
 107
 108
 109 /*
 110  * cpu_heavy_switch(struct thread *next_thread)
 111  *
 112  *      Switch from the current thread to a new thread.  This entry
 113  *      is normally called via the thread->td_switch function, and will
 114  *      only be called when the current thread is a heavy weight process.
 115  *
 116  *      Some instructions have been reordered to reduce pipeline stalls.
 117  *
 118  *      YYY disable interrupts once giant is removed.
 119  */
 120 ENTRY(cpu_heavy_switch)
 121         /*
 122          * Save RIP, RSP and callee-saved registers (RBX, RBP, R12-R15).
 123          */
 124         movq    PCPU(curthread),%rcx
 125         /* On top of the stack is the return adress. */
 126         movq    (%rsp),%rax                     /* (reorder optimization) */
 127         movq    TD_PCB(%rcx),%rdx               /* RDX = PCB */
 128         movq    %rax,PCB_RIP(%rdx)              /* return PC may be modified */
 129         movq    %rbx,PCB_RBX(%rdx)
 130         movq    %rsp,PCB_RSP(%rdx)
 131         movq    %rbp,PCB_RBP(%rdx)
 132         movq    %r12,PCB_R12(%rdx)
 133         movq    %r13,PCB_R13(%rdx)
 134         movq    %r14,PCB_R14(%rdx)
 135         movq    %r15,PCB_R15(%rdx)
 136
 137         movq    %rcx,%rbx                       /* RBX = curthread */
 138         movq    TD_LWP(%rcx),%rcx
 139         movl    PCPU(cpuid), %eax
 140         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 141         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%rcx)
 142
 143         /*
 144          * Push the LWKT switch restore function, which resumes a heavy
 145          * weight process.  Note that the LWKT switcher is based on
 146          * TD_SP, while the heavy weight process switcher is based on
 147          * PCB_RSP.  TD_SP is usually two ints pushed relative to
 148          * PCB_RSP.  We push the flags for later restore by cpu_heavy_restore.
 149          */
 150         pushfq
 151         movq    $cpu_heavy_restore, %rax
 152         pushq   %rax
 153         movq    %rsp,TD_SP(%rbx)
 154
 155         /*
 156          * Save debug regs if necessary
 157          */
 158         movq    PCB_FLAGS(%rdx),%rax
 159         andq    $PCB_DBREGS,%rax
 160         jz      1f                              /* no, skip over */
 161         movq    %dr7,%rax                       /* yes, do the save */
 162         movq    %rax,PCB_DR7(%rdx)
 163         /* JG correct value? */
 164         andq    $0x0000fc00, %rax               /* disable all watchpoints */
 165         movq    %rax,%dr7
 166         movq    %dr6,%rax
 167         movq    %rax,PCB_DR6(%rdx)
 168         movq    %dr3,%rax
 169         movq    %rax,PCB_DR3(%rdx)
 170         movq    %dr2,%rax
 171         movq    %rax,PCB_DR2(%rdx)
 172         movq    %dr1,%rax
 173         movq    %rax,PCB_DR1(%rdx)
 174         movq    %dr0,%rax
 175         movq    %rax,PCB_DR0(%rdx)
 176 1:
 177
 178 #if 1
 179         /*
 180          * Save the FP state if we have used the FP.  Note that calling
 181          * npxsave will NULL out PCPU(npxthread).
 182          */
 183         cmpq    %rbx,PCPU(npxthread)
 184         jne     1f
 185         movq    %rdi,%r12               /* save %rdi. %r12 is callee-saved */
 186         movq    TD_SAVEFPU(%rbx),%rdi
 187         call    npxsave                 /* do it in a big C function */
 188         movq    %r12,%rdi               /* restore %rdi */
 189 1:
 190 #endif
 191
 192         /*
 193          * Switch to the next thread, which was passed as an argument
 194          * to cpu_heavy_switch().  The argument is in %rdi.
 195          * Set the current thread, load the stack pointer,
 196          * and 'ret' into the switch-restore function.
 197          *
 198          * The switch restore function expects the new thread to be in %rax
 199          * and the old one to be in %rbx.
 200          *
 201          * There is a one-instruction window where curthread is the new
 202          * thread but %rsp still points to the old thread's stack, but
 203          * we are protected by a critical section so it is ok.
 204          */
 205         movq    %rdi,%rax               /* RAX = newtd, RBX = oldtd */
 206         movq    %rax,PCPU(curthread)
 207         movq    TD_SP(%rax),%rsp
 208         CHECKNZ((%rsp), %r9)
 209         ret
 210
 211 /*
 212  *  cpu_exit_switch(struct thread *next)
 213  *
 214  *      The switch function is changed to this when a thread is going away
 215  *      for good.  We have to ensure that the MMU state is not cached, and
 216  *      we don't bother saving the existing thread state before switching.
 217  *
 218  *      At this point we are in a critical section and this cpu owns the
 219  *      thread's token, which serves as an interlock until the switchout is
 220  *      complete.
 221  */
 222 ENTRY(cpu_exit_switch)
 223         /*
 224          * Get us out of the vmspace
 225          */
 226         movq    KPML4phys,%rcx
 227         movq    %cr3,%rax
 228         cmpq    %rcx,%rax
 229         je      1f
 230         /* JG no increment of statistics counters? see cpu_heavy_restore */
 231         movq    %rcx,%cr3
 232 1:
 233         movq    PCPU(curthread),%rbx
 234
 235         /*
 236          * If this is a process/lwp, deactivate the pmap after we've
 237          * switched it out.
 238          */
 239         movq    TD_LWP(%rbx),%rcx
 240         testq   %rcx,%rcx
 241         jz      2f
 242         movl    PCPU(cpuid), %eax
 243         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 244         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%rcx)
 245 2:
 246         /*
 247          * Switch to the next thread.  RET into the restore function, which
 248          * expects the new thread in RAX and the old in RBX.
 249          *
 250          * There is a one-instruction window where curthread is the new
 251          * thread but %rsp still points to the old thread's stack, but
 252          * we are protected by a critical section so it is ok.
 253          */
 254         movq    %rdi,%rax
 255         movq    %rax,PCPU(curthread)
 256         movq    TD_SP(%rax),%rsp
 257         CHECKNZ((%rsp), %r9)
 258         ret
 259
 260 /*
 261  * cpu_heavy_restore()  (current thread in %rax on entry)
 262  *
 263  *      Restore the thread after an LWKT switch.  This entry is normally
 264  *      called via the LWKT switch restore function, which was pulled
 265  *      off the thread stack and jumped to.
 266  *
 267  *      This entry is only called if the thread was previously saved
 268  *      using cpu_heavy_switch() (the heavy weight process thread switcher),
 269  *      or when a new process is initially scheduled.  The first thing we
 270  *      do is clear the TDF_RUNNING bit in the old thread and set it in the
 271  *      new thread.
 272  *
 273  *      NOTE: The lwp may be in any state, not necessarily LSRUN, because
 274  *      a preemption switch may interrupt the process and then return via
 275  *      cpu_heavy_restore.
 276  *
 277  *      YYY theoretically we do not have to restore everything here, a lot
 278  *      of this junk can wait until we return to usermode.  But for now
 279  *      we restore everything.
 280  *
 281  *      YYY the PCB crap is really crap, it makes startup a bitch because
 282  *      we can't switch away.
 283  *
 284  *      YYY note: spl check is done in mi_switch when it splx()'s.
 285  */
 286
 287 ENTRY(cpu_heavy_restore)
 288         popfq
 289         movq    TD_PCB(%rax),%rdx               /* RDX = PCB */
 290         movq    TD_LWP(%rax),%rcx
 291
 292 #if defined(SWTCH_OPTIM_STATS)
 293         incl    _swtch_optim_stats
 294 #endif
 295         /*
 296          * Tell the pmap that our cpu is using the VMSPACE now.  We cannot
 297          * safely test/reload %cr3 until after we have set the bit in the
 298          * pmap (remember, we do not hold the MP lock in the switch code).
 299          */
 300         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 301         movl    PCPU(cpuid), %esi
 302         MPLOCKED btsl   %esi, VM_PMAP+PM_ACTIVE(%rcx)
 303
 304         /*
 305          * Restore the MMU address space.  If it is the same as the last
 306          * thread we don't have to invalidate the tlb (i.e. reload cr3).
 307          * YYY which naturally also means that the PM_ACTIVE bit had better
 308          * already have been set before we set it above, check? YYY
 309          */
 310         movq    %cr3,%rsi
 311         movq    PCB_CR3(%rdx),%rcx
 312         cmpq    %rsi,%rcx
 313         je      4f
 314 #if defined(SWTCH_OPTIM_STATS)
 315         decl    _swtch_optim_stats
 316         incl    _tlb_flush_count
 317 #endif
 318         movq    %rcx,%cr3
 319 4:
 320         /*
 321          * Clear TDF_RUNNING flag in old thread only after cleaning up
 322          * %cr3.  The target thread is already protected by being TDF_RUNQ
 323          * so setting TDF_RUNNING isn't as big a deal.
 324          */
 325         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 326         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 327
 328         /*
 329          * Deal with the PCB extension, restore the private tss
 330          */
 331         movq    PCB_EXT(%rdx),%rdi      /* check for a PCB extension */
 332         /* JG cheaper than "movq $1,%rbx", right? */
 333         /* JG what's that magic value $1? */
 334         movl    $1,%ebx                 /* maybe mark use of a private tss */
 335         testq   %rdi,%rdi
 336 #if JG
 337         jnz     2f
 338 #endif
 339
 340         /* JG
 341          * Going back to the common_tss.  We may need to update TSS_ESP0
 342          * which sets the top of the supervisor stack when entering from
 343          * usermode.  The PCB is at the top of the stack but we need another
 344          * 16 bytes to take vm86 into account.
 345          */
 346         leaq    -16(%rdx),%rbx
 347         movq    %rbx, PCPU(common_tss) + TSS_RSP0
 348         movq    %rbx, PCPU(rsp0)
 349
 350 #if JG
 351         cmpl    $0,PCPU(private_tss)    /* don't have to reload if      */
 352         je      3f                      /* already using the common TSS */
 353
 354         /* JG? */
 355         subl    %ebx,%ebx               /* unmark use of private tss */
 356
 357         /*
 358          * Get the address of the common TSS descriptor for the ltr.
 359          * There is no way to get the address of a segment-accessed variable
 360          * so we store a self-referential pointer at the base of the per-cpu
 361          * data area and add the appropriate offset.
 362          */
 363         /* JG movl? */
 364         movq    $gd_common_tssd, %rdi
 365         /* JG name for "%gs:0"? */
 366         addq    %gs:0, %rdi
 367
 368         /*
 369          * Move the correct TSS descriptor into the GDT slot, then reload
 370          * ltr.
 371          */
 372 2:
 373         /* JG */
 374         movl    %ebx,PCPU(private_tss)          /* mark/unmark private tss */
 375         movq    PCPU(tss_gdt), %rbx             /* entry in GDT */
 376         movq    0(%rdi), %rax
 377         movq    %rax, 0(%rbx)
 378         movl    $GPROC0_SEL*8, %esi             /* GSEL(entry, SEL_KPL) */
 379         ltr     %si
 380 #endif
 381
 382 3:
 383         /*
 384          * Restore the user %gs and %fs
 385          */
 386         movq    PCB_FSBASE(%rdx),%r9
 387         cmpq    PCPU(user_fs),%r9
 388         je      4f
 389         movq    %rdx,%r10
 390         movq    %r9,PCPU(user_fs)
 391         movl    $MSR_FSBASE,%ecx
 392         movl    PCB_FSBASE(%r10),%eax
 393         movl    PCB_FSBASE+4(%r10),%edx
 394         wrmsr
 395         movq    %r10,%rdx
 396 4:
 397         movq    PCB_GSBASE(%rdx),%r9
 398         cmpq    PCPU(user_gs),%r9
 399         je      5f
 400         movq    %rdx,%r10
 401         movq    %r9,PCPU(user_gs)
 402         movl    $MSR_KGSBASE,%ecx       /* later swapgs moves it to GSBASE */
 403         movl    PCB_GSBASE(%r10),%eax
 404         movl    PCB_GSBASE+4(%r10),%edx
 405         wrmsr
 406         movq    %r10,%rdx
 407 5:
 408
 409         /*
 410          * Restore general registers.
 411          */
 412         movq    PCB_RBX(%rdx), %rbx
 413         movq    PCB_RSP(%rdx), %rsp
 414         movq    PCB_RBP(%rdx), %rbp
 415         movq    PCB_R12(%rdx), %r12
 416         movq    PCB_R13(%rdx), %r13
 417         movq    PCB_R14(%rdx), %r14
 418         movq    PCB_R15(%rdx), %r15
 419         movq    PCB_RIP(%rdx), %rax
 420         movq    %rax, (%rsp)
 421
 422 #if JG
 423         /*
 424          * Restore the user LDT if we have one
 425          */
 426         cmpl    $0, PCB_USERLDT(%edx)
 427         jnz     1f
 428         movl    _default_ldt,%eax
 429         cmpl    PCPU(currentldt),%eax
 430         je      2f
 431         lldt    _default_ldt
 432         movl    %eax,PCPU(currentldt)
 433         jmp     2f
 434 1:      pushl   %edx
 435         call    set_user_ldt
 436         popl    %edx
 437 2:
 438 #endif
 439 #if JG
 440         /*
 441          * Restore the user TLS if we have one
 442          */
 443         pushl   %edx
 444         call    set_user_TLS
 445         popl    %edx
 446 #endif
 447
 448         /*
 449          * Restore the DEBUG register state if necessary.
 450          */
 451         movq    PCB_FLAGS(%rdx),%rax
 452         andq    $PCB_DBREGS,%rax
 453         jz      1f                              /* no, skip over */
 454         movq    PCB_DR6(%rdx),%rax              /* yes, do the restore */
 455         movq    %rax,%dr6
 456         movq    PCB_DR3(%rdx),%rax
 457         movq    %rax,%dr3
 458         movq    PCB_DR2(%rdx),%rax
 459         movq    %rax,%dr2
 460         movq    PCB_DR1(%rdx),%rax
 461         movq    %rax,%dr1
 462         movq    PCB_DR0(%rdx),%rax
 463         movq    %rax,%dr0
 464         movq    %dr7,%rax                /* load dr7 so as not to disturb */
 465         /* JG correct value? */
 466         andq    $0x0000fc00,%rax         /*   reserved bits               */
 467         /* JG we've got more registers on x86_64 */
 468         pushq   %rbx
 469         movq    PCB_DR7(%rdx),%rbx
 470         /* JG correct value? */
 471         andq    $~0x0000fc00,%rbx
 472         orq     %rbx,%rax
 473         popq    %rbx
 474         movq    %rax,%dr7
 475 1:
 476
 477         CHECKNZ((%rsp), %r9)
 478         ret
 479
 480 /*
 481  * savectx(struct pcb *pcb)
 482  *
 483  * Update pcb, saving current processor state.
 484  */
 485 ENTRY(savectx)
 486         /* fetch PCB */
 487         /* JG use %rdi instead of %rcx everywhere? */
 488         movq    %rdi,%rcx
 489
 490         /* caller's return address - child won't execute this routine */
 491         movq    (%rsp),%rax
 492         movq    %rax,PCB_RIP(%rcx)
 493
 494         movq    %cr3,%rax
 495         movq    %rax,PCB_CR3(%rcx)
 496
 497         movq    %rbx,PCB_RBX(%rcx)
 498         movq    %rsp,PCB_RSP(%rcx)
 499         movq    %rbp,PCB_RBP(%rcx)
 500         movq    %r12,PCB_R12(%rcx)
 501         movq    %r13,PCB_R13(%rcx)
 502         movq    %r14,PCB_R14(%rcx)
 503         movq    %r15,PCB_R15(%rcx)
 504
 505 #if 1
 506         /*
 507          * If npxthread == NULL, then the npx h/w state is irrelevant and the
 508          * state had better already be in the pcb.  This is true for forks
 509          * but not for dumps (the old book-keeping with FP flags in the pcb
 510          * always lost for dumps because the dump pcb has 0 flags).
 511          *
 512          * If npxthread != NULL, then we have to save the npx h/w state to
 513          * npxthread's pcb and copy it to the requested pcb, or save to the
 514          * requested pcb and reload.  Copying is easier because we would
 515          * have to handle h/w bugs for reloading.  We used to lose the
 516          * parent's npx state for forks by forgetting to reload.
 517          */
 518         movq    PCPU(npxthread),%rax
 519         testq   %rax,%rax
 520         jz      1f
 521
 522         pushq   %rcx                    /* target pcb */
 523         movq    TD_SAVEFPU(%rax),%rax   /* originating savefpu area */
 524         pushq   %rax
 525
 526         movq    %rax,%rdi
 527         call    npxsave
 528
 529         popq    %rax
 530         popq    %rcx
 531
 532         movq    $PCB_SAVEFPU_SIZE,%rdx
 533         leaq    PCB_SAVEFPU(%rcx),%rcx
 534         movq    %rcx,%rsi
 535         movq    %rax,%rdi
 536         call    bcopy
 537 #endif
 538
 539 1:
 540         CHECKNZ((%rsp), %r9)
 541         ret
 542
 543 /*
 544  * cpu_idle_restore()   (current thread in %rax on entry) (one-time execution)
 545  *
 546  *      Don't bother setting up any regs other than %rbp so backtraces
 547  *      don't die.  This restore function is used to bootstrap into the
 548  *      cpu_idle() LWKT only, after that cpu_lwkt_*() will be used for
 549  *      switching.
 550  *
 551  *      Clear TDF_RUNNING in old thread only after we've cleaned up %cr3.
 552  *
 553  *      If we are an AP we have to call ap_init() before jumping to
 554  *      cpu_idle().  ap_init() will synchronize with the BP and finish
 555  *      setting up various ncpu-dependant globaldata fields.  This may
 556  *      happen on UP as well as SMP if we happen to be simulating multiple
 557  *      cpus.
 558  */
 559 ENTRY(cpu_idle_restore)
 560         /* cli */
 561         movq    KPML4phys,%rcx
 562         /* JG xor? */
 563         movl    $0,%ebp
 564         /* JG push RBP? */
 565         pushq   $0
 566         movq    %rcx,%cr3
 567         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 568         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 569 #ifdef SMP
 570         cmpl    $0,PCPU(cpuid)
 571         je      1f
 572         call    ap_init
 573 1:
 574 #endif
 575         /*
 576          * ap_init can decide to enable interrupts early, but otherwise, or if
 577          * we are UP, do it here.
 578          */
 579         sti
 580         jmp     cpu_idle
 581
 582 /*
 583  * cpu_kthread_restore() (current thread is %rax on entry) (one-time execution)
 584  *
 585  *      Don't bother setting up any regs other then %rbp so backtraces
 586  *      don't die.  This restore function is used to bootstrap into an
 587  *      LWKT based kernel thread only.  cpu_lwkt_switch() will be used
 588  *      after this.
 589  *
 590  *      Since all of our context is on the stack we are reentrant and
 591  *      we can release our critical section and enable interrupts early.
 592  */
 593 ENTRY(cpu_kthread_restore)
 594         sti
 595         movq    KPML4phys,%rcx
 596         movq    TD_PCB(%rax),%rdx
 597         /* JG "movq $0, %rbp"? "xorq %rbp, %rbp"? */
 598         movl    $0,%ebp
 599         movq    %rcx,%cr3
 600         /* rax and rbx come from the switchout code */
 601         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 602         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 603         subl    $TDPRI_CRIT,TD_PRI(%rax)
 604         movq    PCB_R12(%rdx),%rdi      /* argument to RBX function */
 605         movq    PCB_RBX(%rdx),%rax      /* thread function */
 606         /* note: top of stack return address inherited by function */
 607         CHECKNZ(%rax, %r9)
 608         jmp     *%rax
 609
 610 /*
 611  * cpu_lwkt_switch(struct thread *)
 612  *
 613  *      Standard LWKT switching function.  Only non-scratch registers are
 614  *      saved and we don't bother with the MMU state or anything else.
 615  *
 616  *      This function is always called while in a critical section.
 617  *
 618  *      There is a one-instruction window where curthread is the new
 619  *      thread but %rsp still points to the old thread's stack, but
 620  *      we are protected by a critical section so it is ok.
 621  *
 622  *      YYY BGL, SPL
 623  */
 624 ENTRY(cpu_lwkt_switch)
 625         pushq   %rbp    /* JG note: GDB hacked to locate ebp relative to td_sp */
 626         /* JG we've got more registers on x86_64 */
 627         pushq   %rbx
 628         movq    PCPU(curthread),%rbx
 629         pushq   %r12
 630         pushq   %r13
 631         pushq   %r14
 632         pushq   %r15
 633         pushfq
 634
 635 #if 1
 636         /*
 637          * Save the FP state if we have used the FP.  Note that calling
 638          * npxsave will NULL out PCPU(npxthread).
 639          *
 640          * We have to deal with the FP state for LWKT threads in case they
 641          * happen to get preempted or block while doing an optimized
 642          * bzero/bcopy/memcpy.
 643          */
 644         cmpq    %rbx,PCPU(npxthread)
 645         jne     1f
 646         movq    %rdi,%r12               /* save %rdi. %r12 is callee-saved */
 647         movq    TD_SAVEFPU(%rbx),%rdi
 648         call    npxsave                 /* do it in a big C function */
 649         movq    %r12,%rdi               /* restore %rdi */
 650 1:
 651 #endif
 652
 653         movq    %rdi,%rax               /* switch to this thread */
 654         pushq   $cpu_lwkt_restore
 655         movq    %rsp,TD_SP(%rbx)
 656         movq    %rax,PCPU(curthread)
 657         movq    TD_SP(%rax),%rsp
 658
 659         /*
 660          * %rax contains new thread, %rbx contains old thread.
 661          */
 662         CHECKNZ((%rsp), %r9)
 663         ret
 664
 665 /*
 666  * cpu_lwkt_restore()   (current thread in %rax on entry)
 667  *
 668  *      Standard LWKT restore function.  This function is always called
 669  *      while in a critical section.
 670  *
 671  *      Warning: due to preemption the restore function can be used to
 672  *      'return' to the original thread.  Interrupt disablement must be
 673  *      protected through the switch so we cannot run splz here.
 674  *
 675  *      YYY we theoretically do not need to load KPML4phys into cr3, but if
 676  *      so we need a way to detect when the PTD we are using is being
 677  *      deleted due to a process exiting.
 678  */
 679 ENTRY(cpu_lwkt_restore)
 680         movq    KPML4phys,%rcx  /* YYY borrow but beware desched/cpuchg/exit */
 681         movq    %cr3,%rdx
 682         cmpq    %rcx,%rdx
 683         je      1f
 684         movq    %rcx,%cr3
 685 1:
 686         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 687         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 688         popfq
 689         popq    %r15
 690         popq    %r14
 691         popq    %r13
 692         popq    %r12
 693         popq    %rbx
 694         popq    %rbp
 695         ret