sys/kern/makesyscalls.sh

   1 #! /bin/sh -
   2 #       @(#)makesyscalls.sh     8.1 (Berkeley) 6/10/93
   3 # $FreeBSD: src/sys/kern/makesyscalls.sh,v 1.39.2.4 2001/10/20 09:01:24 marcel Exp $
   4 # $DragonFly: src/sys/kern/makesyscalls.sh,v 1.5 2003/07/24 01:41:25 dillon Exp $
   5
   6 set -e
   7
   8 # name of compat option:
   9 compat=COMPAT_43
  10
  11 # output files:
  12 sysnames="syscalls.c"
  13 sysproto="../sys/sysproto.h"
  14 sysunion="../sys/sysunion.h"
  15 sysproto_h=_SYS_SYSPROTO_H_
  16 syshdr="../sys/syscall.h"
  17 sysmk="../sys/syscall.mk"
  18 syssw="init_sysent.c"
  19 syshide="../sys/syscall-hide.h"
  20 syscallprefix="SYS_"
  21 switchname="sysent"
  22 namesname="syscallnames"
  23
  24 # tmp files:
  25 sysdcl="sysent.dcl.$$"
  26 syscompat="sysent.compat.$$"
  27 syscompatdcl="sysent.compatdcl.$$"
  28 sysent="sysent.switch.$$"
  29 sysinc="sysinc.switch.$$"
  30 sysarg="sysarg.switch.$$"
  31 sysun="sysunion.switch.$$"
  32
  33 trap "rm $sysdcl $syscompat $syscompatdcl $sysent $sysinc $sysarg $sysun" 0
  34
  35 touch $sysdcl $syscompat $syscompatdcl $sysent $sysinc $sysarg $sysun
  36
  37 case $# in
  38     0)  echo "Usage: $0 input-file <config-file>" 1>&2
  39         exit 1
  40         ;;
  41 esac
  42
  43 if [ -n "$2" -a -f "$2" ]; then
  44         . $2
  45 fi
  46
  47 sed -e '
  48 s/\$//g
  49 :join
  50         /\\$/{a\
  51
  52         N
  53         s/\\\n//
  54         b join
  55         }
  56 2,${
  57         /^#/!s/\([{}()*,]\)/ \1 /g
  58 }
  59 ' < $1 | awk "
  60         BEGIN {
  61                 sysdcl = \"$sysdcl\"
  62                 sysproto = \"$sysproto\"
  63                 sysproto_h = \"$sysproto_h\"
  64                 syscompat = \"$syscompat\"
  65                 syscompatdcl = \"$syscompatdcl\"
  66                 sysent = \"$sysent\"
  67                 syssw = \"$syssw\"
  68                 sysinc = \"$sysinc\"
  69                 sysarg = \"$sysarg\"
  70                 sysun = \"$sysun\"
  71                 sysnames = \"$sysnames\"
  72                 syshdr = \"$syshdr\"
  73                 sysmk = \"$sysmk\"
  74                 compat = \"$compat\"
  75                 syshide = \"$syshide\"
  76                 syscallprefix = \"$syscallprefix\"
  77                 switchname = \"$switchname\"
  78                 namesname = \"$namesname\"
  79                 infile = \"$1\"
  80                 "'
  81
  82                 printf "/*\n * System call switch table.\n *\n" > syssw
  83                 printf " * DO NOT EDIT-- this file is automatically generated.\n" > syssw
  84                 printf " * \$\DragonFly\$\n" > syssw
  85
  86                 printf "/*\n * System call prototypes.\n *\n" > sysarg
  87                 printf " * DO NOT EDIT-- this file is automatically generated.\n" > sysarg
  88                 printf " * \$\DragonFly\$\n" > sysarg
  89
  90                 printf "\n#ifdef %s\n\n", compat > syscompat
  91
  92                 printf "/*\n * System call names.\n *\n" > sysnames
  93                 printf " * DO NOT EDIT-- this file is automatically generated.\n" > sysnames
  94                 printf " * \$\DragonFly\$\n" > sysnames
  95
  96                 printf "/*\n * System call numbers.\n *\n" > syshdr
  97                 printf " * DO NOT EDIT-- this file is automatically generated.\n" > syshdr
  98                 printf " * \$\DragonFly\$\n" > syshdr
  99                 printf "# DragonFly system call names.\n" > sysmk
 100                 printf "# DO NOT EDIT-- this file is automatically generated.\n" > sysmk
 101                 printf "# \$\DragonFly\$\n" > sysmk
 102                 printf "/*\n * System call hiders.\n *\n" > syshide
 103                 printf " * DO NOT EDIT-- this file is automatically generated.\n" > syshide
 104                 printf " * \$\DragonFly\$\n" > syshide
 105
 106                 printf "/*\n * Union of syscall args for messaging.\n *\n" > sysun
 107                 printf " * DO NOT EDIT-- this file is automatically generated.\n" > sysun
 108                 printf " * \$\DragonFly\$\n" > sysun
 109         }
 110         NR == 1 {
 111                 gsub("[$]DragonFly: ", "", $0)
 112                 gsub(" [$]", "", $0)
 113
 114                 printf " * created from%s\n */\n\n", $0 > syssw
 115
 116                 printf "\n/* The casts are bogus but will do for now. */\n" > sysent
 117                 printf "struct sysent %s[] = {\n",switchname > sysent
 118
 119                 printf " * created from%s\n */\n\n", $0 > sysarg
 120                 printf "#ifndef %s\n", sysproto_h > sysarg
 121                 printf "#define\t%s\n\n", sysproto_h > sysarg
 122                 printf "#include <sys/signal.h>\n\n" > sysarg
 123                 printf "#include <sys/acl.h>\n\n" > sysarg
 124                 printf "#include <sys/msgport.h>\n\n" > sysarg
 125                 printf "#define\tPAD_(t)\t(sizeof(register_t) <= sizeof(t) ? \\\n" > sysarg
 126                 printf "\t\t0 : sizeof(register_t) - sizeof(t))\n\n" > sysarg
 127
 128                 printf " * created from%s\n */\n\n", $0 > sysnames
 129                 printf "char *%s[] = {\n", namesname > sysnames
 130
 131                 printf " * created from%s\n */\n\n", $0 > syshdr
 132
 133                 printf "# created from%s\nMIASM = ", $0 > sysmk
 134
 135                 printf " * created from%s\n */\n\n", $0 > syshide
 136                 printf " * created from%s\n */\n\n", $0 > sysun
 137                 printf "union sysunion {\n" > sysun
 138                 printf "\tstruct lwkt_msg lmsg;\n" > sysun
 139                 next
 140         }
 141         NF == 0 || $1 ~ /^;/ {
 142                 next
 143         }
 144         $1 ~ /^#[       ]*include/ {
 145                 print > sysinc
 146                 next
 147         }
 148         $1 ~ /^#[       ]*if/ {
 149                 print > sysent
 150                 print > sysdcl
 151                 print > sysarg
 152                 print > syscompat
 153                 print > sysnames
 154                 print > syshide
 155                 print > sysun
 156                 savesyscall = syscall
 157                 next
 158         }
 159         $1 ~ /^#[       ]*else/ {
 160                 print > sysent
 161                 print > sysdcl
 162                 print > sysarg
 163                 print > sysun
 164                 print > syscompat
 165                 print > sysnames
 166                 print > syshide
 167                 syscall = savesyscall
 168                 next
 169         }
 170         $1 ~ /^#/ {
 171                 print > sysent
 172                 print > sysdcl
 173                 print > sysarg
 174                 print > sysun
 175                 print > syscompat
 176                 print > sysnames
 177                 print > syshide
 178                 next
 179         }
 180         syscall != $1 {
 181                 printf "%s: line %d: syscall number out of sync at %d\n",
 182                     infile, NR, syscall
 183                 printf "line is:\n"
 184                 print
 185                 exit 1
 186         }
 187         function align_sysent_comment(column) {
 188                 printf("\t") > sysent
 189                 column = column + 8 - column % 8
 190                 while (column < 56) {
 191                         printf("\t") > sysent
 192                         column = column + 8
 193                 }
 194         }
 195         function parserr(was, wanted) {
 196                 printf "%s: line %d: unexpected %s (expected %s)\n",
 197                     infile, NR, was, wanted
 198                 exit 1
 199         }
 200         function parseline() {
 201                 f=4                     # toss number and type
 202                 argc= 0;
 203                 argssize = "0"
 204                 if ($NF != "}") {
 205                         funcalias=$(NF-2)
 206                         argalias=$(NF-1)
 207                         rettype=$NF
 208                         end=NF-3
 209                 } else {
 210                         funcalias=""
 211                         argalias=""
 212                         rettype="int"
 213                         end=NF
 214                 }
 215                 if ($2 == "NODEF") {
 216                         funcname=$4
 217                         argssize = "AS(" $6 ")"
 218                         return
 219                 }
 220                 if ($f != "{")
 221                         parserr($f, "{")
 222                 f++
 223                 if ($end != "}")
 224                         parserr($end, "}")
 225                 end--
 226                 if ($end != ";")
 227                         parserr($end, ";")
 228                 end--
 229                 if ($end != ")")
 230                         parserr($end, ")")
 231                 end--
 232
 233                 f++     #function return type
 234
 235                 funcname=$f
 236                 usefuncname=$f
 237                 if (funcalias == "")
 238                         funcalias = funcname
 239                 if (argalias == "") {
 240                         argalias = funcname "_args"
 241                         if ($2 == "COMPAT") {
 242                                 argalias = "o" argalias
 243                                 usefuncname = "o" funcname
 244                         }
 245                 }
 246                 f++
 247
 248                 if ($f != "(")
 249                         parserr($f, ")")
 250                 f++
 251
 252                 if (f == end) {
 253                         if ($f != "void")
 254                                 parserr($f, "argument definition")
 255                         return
 256                 }
 257
 258                 while (f <= end) {
 259                         argc++
 260                         argtype[argc]=""
 261                         oldf=""
 262                         while (f < end && $(f+1) != ",") {
 263                                 if (argtype[argc] != "" && oldf != "*")
 264                                         argtype[argc] = argtype[argc]" ";
 265                                 argtype[argc] = argtype[argc]$f;
 266                                 oldf = $f;
 267                                 f++
 268                         }
 269                         if (argtype[argc] == "")
 270                                 parserr($f, "argument definition")
 271                         argname[argc]=$f;
 272                         f += 2;                 # skip name, and any comma
 273                 }
 274                 if (argc != 0)
 275                         argssize = "AS(" argalias ")"
 276         }
 277         {       comment = $4
 278                 if (NF < 7)
 279                         for (i = 5; i <= NF; i++)
 280                                 comment = comment " " $i
 281         }
 282         # if the "MPSAFE" keyword is found, note it and shift the line
 283         mpsafe = ""
 284         $2 == "MPSAFE" {
 285                 for (i = 2; i <= NF; i++)
 286                         $i = $(i + 1);
 287                 NF -= 1;
 288                 mpsafe = "SYF_MPSAFE | "
 289         }
 290         $2 == "STD" || $2 == "NODEF" || $2 == "NOARGS"  || $2 == "NOPROTO" \
 291             || $2 == "NOIMPL" {
 292                 parseline()
 293                 if ((!nosys || funcname != "nosys") && \
 294                     (funcname != "lkmnosys")) {
 295                         if (argc != 0 && $2 != "NOARGS" && $2 != "NOPROTO") {
 296                                 printf("\tstruct\t%s %s;\n", argalias, usefuncname) > sysun
 297                                 printf("struct\t%s {\n", argalias) > sysarg
 298                                 printf("\tstruct lwkt_msg lmsg;\n") > sysarg
 299                                 for (i = 1; i <= argc; i++)
 300                                         printf("\t%s\t%s;\tchar %s_[PAD_(%s)];\n",
 301                                             argtype[i], argname[i],
 302                                             argname[i], argtype[i]) > sysarg
 303                                 printf("};\n") > sysarg
 304                         }
 305                         else if ($2 != "NOARGS" && $2 != "NOPROTO" && \
 306                             $2 != "NODEF") {
 307                                 printf("\tstruct\t%s %s;\n", argalias, usefuncname) > sysun
 308                                 printf("struct\t%s {\n", argalias) > sysarg
 309                                 printf("\tstruct lwkt_msg lmsg;\n") > sysarg
 310                                 printf("\tregister_t dummy;\n") > sysarg
 311                                 printf("};\n") > sysarg
 312                         }
 313                 }
 314                 if (($2 != "NOPROTO" && $2 != "NODEF" && \
 315                     (funcname != "nosys" || !nosys)) || \
 316                     (funcname == "lkmnosys" && !lkmnosys) || \
 317                     funcname == "lkmressys") {
 318                         printf("%s\t%s __P((struct %s *))",
 319                             rettype, funcname, argalias) > sysdcl
 320                         printf(";\n") > sysdcl
 321                 }
 322                 if (funcname == "nosys")
 323                         nosys = 1
 324                 if (funcname == "lkmnosys")
 325                         lkmnosys = 1
 326                 printf("\t{ %s%s, (sy_call_t *)", mpsafe, argssize) > sysent
 327                 column = 8 + 2 + length(mpsafe) + length(argssize) + 15
 328                 if ($2 != "NOIMPL") {
 329                         printf("%s },", funcname) > sysent
 330                         column = column + length(funcname) + 3
 331                 } else {
 332                         printf("%s },", "nosys") > sysent
 333                         column = column + length("nosys") + 3
 334                 }
 335                 align_sysent_comment(column)
 336                 printf("/* %d = %s */\n", syscall, funcalias) > sysent
 337                 printf("\t\"%s\",\t\t\t/* %d = %s */\n",
 338                     funcalias, syscall, funcalias) > sysnames
 339                 if ($2 != "NODEF") {
 340                         printf("#define\t%s%s\t%d\n", syscallprefix,
 341                             funcalias, syscall) > syshdr
 342                         printf(" \\\n\t%s.o", funcalias) > sysmk
 343                 }
 344                 if ($3 != "NOHIDE")
 345                         printf("HIDE_%s(%s)\n", $3, funcname) > syshide
 346                 syscall++
 347                 next
 348         }
 349         $2 == "COMPAT" || $2 == "CPT_NOA" {
 350                 ncompat++
 351                 parseline()
 352                 if (argc != 0 && $2 != "CPT_NOA") {
 353                         printf("#ifdef %s\n", compat) > sysun
 354                         printf("\tstruct\t%s %s;\n", argalias, usefuncname) > sysun
 355                         printf("#endif\n") > sysun
 356                         printf("struct\t%s {\n", argalias) > syscompat
 357                         printf("\tstruct lwkt_msg lmsg;\n") > syscompat
 358                         for (i = 1; i <= argc; i++)
 359                                 printf("\t%s\t%s;\tchar %s_[PAD_(%s)];\n",
 360                                     argtype[i], argname[i],
 361                                     argname[i], argtype[i]) > syscompat
 362                         printf("};\n") > syscompat
 363                 }
 364                 else if($2 != "CPT_NOA") {
 365                         printf("\tstruct\t%s %s;\n", argalias, usefuncname) > sysun
 366                         printf("struct\t%s {\n", argalias) > sysarg
 367                         printf("\tstruct lwkt_msg lmsg;\n") > sysarg
 368                         printf("\tregister_t dummy;\n") > sysarg
 369                         printf("};\n") > sysarg
 370                 }
 371                 printf("%s\to%s __P((struct %s *));\n",
 372                     rettype, funcname, argalias) > syscompatdcl
 373                 printf("\t{ compat(%s%s,%s) },",
 374                     mpsafe, argssize, funcname) > sysent
 375                 align_sysent_comment(8 + 9 + length(mpsafe) + \
 376                     length(argssize) + 1 + length(funcname) + 4)
 377                 printf("/* %d = old %s */\n", syscall, funcalias) > sysent
 378                 printf("\t\"old.%s\",\t\t/* %d = old %s */\n",
 379                     funcalias, syscall, funcalias) > sysnames
 380                 printf("\t\t\t\t/* %d is old %s */\n",
 381                     syscall, funcalias) > syshdr
 382                 if ($3 != "NOHIDE")
 383                         printf("HIDE_%s(%s)\n", $3, funcname) > syshide
 384                 syscall++
 385                 next
 386         }
 387         $2 == "LIBCOMPAT" {
 388                 ncompat++
 389                 parseline()
 390                 printf("%s\to%s();\n", rettype, funcname) > syscompatdcl
 391                 printf("\t{ compat(%s%s,%s) },",
 392                     mpsafe, argssize, funcname) > sysent
 393                 align_sysent_comment(8 + 9 + length(mpsafe) + \
 394                     length(argssize) + 1 + length(funcname) + 4)
 395                 printf("/* %d = old %s */\n", syscall, funcalias) > sysent
 396                 printf("\t\"old.%s\",\t\t/* %d = old %s */\n",
 397                     funcalias, syscall, funcalias) > sysnames
 398                 printf("#define\t%s%s\t%d\t/* compatibility; still used by libc */\n",
 399                     syscallprefix, funcalias, syscall) > syshdr
 400                 printf(" \\\n\t%s.o", funcalias) > sysmk
 401                 if ($3 != "NOHIDE")
 402                         printf("HIDE_%s(%s)\n", $3, funcname) > syshide
 403                 syscall++
 404                 next
 405         }
 406         $2 == "OBSOL" {
 407                 printf("\t{ 0, (sy_call_t *)nosys },") > sysent
 408                 align_sysent_comment(34)
 409                 printf("/* %d = obsolete %s */\n", syscall, comment) > sysent
 410                 printf("\t\"obs_%s\",\t\t\t/* %d = obsolete %s */\n",
 411                     $4, syscall, comment) > sysnames
 412                 printf("\t\t\t\t/* %d is obsolete %s */\n",
 413                     syscall, comment) > syshdr
 414                 if ($3 != "NOHIDE")
 415                         printf("HIDE_%s(%s)\n", $3, $4) > syshide
 416                 syscall++
 417                 next
 418         }
 419         $2 == "UNIMPL" {
 420                 printf("\t{ 0, (sy_call_t *)nosys },\t\t\t/* %d = %s */\n",
 421                     syscall, comment) > sysent
 422                 printf("\t\"#%d\",\t\t\t/* %d = %s */\n",
 423                     syscall, syscall, comment) > sysnames
 424                 if ($3 != "NOHIDE")
 425                         printf("HIDE_%s(%s)\n", $3, $4) > syshide
 426                 syscall++
 427                 next
 428         }
 429         {
 430                 printf "%s: line %d: unrecognized keyword %s\n", infile, NR, $2
 431                 exit 1
 432         }
 433         END {
 434                 printf "\n#define AS(name) ((sizeof(struct name) - sizeof(struct lwkt_msg)) / sizeof(register_t))\n" > sysinc
 435                 if (ncompat != 0) {
 436                         printf "#include \"opt_compat.h\"\n\n" > syssw
 437                         printf "\n#ifdef %s\n", compat > sysinc
 438                         printf "#define compat(n, name) n, (sy_call_t *)__CONCAT(o,name)\n" > sysinc
 439                         printf "#else\n" > sysinc
 440                         printf "#define compat(n, name) 0, (sy_call_t *)nosys\n" > sysinc
 441                         printf "#endif\n" > sysinc
 442                 }
 443
 444                 printf("\n#endif /* %s */\n\n", compat) > syscompatdcl
 445                 printf("#undef PAD_\n") > syscompatdcl
 446                 printf("\n#endif /* !%s */\n", sysproto_h) > syscompatdcl
 447
 448                 printf("\n") > sysmk
 449                 printf("};\n") > sysent
 450                 printf("};\n") > sysnames
 451                 printf("};\n") > sysun
 452                 printf("\ntypedef union sysunion *sysmsg_t;\n") > sysun
 453                 printf("#define\t%sMAXSYSCALL\t%d\n", syscallprefix, syscall) \
 454                     > syshdr
 455         } '
 456
 457 cat $sysinc $sysent >> $syssw
 458 cat $sysarg $sysdcl $syscompat $syscompatdcl > $sysproto
 459 cat $sysun > $sysunion