sys/platform/pc64/amd64/swtch.s

   1 /*
   2  * Copyright (c) 2003,2004,2008 The DragonFly Project.  All rights reserved.
   3  * Copyright (c) 2008 Jordan Gordeev.
   4  *
   5  * This code is derived from software contributed to The DragonFly Project
   6  * by Matthew Dillon <dillon@backplane.com>
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  *
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in
  16  *    the documentation and/or other materials provided with the
  17  *    distribution.
  18  * 3. Neither the name of The DragonFly Project nor the names of its
  19  *    contributors may be used to endorse or promote products derived
  20  *    from this software without specific, prior written permission.
  21  *
  22  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  23  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  24  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  25  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  26  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  27  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  28  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  29  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  30  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  31  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  32  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  33  * SUCH DAMAGE.
  34  *
  35  * Copyright (c) 1990 The Regents of the University of California.
  36  * All rights reserved.
  37  *
  38  * This code is derived from software contributed to Berkeley by
  39  * William Jolitz.
  40  *
  41  * Redistribution and use in source and binary forms, with or without
  42  * modification, are permitted provided that the following conditions
  43  * are met:
  44  * 1. Redistributions of source code must retain the above copyright
  45  *    notice, this list of conditions and the following disclaimer.
  46  * 2. Redistributions in binary form must reproduce the above copyright
  47  *    notice, this list of conditions and the following disclaimer in the
  48  *    documentation and/or other materials provided with the distribution.
  49  * 3. All advertising materials mentioning features or use of this software
  50  *    must display the following acknowledgement:
  51  *      This product includes software developed by the University of
  52  *      California, Berkeley and its contributors.
  53  * 4. Neither the name of the University nor the names of its contributors
  54  *    may be used to endorse or promote products derived from this software
  55  *    without specific prior written permission.
  56  *
  57  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  58  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  59  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  60  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  61  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  62  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  63  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  64  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  65  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  66  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  67  * SUCH DAMAGE.
  68  *
  69  * $FreeBSD: src/sys/i386/i386/swtch.s,v 1.89.2.10 2003/01/23 03:36:24 ps Exp $
  70  * $DragonFly: src/sys/platform/pc64/amd64/swtch.s,v 1.3 2008/08/29 17:07:10 dillon Exp $
  71  */
  72
  73 //#include "use_npx.h"
  74
  75 #include <sys/rtprio.h>
  76
  77 #include <machine/asmacros.h>
  78 #include <machine/segments.h>
  79
  80 #include <machine/pmap.h>
  81 #if JG
  82 #include <machine_base/apic/apicreg.h>
  83 #endif
  84 #include <machine/lock.h>
  85
  86 #define CHECKNZ(expr, scratch_reg) \
  87         movq expr, scratch_reg; testq scratch_reg, scratch_reg; jnz 7f; int $3; 7:
  88
  89 #include "assym.s"
  90
  91 #if defined(SMP)
  92 #define MPLOCKED        lock ;
  93 #else
  94 #define MPLOCKED
  95 #endif
  96
  97         .data
  98
  99         .globl  panic
 100
 101 #if defined(SWTCH_OPTIM_STATS)
 102         .globl  swtch_optim_stats, tlb_flush_count
 103 swtch_optim_stats:      .long   0               /* number of _swtch_optims */
 104 tlb_flush_count:        .long   0
 105 #endif
 106
 107         .text
 108
 109
 110 /*
 111  * cpu_heavy_switch(struct thread *next_thread)
 112  *
 113  *      Switch from the current thread to a new thread.  This entry
 114  *      is normally called via the thread->td_switch function, and will
 115  *      only be called when the current thread is a heavy weight process.
 116  *
 117  *      Some instructions have been reordered to reduce pipeline stalls.
 118  *
 119  *      YYY disable interrupts once giant is removed.
 120  */
 121 ENTRY(cpu_heavy_switch)
 122         /*
 123          * Save RIP, RSP and callee-saved registers (RBX, RBP, R12-R15).
 124          */
 125         movq    PCPU(curthread),%rcx
 126         /* On top of the stack is the return adress. */
 127         movq    (%rsp),%rax                     /* (reorder optimization) */
 128         movq    TD_PCB(%rcx),%rdx               /* RDX = PCB */
 129         movq    %rax,PCB_RIP(%rdx)              /* return PC may be modified */
 130         movq    %rbx,PCB_RBX(%rdx)
 131         movq    %rsp,PCB_RSP(%rdx)
 132         movq    %rbp,PCB_RBP(%rdx)
 133         movq    %r12,PCB_R12(%rdx)
 134         movq    %r13,PCB_R13(%rdx)
 135         movq    %r14,PCB_R14(%rdx)
 136         movq    %r15,PCB_R15(%rdx)
 137
 138         movq    %rcx,%rbx                       /* RBX = curthread */
 139         movq    TD_LWP(%rcx),%rcx
 140         movl    PCPU(cpuid), %eax
 141         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 142         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%rcx)
 143
 144         /*
 145          * Push the LWKT switch restore function, which resumes a heavy
 146          * weight process.  Note that the LWKT switcher is based on
 147          * TD_SP, while the heavy weight process switcher is based on
 148          * PCB_RSP.  TD_SP is usually two ints pushed relative to
 149          * PCB_RSP.  We push the flags for later restore by cpu_heavy_restore.
 150          */
 151         pushfq
 152         movq    $cpu_heavy_restore, %rax
 153         pushq   %rax
 154         movq    %rsp,TD_SP(%rbx)
 155
 156         /*
 157          * Save debug regs if necessary
 158          */
 159         movq    PCB_FLAGS(%rdx),%rax
 160         andq    $PCB_DBREGS,%rax
 161         jz      1f                              /* no, skip over */
 162         movq    %dr7,%rax                       /* yes, do the save */
 163         movq    %rax,PCB_DR7(%rdx)
 164         /* JG correct value? */
 165         andq    $0x0000fc00, %rax               /* disable all watchpoints */
 166         movq    %rax,%dr7
 167         movq    %dr6,%rax
 168         movq    %rax,PCB_DR6(%rdx)
 169         movq    %dr3,%rax
 170         movq    %rax,PCB_DR3(%rdx)
 171         movq    %dr2,%rax
 172         movq    %rax,PCB_DR2(%rdx)
 173         movq    %dr1,%rax
 174         movq    %rax,PCB_DR1(%rdx)
 175         movq    %dr0,%rax
 176         movq    %rax,PCB_DR0(%rdx)
 177 1:
 178
 179 #if JG
 180 #if NNPX > 0
 181         /*
 182          * Save the FP state if we have used the FP.  Note that calling
 183          * npxsave will NULL out PCPU(npxthread).
 184          */
 185         cmpl    %ebx,PCPU(npxthread)
 186         jne     1f
 187         pushl   TD_SAVEFPU(%ebx)
 188         call    npxsave                 /* do it in a big C function */
 189         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 190 1:
 191 #endif
 192 #endif  /* NNPX > 0 */
 193
 194         /*
 195          * Switch to the next thread, which was passed as an argument
 196          * to cpu_heavy_switch().  The argument is in %rdi.
 197          * Set the current thread, load the stack pointer,
 198          * and 'ret' into the switch-restore function.
 199          *
 200          * The switch restore function expects the new thread to be in %rax
 201          * and the old one to be in %rbx.
 202          *
 203          * There is a one-instruction window where curthread is the new
 204          * thread but %rsp still points to the old thread's stack, but
 205          * we are protected by a critical section so it is ok.
 206          */
 207         movq    %rdi,%rax               /* RAX = newtd, RBX = oldtd */
 208         movq    %rax,PCPU(curthread)
 209         movq    TD_SP(%rax),%rsp
 210         CHECKNZ((%rsp), %r9)
 211         ret
 212
 213 /*
 214  *  cpu_exit_switch(struct thread *next)
 215  *
 216  *      The switch function is changed to this when a thread is going away
 217  *      for good.  We have to ensure that the MMU state is not cached, and
 218  *      we don't bother saving the existing thread state before switching.
 219  *
 220  *      At this point we are in a critical section and this cpu owns the
 221  *      thread's token, which serves as an interlock until the switchout is
 222  *      complete.
 223  */
 224 ENTRY(cpu_exit_switch)
 225         /*
 226          * Get us out of the vmspace
 227          */
 228 #if JG
 229         movq    %cr3,%rax
 230         cmpq    %rcx,%rax
 231         je      1f
 232         /* JG no increment of statistics counters? see cpu_heavy_restore */
 233         movq    %rcx,%cr3
 234 1:
 235 #else
 236         movq    IdlePTD, %rcx
 237         orq     $(PG_RW|PG_V), %rcx
 238         movq    link_pdpe,%r12
 239         movq    %rcx, (%r12)
 240         movq    %cr3, %rcx
 241         movq    %rcx, %cr3
 242 #endif
 243         movq    PCPU(curthread),%rbx
 244
 245         /*
 246          * If this is a process/lwp, deactivate the pmap after we've
 247          * switched it out.
 248          */
 249         movq    TD_LWP(%rbx),%rcx
 250         testq   %rcx,%rcx
 251         jz      2f
 252         movl    PCPU(cpuid), %eax
 253         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 254         MPLOCKED btrl   %eax, VM_PMAP+PM_ACTIVE(%rcx)
 255 2:
 256         /*
 257          * Switch to the next thread.  RET into the restore function, which
 258          * expects the new thread in RAX and the old in RBX.
 259          *
 260          * There is a one-instruction window where curthread is the new
 261          * thread but %rsp still points to the old thread's stack, but
 262          * we are protected by a critical section so it is ok.
 263          */
 264         movq    %rdi,%rax
 265         movq    %rax,PCPU(curthread)
 266         movq    TD_SP(%rax),%rsp
 267         CHECKNZ((%rsp), %r9)
 268         ret
 269
 270 /*
 271  * cpu_heavy_restore()  (current thread in %rax on entry)
 272  *
 273  *      Restore the thread after an LWKT switch.  This entry is normally
 274  *      called via the LWKT switch restore function, which was pulled
 275  *      off the thread stack and jumped to.
 276  *
 277  *      This entry is only called if the thread was previously saved
 278  *      using cpu_heavy_switch() (the heavy weight process thread switcher),
 279  *      or when a new process is initially scheduled.  The first thing we
 280  *      do is clear the TDF_RUNNING bit in the old thread and set it in the
 281  *      new thread.
 282  *
 283  *      NOTE: The lwp may be in any state, not necessarily LSRUN, because
 284  *      a preemption switch may interrupt the process and then return via
 285  *      cpu_heavy_restore.
 286  *
 287  *      YYY theoretically we do not have to restore everything here, a lot
 288  *      of this junk can wait until we return to usermode.  But for now
 289  *      we restore everything.
 290  *
 291  *      YYY the PCB crap is really crap, it makes startup a bitch because
 292  *      we can't switch away.
 293  *
 294  *      YYY note: spl check is done in mi_switch when it splx()'s.
 295  */
 296
 297 ENTRY(cpu_heavy_restore)
 298         popfq
 299         movq    TD_PCB(%rax),%rdx               /* RDX = PCB */
 300         movq    TD_LWP(%rax),%rcx
 301
 302 #if defined(SWTCH_OPTIM_STATS)
 303         incl    _swtch_optim_stats
 304 #endif
 305         /*
 306          * Tell the pmap that our cpu is using the VMSPACE now.  We cannot
 307          * safely test/reload %cr3 until after we have set the bit in the
 308          * pmap (remember, we do not hold the MP lock in the switch code).
 309          */
 310         movq    LWP_VMSPACE(%rcx), %rcx         /* RCX = vmspace */
 311         movl    PCPU(cpuid), %esi
 312         MPLOCKED btsl   %esi, VM_PMAP+PM_ACTIVE(%rcx)
 313
 314         /*
 315          * Restore the MMU address space.  If it is the same as the last
 316          * thread we don't have to invalidate the tlb (i.e. reload cr3).
 317          * YYY which naturally also means that the PM_ACTIVE bit had better
 318          * already have been set before we set it above, check? YYY
 319          */
 320 #if JG
 321 #error x
 322         movq    %cr3,%rsi
 323         movq    PCB_CR3(%rdx),%rcx
 324         cmpq    %rsi,%rcx
 325         je      4f
 326 #if defined(SWTCH_OPTIM_STATS)
 327         decl    _swtch_optim_stats
 328         incl    _tlb_flush_count
 329 #endif
 330         movq    %rcx,%cr3
 331 4:
 332 #else
 333         movq    PCB_CR3(%rdx),%rcx
 334         orq     $(PG_RW|PG_U|PG_V), %rcx
 335         /*XXX*/
 336         movq    link_pdpe,%r12
 337         movq    %rcx, (%r12)
 338         movq    %cr3, %rcx
 339         movq    %rcx, %cr3
 340 #endif
 341         /*
 342          * Clear TDF_RUNNING flag in old thread only after cleaning up
 343          * %cr3.  The target thread is already protected by being TDF_RUNQ
 344          * so setting TDF_RUNNING isn't as big a deal.
 345          */
 346         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 347         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 348
 349         /*
 350          * Deal with the PCB extension, restore the private tss
 351          */
 352         movq    PCB_EXT(%rdx),%rdi      /* check for a PCB extension */
 353         /* JG cheaper than "movq $1,%rbx", right? */
 354         /* JG what's that magic value $1? */
 355         movl    $1,%ebx                 /* maybe mark use of a private tss */
 356         testq   %rdi,%rdi
 357 #if JG
 358         jnz     2f
 359 #endif
 360
 361         /* JG
 362          * Going back to the common_tss.  We may need to update TSS_ESP0
 363          * which sets the top of the supervisor stack when entering from
 364          * usermode.  The PCB is at the top of the stack but we need another
 365          * 16 bytes to take vm86 into account.
 366          */
 367         leaq    -16(%rdx),%rbx
 368         movq    %rbx, PCPU(common_tss) + TSS_RSP0
 369         movq    %rbx, PCPU(rsp0)
 370
 371 #if JG
 372         cmpl    $0,PCPU(private_tss)    /* don't have to reload if      */
 373         je      3f                      /* already using the common TSS */
 374
 375         /* JG? */
 376         subl    %ebx,%ebx               /* unmark use of private tss */
 377
 378         /*
 379          * Get the address of the common TSS descriptor for the ltr.
 380          * There is no way to get the address of a segment-accessed variable
 381          * so we store a self-referential pointer at the base of the per-cpu
 382          * data area and add the appropriate offset.
 383          */
 384         /* JG movl? */
 385         movq    $gd_common_tssd, %rdi
 386         /* JG name for "%gs:0"? */
 387         addq    %gs:0, %rdi
 388
 389         /*
 390          * Move the correct TSS descriptor into the GDT slot, then reload
 391          * ltr.
 392          */
 393 2:
 394         /* JG */
 395         movl    %ebx,PCPU(private_tss)          /* mark/unmark private tss */
 396         movq    PCPU(tss_gdt), %rbx             /* entry in GDT */
 397         movq    0(%rdi), %rax
 398         movq    %rax, 0(%rbx)
 399         movl    $GPROC0_SEL*8, %esi             /* GSEL(entry, SEL_KPL) */
 400         ltr     %si
 401 #endif
 402
 403 3:
 404         /*
 405          * Restore the user %gs and %fs
 406          */
 407         movq    PCB_FSBASE(%rdx),%r9
 408         cmpq    PCPU(user_fs),%r9
 409         je      4f
 410         movq    %rdx,%r10
 411         movq    %r9,PCPU(user_fs)
 412         movl    $MSR_FSBASE,%ecx
 413         movl    PCB_FSBASE(%r10),%eax
 414         movl    PCB_FSBASE+4(%r10),%edx
 415         wrmsr
 416         movq    %r10,%rdx
 417 4:
 418         movq    PCB_GSBASE(%rdx),%r9
 419         cmpq    PCPU(user_gs),%r9
 420         je      5f
 421         movq    %rdx,%r10
 422         movq    %r9,PCPU(user_gs)
 423         movl    $MSR_KGSBASE,%ecx       /* later swapgs moves it to GSBASE */
 424         movl    PCB_GSBASE(%r10),%eax
 425         movl    PCB_GSBASE+4(%r10),%edx
 426         wrmsr
 427         movq    %r10,%rdx
 428 5:
 429
 430         /*
 431          * Restore general registers.
 432          */
 433         movq    PCB_RBX(%rdx), %rbx
 434         movq    PCB_RSP(%rdx), %rsp
 435         movq    PCB_RBP(%rdx), %rbp
 436         movq    PCB_R12(%rdx), %r12
 437         movq    PCB_R13(%rdx), %r13
 438         movq    PCB_R14(%rdx), %r14
 439         movq    PCB_R15(%rdx), %r15
 440         movq    PCB_RIP(%rdx), %rax
 441         movq    %rax, (%rsp)
 442
 443 #if JG
 444         /*
 445          * Restore the user LDT if we have one
 446          */
 447         cmpl    $0, PCB_USERLDT(%edx)
 448         jnz     1f
 449         movl    _default_ldt,%eax
 450         cmpl    PCPU(currentldt),%eax
 451         je      2f
 452         lldt    _default_ldt
 453         movl    %eax,PCPU(currentldt)
 454         jmp     2f
 455 1:      pushl   %edx
 456         call    set_user_ldt
 457         popl    %edx
 458 2:
 459 #endif
 460 #if JG
 461         /*
 462          * Restore the user TLS if we have one
 463          */
 464         pushl   %edx
 465         call    set_user_TLS
 466         popl    %edx
 467 #endif
 468
 469         /*
 470          * Restore the DEBUG register state if necessary.
 471          */
 472         movq    PCB_FLAGS(%rdx),%rax
 473         andq    $PCB_DBREGS,%rax
 474         jz      1f                              /* no, skip over */
 475         movq    PCB_DR6(%rdx),%rax              /* yes, do the restore */
 476         movq    %rax,%dr6
 477         movq    PCB_DR3(%rdx),%rax
 478         movq    %rax,%dr3
 479         movq    PCB_DR2(%rdx),%rax
 480         movq    %rax,%dr2
 481         movq    PCB_DR1(%rdx),%rax
 482         movq    %rax,%dr1
 483         movq    PCB_DR0(%rdx),%rax
 484         movq    %rax,%dr0
 485         movq    %dr7,%rax                /* load dr7 so as not to disturb */
 486         /* JG correct value? */
 487         andq    $0x0000fc00,%rax         /*   reserved bits               */
 488         /* JG we've got more registers on amd64 */
 489         pushq   %rbx
 490         movq    PCB_DR7(%rdx),%rbx
 491         /* JG correct value? */
 492         andq    $~0x0000fc00,%rbx
 493         orq     %rbx,%rax
 494         popq    %rbx
 495         movq    %rax,%dr7
 496 1:
 497
 498         CHECKNZ((%rsp), %r9)
 499         ret
 500
 501 /*
 502  * savectx(struct pcb *pcb)
 503  *
 504  * Update pcb, saving current processor state.
 505  */
 506 ENTRY(savectx)
 507         /* fetch PCB */
 508         /* JG use %rdi instead of %rcx everywhere? */
 509         movq    %rdi,%rcx
 510
 511         /* caller's return address - child won't execute this routine */
 512         movq    (%rsp),%rax
 513         movq    %rax,PCB_RIP(%rcx)
 514
 515         movq    %cr3,%rax
 516 #ifndef JG
 517         movq    (%rax), %rax
 518         movq    $0x000ffffffffff000, %rcx
 519         andq    %rcx, %rax
 520         movq    (%rax), %rax
 521         andq    %rcx, %rax
 522 #endif
 523         movq    %rax,PCB_CR3(%rcx)
 524
 525         movq    %rbx,PCB_RBX(%rcx)
 526         movq    %rsp,PCB_RSP(%rcx)
 527         movq    %rbp,PCB_RBP(%rcx)
 528         movq    %r12,PCB_R12(%rcx)
 529         movq    %r13,PCB_R13(%rcx)
 530         movq    %r14,PCB_R14(%rcx)
 531         movq    %r15,PCB_R15(%rcx)
 532
 533 #if JG
 534 #if NNPX > 0
 535         /*
 536          * If npxthread == NULL, then the npx h/w state is irrelevant and the
 537          * state had better already be in the pcb.  This is true for forks
 538          * but not for dumps (the old book-keeping with FP flags in the pcb
 539          * always lost for dumps because the dump pcb has 0 flags).
 540          *
 541          * If npxthread != NULL, then we have to save the npx h/w state to
 542          * npxthread's pcb and copy it to the requested pcb, or save to the
 543          * requested pcb and reload.  Copying is easier because we would
 544          * have to handle h/w bugs for reloading.  We used to lose the
 545          * parent's npx state for forks by forgetting to reload.
 546          */
 547         movl    PCPU(npxthread),%eax
 548         testl   %eax,%eax
 549         je      1f
 550
 551         pushl   %ecx                    /* target pcb */
 552         movl    TD_SAVEFPU(%eax),%eax   /* originating savefpu area */
 553         pushl   %eax
 554
 555         pushl   %eax
 556         call    npxsave
 557         addl    $4,%esp
 558
 559         popl    %eax
 560         popl    %ecx
 561
 562         pushl   $PCB_SAVEFPU_SIZE
 563         leal    PCB_SAVEFPU(%ecx),%ecx
 564         pushl   %ecx
 565         pushl   %eax
 566         call    bcopy
 567         addl    $12,%esp
 568 #endif  /* NNPX > 0 */
 569
 570 1:
 571 #endif
 572         CHECKNZ((%rsp), %r9)
 573         ret
 574
 575 /*
 576  * cpu_idle_restore()   (current thread in %rax on entry) (one-time execution)
 577  *
 578  *      Don't bother setting up any regs other than %rbp so backtraces
 579  *      don't die.  This restore function is used to bootstrap into the
 580  *      cpu_idle() LWKT only, after that cpu_lwkt_*() will be used for
 581  *      switching.
 582  *
 583  *      Clear TDF_RUNNING in old thread only after we've cleaned up %cr3.
 584  *
 585  *      If we are an AP we have to call ap_init() before jumping to
 586  *      cpu_idle().  ap_init() will synchronize with the BP and finish
 587  *      setting up various ncpu-dependant globaldata fields.  This may
 588  *      happen on UP as well as SMP if we happen to be simulating multiple
 589  *      cpus.
 590  */
 591 ENTRY(cpu_idle_restore)
 592         /* cli */
 593         movq    IdlePTD,%rcx
 594         /* JG xor? */
 595         movl    $0,%ebp
 596         /* JG push RBP? */
 597         pushq   $0
 598         orq     $(PG_RW|PG_V), %rcx
 599         movq    link_pdpe,%r12
 600         movq    %rcx, (%r12)
 601         movq    %cr3, %rcx
 602         movq    %rcx,%cr3
 603         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 604         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 605 #ifdef SMP
 606         cmpl    $0,PCPU(cpuid)
 607         je      1f
 608         call    ap_init
 609 1:
 610 #endif
 611         /*
 612          * ap_init can decide to enable interrupts early, but otherwise, or if
 613          * we are UP, do it here.
 614          */
 615         sti
 616         jmp     cpu_idle
 617
 618 /*
 619  * cpu_kthread_restore() (current thread is %rax on entry) (one-time execution)
 620  *
 621  *      Don't bother setting up any regs other then %rbp so backtraces
 622  *      don't die.  This restore function is used to bootstrap into an
 623  *      LWKT based kernel thread only.  cpu_lwkt_switch() will be used
 624  *      after this.
 625  *
 626  *      Since all of our context is on the stack we are reentrant and
 627  *      we can release our critical section and enable interrupts early.
 628  */
 629 ENTRY(cpu_kthread_restore)
 630         sti
 631         movq    IdlePTD,%rcx
 632         movq    TD_PCB(%rax),%rdx
 633         /* JG "movq $0, %rbp"? "xorq %rbp, %rbp"? */
 634         movl    $0,%ebp
 635         orq     $(PG_RW|PG_V), %rcx
 636         movq    link_pdpe,%r12
 637         movq    %rcx, (%r12)
 638         movq    %cr3, %rcx
 639         movq    %rcx,%cr3
 640         /* rax and rbx come from the switchout code */
 641         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 642         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 643         subl    $TDPRI_CRIT,TD_PRI(%rax)
 644         movq    PCB_R12(%rdx),%rdi      /* argument to RBX function */
 645         movq    PCB_RBX(%rdx),%rax      /* thread function */
 646         /* note: top of stack return address inherited by function */
 647         CHECKNZ(%rax, %r9)
 648         jmp     *%rax
 649
 650 /*
 651  * cpu_lwkt_switch(struct thread *)
 652  *
 653  *      Standard LWKT switching function.  Only non-scratch registers are
 654  *      saved and we don't bother with the MMU state or anything else.
 655  *
 656  *      This function is always called while in a critical section.
 657  *
 658  *      There is a one-instruction window where curthread is the new
 659  *      thread but %rsp still points to the old thread's stack, but
 660  *      we are protected by a critical section so it is ok.
 661  *
 662  *      YYY BGL, SPL
 663  */
 664 ENTRY(cpu_lwkt_switch)
 665         pushq   %rbp    /* JG note: GDB hacked to locate ebp relative to td_sp */
 666         /* JG we've got more registers on AMD64 */
 667         pushq   %rbx
 668         movq    PCPU(curthread),%rbx
 669         pushq   %r12
 670         pushq   %r13
 671         pushq   %r14
 672         pushq   %r15
 673         pushfq
 674
 675 #if JG
 676 #if NNPX > 0
 677         /*
 678          * Save the FP state if we have used the FP.  Note that calling
 679          * npxsave will NULL out PCPU(npxthread).
 680          *
 681          * We have to deal with the FP state for LWKT threads in case they
 682          * happen to get preempted or block while doing an optimized
 683          * bzero/bcopy/memcpy.
 684          */
 685         cmpl    %ebx,PCPU(npxthread)
 686         jne     1f
 687         pushl   TD_SAVEFPU(%ebx)
 688         call    npxsave                 /* do it in a big C function */
 689         addl    $4,%esp                 /* EAX, ECX, EDX trashed */
 690 1:
 691 #endif  /* NNPX > 0 */
 692 #endif
 693
 694         movq    %rdi,%rax               /* switch to this thread */
 695         pushq   $cpu_lwkt_restore
 696         movq    %rsp,TD_SP(%rbx)
 697         movq    %rax,PCPU(curthread)
 698         movq    TD_SP(%rax),%rsp
 699
 700         /*
 701          * %rax contains new thread, %rbx contains old thread.
 702          */
 703         CHECKNZ((%rsp), %r9)
 704         ret
 705
 706 /*
 707  * cpu_lwkt_restore()   (current thread in %rax on entry)
 708  *
 709  *      Standard LWKT restore function.  This function is always called
 710  *      while in a critical section.
 711  *
 712  *      Warning: due to preemption the restore function can be used to
 713  *      'return' to the original thread.  Interrupt disablement must be
 714  *      protected through the switch so we cannot run splz here.
 715  *
 716  *      YYY we theoretically do not need to load KPML4phys into cr3, but if
 717  *      so we need a way to detect when the PTD we are using is being
 718  *      deleted due to a process exiting.
 719  */
 720 ENTRY(cpu_lwkt_restore)
 721 #if JG
 722         movq    common_lvl4_phys,%rcx   /* YYY borrow but beware desched/cpuchg/exit */
 723 #endif
 724         movq    IdlePTD, %rcx
 725         orq     $(PG_RW|PG_V), %rcx
 726         movq    link_pdpe,%r12
 727         movq    %rcx, (%r12)
 728         movq    %cr3, %rcx
 729         movq    %rcx, %cr3
 730 #if JG
 731         movq    %cr3,%rdx
 732         cmpq    %rcx,%rdx
 733         je      1f
 734         movq    %rcx,%cr3
 735 1:
 736 #endif
 737         andl    $~TDF_RUNNING,TD_FLAGS(%rbx)
 738         orl     $TDF_RUNNING,TD_FLAGS(%rax)
 739         popfq
 740         popq    %r15
 741         popq    %r14
 742         popq    %r13
 743         popq    %r12
 744         popq    %rbx
 745         popq    %rbp
 746         ret