gcc44 warns: Put input() under YY_NO_INPUT and set that if it isn't used.
[dragonfly.git] / usr.sbin / config / lang.l
1 %{
2 /*-
3  * Copyright (c) 1980, 1993
4  *      The Regents of the University of California.  All rights reserved.
5  *
6  * Redistribution and use in source and binary forms, with or without
7  * modification, are permitted provided that the following conditions
8  * are met:
9  * 1. Redistributions of source code must retain the above copyright
10  *    notice, this list of conditions and the following disclaimer.
11  * 2. Redistributions in binary form must reproduce the above copyright
12  *    notice, this list of conditions and the following disclaimer in the
13  *    documentation and/or other materials provided with the distribution.
14  * 3. All advertising materials mentioning features or use of this software
15  *    must display the following acknowledgement:
16  *      This product includes software developed by the University of
17  *      California, Berkeley and its contributors.
18  * 4. Neither the name of the University nor the names of its contributors
19  *    may be used to endorse or promote products derived from this software
20  *    without specific prior written permission.
21  *
22  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
23  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
24  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
25  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
26  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
27  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
28  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
29  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
30  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
31  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
32  * SUCH DAMAGE.
33  *
34  *      @(#)lang.l      8.1 (Berkeley) 6/6/93
35  * $FreeBSD: src/usr.sbin/config/lang.l,v 1.27 1999/11/09 07:20:22 peter Exp $
36  * $DragonFly: src/usr.sbin/config/lang.l,v 1.14 2008/05/01 09:24:42 swildner Exp $
37  */
38
39 #include <ctype.h>
40 #include <string.h>
41 #include "y.tab.h"
42 #include "config.h"
43
44 #define YY_NO_INPUT
45 #define YY_NO_UNPUT
46
47 /*
48  * Key word table
49  */
50
51 struct kt {
52         const char *kt_name;
53         int kt_val;
54 } key_words[] = {
55         { "at",         AT },
56         { "bus",        BUS },
57         { "config",     CONFIG },
58         { "cpu",        CPU },
59         { "device",     DEVICE },
60         { "disable",    DISABLE },
61         { "drive",      DRIVE },
62         { "drq",        DRQ },
63         { "flags",      FLAGS },
64         { "ident",      IDENT },
65         { "iomem",      IOMEM },
66         { "iosiz",      IOSIZ },
67         { "irq",        IRQ },
68         { "machine",    CONFIG_MACHINE },
69         { "machine_arch", CONFIG_MACHINE_ARCH },
70         { "makeoptions", MAKEOPTIONS },
71         { "maxusers",   MAXUSERS },
72         { "nexus",      NEXUS },
73         { "option",     OPTIONS },
74         { "options",    OPTIONS },
75         { "platform",   CONFIG_PLATFORM },
76         { "port",       PORT },
77         { "pseudo-device",PSEUDO_DEVICE },
78         { "target",     TARGET },
79         { "unit",       UNIT },
80         { 0, 0 },
81 };
82
83
84 int kw_lookup(char *);
85 int octal(char *);
86 int hex(char *);
87
88 %}
89 WORD    [A-Za-z_][-A-Za-z_]*
90 ID      [A-Za-z_][-A-Za-z_0-9]*
91 %START NONUM TOEOL
92 %%
93 <NONUM>{WORD}   {
94                         int i;
95
96                         BEGIN 0;
97                         if ((i = kw_lookup(yytext)) == -1)
98                         {
99                                 yylval.str = strdup(yytext);
100                                 return(ID);
101                         }
102                         return(i);
103                 }
104 <INITIAL>{WORD}/[0-9]* {
105                         int i;
106
107                         if ((i = kw_lookup(yytext)) == -1)
108                                 REJECT;
109                         if (i == DEVICE || i == PSEUDO_DEVICE || i == AT)
110                                 BEGIN NONUM;
111                         return(i);
112                 }
113 <INITIAL>{ID}   {
114                         BEGIN 0;
115                         yylval.str = strdup(yytext);
116                         return(ID);
117                 }
118 \\\"[^"]+\\\"   {
119                         BEGIN 0;
120                         yytext[yyleng-2] = '"';
121                         yytext[yyleng-1] = '\0';
122                         yylval.str = strdup(yytext + 1);
123                         return(ID);
124                 }
125 \"[^"]+\"       {
126                         BEGIN 0;
127                         yytext[yyleng-1] = '\0';
128                         yylval.str = strdup(yytext + 1);
129                         return(ID);
130                 }
131 <TOEOL>[^# \t\n]*       {
132                         BEGIN 0;
133                         yylval.str = strdup(yytext);
134                         return(ID);
135                 }
136 0[0-7]*         {
137                         yylval.val = octal(yytext);
138                         return(NUMBER);
139                 }
140 0x[0-9a-fA-F]+  {
141                         yylval.val = hex(yytext);
142                         return(NUMBER);
143                 }
144 -?[1-9][0-9]*   {
145                         yylval.val = atoi(yytext);
146                         return(NUMBER);
147                 }
148 [0-9]"."[0-9]*  {
149                         yylval.val = (int)(60 * atof(yytext) + 0.5);
150                         return(FPNUMBER);
151                 }
152 "?"             {
153                         yylval.val = -1;
154                         return(NUMBER);
155                 }
156 \n/[ \t]        {
157                         yyline++;
158                 }
159 \n              {
160                         yyline++;
161                         return(SEMICOLON);
162                 }
163 #.*             {       /* Ignored (comment) */;        }
164 [ \t\f]*        {       /* Ignored (white space) */;    }
165 ";"             {       return(SEMICOLON);              }
166 ","             {       return(COMMA);                  }
167 "="             {       BEGIN TOEOL; return(EQUALS);    }
168 "@"             {       return(AT);                     }
169 .               {       return(yytext[0]);              }
170
171 %%
172 /*
173  * kw_lookup
174  *      Look up a string in the keyword table.  Returns a -1 if the
175  *      string is not a keyword otherwise it returns the keyword number
176  */
177
178 int
179 kw_lookup(char *word)
180 {
181         struct kt *kp;
182
183         for (kp = key_words; kp->kt_name != NULL; kp++)
184                 if (!strcmp(word, kp->kt_name))
185                         return(kp->kt_val);
186         return(-1);
187 }
188
189 /*
190  * Number conversion routines
191  */
192
193 int
194 octal(char *str)
195 {
196         int num;
197
198         sscanf(str, "%o", &num);
199         return(num);
200 }
201
202 int
203 hex(char *str)
204 {
205         int num;
206
207         sscanf(str + 2, "%x", &num);
208         return(num);
209 }