sbin/devd/token.l

   1 %{
   2 /*-
   3  * DEVD (Device action daemon)
   4  *
   5  * Copyright (c) 2002 M. Warner Losh <imp@freebsd.org>.
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  *
  29  * $FreeBSD: src/sbin/devd/token.l,v 1.7 2008/03/21 20:38:28 imp Exp $
  30  */
  31
  32 #pragma GCC diagnostic ignored "-Wsign-compare"
  33 #include <ctype.h>
  34 #include <stdlib.h>
  35 #include <string.h>
  36 #include <syslog.h>
  37 #include "devd.h"
  38 #include "y.tab.h"
  39
  40 int lineno = 1;
  41
  42 static void
  43 update_lineno(const char *cp)
  44 {
  45         while (*cp)
  46                 if (*cp++ == '\n')
  47                         lineno++;
  48 }
  49
  50 %}
  51
  52 %option nounput
  53 %option noinput
  54
  55 %%
  56
  57 [ \t]+                  ;
  58 \n                      lineno++;
  59 ;                       { return SEMICOLON; }
  60 #.*$                    ;
  61 \/\/.*$                 ;
  62 \/\*([^*]|(\*+([^*\/])))*\*+\/ { update_lineno(yytext); }
  63 \{                      { return BEGINBLOCK; }
  64 \}                      { return ENDBLOCK; }
  65 [0-9]+                  { yylval.i = atoi(yytext); return NUMBER; }
  66 \"[^"]+\"               {
  67                                 int len = strlen(yytext) - 2;
  68                                 char *walker;
  69                                 int i;
  70                                 update_lineno(yytext);
  71                                 if ((yylval.str = (char *) malloc(len + 1)) == NULL)
  72                                         goto out;
  73                                 walker = yylval.str;
  74                                 for (i = 1; i <= len; i++) {
  75                                         if (yytext[i] == '\\' &&
  76                                             yytext[i + 1] == '\n') {
  77                                                 i += 2;
  78                                                 while(isspace(yytext[i]))
  79                                                         i++;
  80                                         }
  81                                         *walker++ = yytext[i];
  82                                 }
  83                                 *walker++ = '\0';
  84                         out:;
  85                                 return STRING;
  86                         }
  87
  88
  89 options                 { return OPTIONS; }
  90 set                     { return SET; }
  91 directory               { return DIRECTORY; }
  92 pid-file                { return PID_FILE; }
  93 attach                  { return ATTACH; }
  94 detach                  { return DETACH; }
  95 device-name             { return DEVICE_NAME; }
  96 media-type              { return MEDIA_TYPE; }
  97 class                   { return CLASS; }
  98 subdevice               { return SUBDEVICE; }
  99 action                  { return ACTION; }
 100 match                   { return MATCH; }
 101 nomatch                 { return NOMATCH; }
 102 notify                  { return NOTIFY; }
 103 [A-Za-z][A-Za-z0-9_-]*  {
 104                                 yylval.str = strdup(yytext);
 105                                 return ID;
 106                         }
 107 %%
 108
 109 void
 110 yyerror(const char *s)
 111 {
 112         syslog(LOG_ERR, "line %d: %s%s %s.\n", lineno, yytext, yytext?":":"", s);
 113 }