lib/libc/i386/string/memcmp.S

   1 /*
   2  * Copyright (c) 1993 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software without specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/lib/libc/i386/string/memcmp.S,v 1.5 1999/08/27 23:59:32 peter Exp $
  31  * $DragonFly: src/lib/libc/i386/string/memcmp.S,v 1.2 2003/06/17 04:26:43 dillon Exp $
  32  *
  33  * $FreeBSD: src/lib/libc/i386/string/memcmp.S,v 1.5 1999/08/27 23:59:32 peter Exp $
  34  */
  35
  36 #include "DEFS.h"
  37
  38 /*
  39  * memcmp (void *b1, void *b2, size_t len)
  40  *
  41  * Written by:
  42  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  43  */
  44
  45 ENTRY(memcmp)
  46         pushl   %edi
  47         pushl   %esi
  48         movl    12(%esp),%edi
  49         movl    16(%esp),%esi
  50         cld                             /* set compare direction forward */
  51
  52         movl    20(%esp),%ecx           /* compare by words */
  53         shrl    $2,%ecx
  54         repe
  55         cmpsl
  56         jne     L5                      /* do we match so far? */
  57
  58         movl    20(%esp),%ecx           /* compare remainder by bytes */
  59         andl    $3,%ecx
  60         repe
  61         cmpsb
  62         jne     L6                      /* do we match? */
  63
  64         xorl    %eax,%eax               /* we match, return zero        */
  65         popl    %esi
  66         popl    %edi
  67         ret
  68
  69 L5:     movl    $4,%ecx                 /* We know that one of the next */
  70         subl    %ecx,%edi               /* four pairs of bytes do not   */
  71         subl    %ecx,%esi               /* match.                       */
  72         repe
  73         cmpsb
  74 L6:     movzbl  -1(%edi),%eax           /* Perform unsigned comparison  */
  75         movzbl  -1(%esi),%edx
  76         subl    %edx,%eax
  77         popl    %esi
  78         popl    %edi
  79         ret