contrib/gcc-5.0/libgcc/config/arc/ieee-754/gedf2.S

   1 /* Copyright (C) 2008-2015 Free Software Foundation, Inc.
   2    Contributor: Joern Rennecke <joern.rennecke@embecosm.com>
   3                 on behalf of Synopsys Inc.
   4
   5 This file is part of GCC.
   6
   7 GCC is free software; you can redistribute it and/or modify it under
   8 the terms of the GNU General Public License as published by the Free
   9 Software Foundation; either version 3, or (at your option) any later
  10 version.
  11
  12 GCC is distributed in the hope that it will be useful, but WITHOUT ANY
  13 WARRANTY; without even the implied warranty of MERCHANTABILITY or
  14 FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
  15 for more details.
  16
  17 Under Section 7 of GPL version 3, you are granted additional
  18 permissions described in the GCC Runtime Library Exception, version
  19 3.1, as published by the Free Software Foundation.
  20
  21 You should have received a copy of the GNU General Public License and
  22 a copy of the GCC Runtime Library Exception along with this program;
  23 see the files COPYING3 and COPYING.RUNTIME respectively.  If not, see
  24 <http://www.gnu.org/licenses/>.  */
  25
  26 #include "arc-ieee-754.h"
  27 /* inputs: DBL0, DBL1
  28    output: c flags to be used for 'hs' condition
  29    clobber: r12, flags  */
  30 /* For NaNs, bit 19.. bit 30 of the high word must be set.  */
  31 #if 0 /* DEBUG */
  32         .global __gedf2
  33         .balign 4
  34         FUNC(__gedf2)
  35 __gedf2:
  36         st.a r11,[sp,-4]` push_s blink` st.a r10,[sp,-4]` st.a r9,[sp,-4]
  37         st.a r8,[sp,-4]` st.a r7,[sp,-4]` st.a r6,[sp,-4]` st.a r5,[sp,-4]
  38         st.a r4,[sp,-4]` push_s r3` push_s r2` push_s r1`
  39         bl.d __gedf2_c` push_s r0
  40         mov r11,r0` pop_s r0` pop_s r1` pop_s r2` pop_s r3
  41         ld.ab r4,[sp,4]` ld.ab r5,[sp,4]` ld.ab r6,[sp,4]`
  42         ld.ab r7,[sp,4]` ld.ab r8,[sp,4]` ld.ab r9,[sp,4]
  43         bl.d __gedf2_asm` ld.ab r10,[sp,4]
  44         pop_s blink
  45         brge.d r11,0,0f
  46         ld.ab r11,[sp,4]
  47         jlo [blink]
  48         bl abort
  49 0:      jhs [blink]
  50         bl abort
  51         ENDFUNC(__gedf2)
  52 #define __gedf2 __gedf2_asm
  53 #endif /* DEBUG */
  54         .global __gedf2
  55         .balign 4
  56         HIDDEN_FUNC(__gedf2)
  57 __gedf2:
  58         or.f    r12,DBL0H,DBL1H
  59         bmi.d   .Lneg
  60         bmsk_s  r12,r12,20
  61         add1.f  0,r12,DBL0H     ; clear z; set c iff NaN
  62         add1.cc.f r12,r12,DBL1H ; clear z; set c iff NaN
  63         bbit1   DBL0H,31,.Lneg
  64         cmp.cc  DBL0H,DBL1H
  65         j_s.d   [blink]
  66         cmp.eq  DBL0L,DBL1L
  67         .balign 4
  68 .Lneg:  breq.d  DBL1H,0,.L0
  69         add1.f  0,r12,DBL0H
  70         add1.cc.f r12,r12,DBL1H
  71         cmp.cc  DBL1H,DBL0H
  72         j_s.d   [blink]
  73         cmp.eq  DBL1L,DBL0L
  74         .balign 4
  75 .L0:
  76         bxor.f  0,DBL0H,31 ; check for high word of -0.
  77         beq_s   .Lcheck_0
  78         cmp.cc  DBL1H,DBL0H
  79         j_s.d   [blink]
  80         cmp.eq  DBL1L,DBL0L
  81 .Lcheck_0:
  82         ; high words suggest DBL0 may be -0, DBL1 +0; check low words.
  83         cmp_s   DBL1H,DBL0L
  84         j_s.d   [blink]
  85         cmp.cc  DBL1H,DBL1L
  86         ENDFUNC(__gedf2)