lib/libcr/i386/string/strcpy.S

   1 /*
   2  * Copyright (c) 1993 Winning Strategies, Inc.
   3  * All rights reserved.
   4  *
   5  * Redistribution and use in source and binary forms, with or without
   6  * modification, are permitted provided that the following conditions
   7  * are met:
   8  * 1. Redistributions of source code must retain the above copyright
   9  *    notice, this list of conditions and the following disclaimer.
  10  * 2. Redistributions in binary form must reproduce the above copyright
  11  *    notice, this list of conditions and the following disclaimer in the
  12  *    documentation and/or other materials provided with the distribution.
  13  * 3. All advertising materials mentioning features or use of this software
  14  *    must display the following acknowledgement:
  15  *      This product includes software developed by Winning Strategies, Inc.
  16  * 4. The name of the author may not be used to endorse or promote products
  17  *    derived from this software withough specific prior written permission
  18  *
  19  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR ``AS IS'' AND ANY EXPRESS OR
  20  * IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED WARRANTIES
  21  * OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE ARE DISCLAIMED.
  22  * IN NO EVENT SHALL THE AUTHOR BE LIABLE FOR ANY DIRECT, INDIRECT,
  23  * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT
  24  * NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  25  * DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  26  * THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  27  * (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF
  28  * THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  29  *
  30  * $FreeBSD: src/lib/libc/i386/string/strcpy.S,v 1.5 1999/08/27 23:59:34 peter Exp $
  31  * $DragonFly: src/lib/libcr/i386/string/Attic/strcpy.S,v 1.3 2003/12/08 13:56:35 eirikn Exp $
  32  *
  33  * $FreeBSD: src/lib/libc/i386/string/strcpy.S,v 1.5 1999/08/27 23:59:34 peter Exp $
  34  */
  35
  36 #include "DEFS.h"
  37
  38 /*
  39  * strcpy (dst, src)
  40  *      copy the string src to dst.
  41  *
  42  * Written by:
  43  *      J.T. Conklin (jtc@wimsey.com), Winning Strategies, Inc.
  44  */
  45
  46 /*
  47  * I've unrolled the loop eight times: large enough to make a
  48  * significant difference, and small enough not to totally trash the
  49  * cache.
  50  */
  51
  52 ENTRY(strcpy)
  53         movl    4(%esp),%ecx            /* dst address */
  54         movl    8(%esp),%edx            /* src address */
  55         pushl   %ecx                    /* push dst address */
  56
  57         .align 2,0x90
  58 L1:     movb    (%edx),%al              /* unroll loop, but not too much */
  59         movb    %al,(%ecx)
  60         testb   %al,%al
  61         je      L2
  62         movb    1(%edx),%al
  63         movb    %al,1(%ecx)
  64         testb   %al,%al
  65         je      L2
  66         movb    2(%edx),%al
  67         movb    %al,2(%ecx)
  68         testb   %al,%al
  69         je      L2
  70         movb    3(%edx),%al
  71         movb    %al,3(%ecx)
  72         testb   %al,%al
  73         je      L2
  74         movb    4(%edx),%al
  75         movb    %al,4(%ecx)
  76         testb   %al,%al
  77         je      L2
  78         movb    5(%edx),%al
  79         movb    %al,5(%ecx)
  80         testb   %al,%al
  81         je      L2
  82         movb    6(%edx),%al
  83         movb    %al,6(%ecx)
  84         testb   %al,%al
  85         je      L2
  86         movb    7(%edx),%al
  87         movb    %al,7(%ecx)
  88         addl    $8,%edx
  89         addl    $8,%ecx
  90         testb   %al,%al
  91         jne     L1
  92 L2:     popl    %eax                    /* pop dst address */
  93         ret