lib/libc/i386/gen/setjmp.S

   1 /*-
   2  * Copyright (c) 1990 The Regents of the University of California.
   3  * All rights reserved.
   4  *
   5  * This code is derived from software contributed to Berkeley by
   6  * William Jolitz.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  * 3. All advertising materials mentioning features or use of this software
  17  *    must display the following acknowledgement:
  18  *      This product includes software developed by the University of
  19  *      California, Berkeley and its contributors.
  20  * 4. Neither the name of the University nor the names of its contributors
  21  *    may be used to endorse or promote products derived from this software
  22  *    without specific prior written permission.
  23  *
  24  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  25  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  26  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  27  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  28  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  29  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  30  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  31  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  32  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  33  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  34  * SUCH DAMAGE.
  35  *
  36  * $FreeBSD: src/lib/libc/i386/gen/setjmp.S,v 1.17.2.2 2001/07/06 12:41:44 deischen Exp $
  37  * $DragonFly: src/lib/libc/i386/gen/setjmp.S,v 1.2 2003/06/17 04:26:43 dillon Exp $
  38  *
  39  * $FreeBSD: src/lib/libc/i386/gen/setjmp.S,v 1.17.2.2 2001/07/06 12:41:44 deischen Exp $
  40  */
  41
  42 /*
  43  * C library -- _setjmp, _longjmp
  44  *
  45  *      longjmp(a,v)
  46  * will generate a "return(v)" from the last call to
  47  *      setjmp(a)
  48  * by restoring registers from the environment 'a'.
  49  * The previous signal state is restored.
  50  */
  51
  52 #include "DEFS.h"
  53 #include "SYS.h"
  54
  55 ENTRY(setjmp)
  56         movl    4(%esp),%ecx
  57         PIC_PROLOGUE
  58         leal    28(%ecx), %eax
  59         pushl   %eax                    /* (sigset_t*)oset */
  60         pushl   $0                      /* (sigset_t*)set  */
  61         pushl   $1                      /* SIG_BLOCK       */
  62         call    PIC_PLT(CNAME(sigprocmask))
  63         addl    $12,%esp
  64         PIC_EPILOGUE
  65         movl    4(%esp),%ecx
  66         movl    0(%esp),%edx
  67         movl    %edx, 0(%ecx)
  68         movl    %ebx, 4(%ecx)
  69         movl    %esp, 8(%ecx)
  70         movl    %ebp,12(%ecx)
  71         movl    %esi,16(%ecx)
  72         movl    %edi,20(%ecx)
  73         fnstcw  24(%ecx)
  74         xorl    %eax,%eax
  75         ret
  76
  77 #ifndef _THREAD_SAFE
  78 .weak CNAME(longjmp);
  79 .set CNAME(longjmp),CNAME(__longjmp);
  80 #endif
  81 ENTRY(__longjmp)
  82         movl    4(%esp),%edx
  83         PIC_PROLOGUE
  84         pushl   $0                      /* (sigset_t*)oset */
  85         leal    28(%edx), %eax
  86         pushl   %eax                    /* (sigset_t*)set  */
  87         pushl   $3                      /* SIG_SETMASK     */
  88         call    PIC_PLT(CNAME(sigprocmask))
  89         addl    $12,%esp
  90         PIC_EPILOGUE
  91         movl    4(%esp),%edx
  92         movl    8(%esp),%eax
  93         movl    0(%edx),%ecx
  94         movl    4(%edx),%ebx
  95         movl    8(%edx),%esp
  96         movl    12(%edx),%ebp
  97         movl    16(%edx),%esi
  98         movl    20(%edx),%edi
  99         fninit
 100         fldcw   24(%edx)
 101         testl   %eax,%eax
 102         jnz     1f
 103         incl    %eax
 104 1:      movl    %ecx,0(%esp)
 105         ret