lib/libc/i386/sys/getcontext.S

   1 /*
   2  * Copyright (c) 2006 The DragonFly Project.  All rights reserved.
   3  *
   4  * This code is derived from software contributed to The DragonFly Project
   5  * by Matthew Dillon <dillon@backplane.com>
   6  *
   7  * Redistribution and use in source and binary forms, with or without
   8  * modification, are permitted provided that the following conditions
   9  * are met:
  10  *
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in
  15  *    the documentation and/or other materials provided with the
  16  *    distribution.
  17  * 3. Neither the name of The DragonFly Project nor the names of its
  18  *    contributors may be used to endorse or promote products derived
  19  *    from this software without specific, prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  22  * ``AS IS'' AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  23  * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
  24  * FOR A PARTICULAR PURPOSE ARE DISCLAIMED.  IN NO EVENT SHALL THE
  25  * COPYRIGHT HOLDERS OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
  26  * INCIDENTAL, SPECIAL, EXEMPLARY OR CONSEQUENTIAL DAMAGES (INCLUDING,
  27  * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES;
  28  * LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
  29  * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY,
  30  * OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT
  31  * OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  32  * SUCH DAMAGE.
  33  *
  34  * $DragonFly: src/lib/libc/i386/sys/getcontext.S,v 1.2 2007/02/04 20:28:21 corecode Exp $
  35  */
  36
  37 #include <machine/asm.h>
  38 #include <asmcontext.h>
  39
  40         /*
  41          * This function is special-cased because the context it saves
  42          * includes a stale stack context (because it returns before the
  43          * caller presumably makes the call to setcontext()).
  44          */
  45         .weak   getcontext
  46         .set    getcontext,_getcontext
  47 ENTRY(_getcontext)
  48         /*
  49          * Retrieve the current signal mask and save it in &ucp->uc_sigmask.
  50          */
  51         movl    4(%esp),%eax            /* ucontext_t pointer */
  52         addl    $UC_SIGMASK,%eax        /* pointer to signal mask */
  53         PIC_PROLOGUE
  54         pushl   %eax
  55         pushl   $0
  56         pushl   $SIG_BLOCK
  57         call    PIC_PLT(_sigprocmask)   /* retrieve & save signal mask */
  58         addl    $12,%esp
  59         PIC_EPILOGUE
  60
  61         /*
  62          * Save what we need because our stack context is going stale.
  63          */
  64         movl    4(%esp),%eax
  65         movl    %eax,%ecx               /* save ucontext_t in %ecx */
  66         movl    (%esp),%edx             /* save return PC in %edx */
  67         addl    $UC_MCONTEXT,%eax
  68         pushl   %eax
  69         call    get_mcontext            /* returns non-zero on resume */
  70         addl    $4,%esp
  71         cmpl    $0,%eax
  72         je      2f
  73         /*
  74          * On resume, resave the stale return pc and restore the signal
  75          * mask (signals are blocked right now from the setcontext call).
  76          */
  77         movl    %edx,(%esp)             /* re-save the return PC */
  78         addl    $UC_SIGMASK,%ecx
  79         PIC_PROLOGUE
  80         pushl   $0
  81         pushl   %ecx
  82         pushl   $SIG_SETMASK
  83         call    PIC_PLT(_sigprocmask)   /* retrieve & save signal mask */
  84         addl    $12,%esp
  85         PIC_EPILOGUE
  86 2:
  87         movl    $0,%eax                 /* return success */
  88         ret
  89
  90 1:
  91         PIC_PROLOGUE
  92         jmp     PIC_PLT(HIDENAME(cerror))