usr.bin/mklocale/lex.l

   1 %{
   2 /*-
   3  * Copyright (c) 1993
   4  *      The Regents of the University of California.  All rights reserved.
   5  *
   6  * This code is derived from software contributed to Berkeley by
   7  * Paul Borman at Krystal Technologies.
   8  *
   9  * Redistribution and use in source and binary forms, with or without
  10  * modification, are permitted provided that the following conditions
  11  * are met:
  12  * 1. Redistributions of source code must retain the above copyright
  13  *    notice, this list of conditions and the following disclaimer.
  14  * 2. Redistributions in binary form must reproduce the above copyright
  15  *    notice, this list of conditions and the following disclaimer in the
  16  *    documentation and/or other materials provided with the distribution.
  17  * 3. Neither the name of the University nor the names of its contributors
  18  *    may be used to endorse or promote products derived from this software
  19  *    without specific prior written permission.
  20  *
  21  * THIS SOFTWARE IS PROVIDED BY THE REGENTS AND CONTRIBUTORS ``AS IS'' AND
  22  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  23  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  24  * ARE DISCLAIMED.  IN NO EVENT SHALL THE REGENTS OR CONTRIBUTORS BE LIABLE
  25  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  26  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  27  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  28  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  29  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  30  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  31  * SUCH DAMAGE.
  32  *
  33  * @(#)lex.l    8.1 (Berkeley) 6/6/93
  34  * $FreeBSD: head/usr.bin/mklocale/lex.l 250926 2013-05-23 05:42:35Z jkim $
  35  */
  36
  37 #include <ctype.h>
  38 #include <stdio.h>
  39 #include <stdlib.h>
  40
  41 #include "ldef.h"
  42 #include "y.tab.h"
  43 #include "extern.h"
  44
  45 #define YY_DECL int yylex(void)
  46 %}
  47
  48 ODIGIT  [0-7]
  49 DIGIT   [0-9]
  50 XDIGIT  [0-9a-fA-F]
  51 W       [\t\n\r ]
  52
  53 %%
  54 \'.\'                           { yylval.rune = (unsigned char)yytext[1];
  55                                   return(RUNE); }
  56
  57 '\\a'                           { yylval.rune = '\a';
  58                                   return(RUNE); }
  59 '\\b'                           { yylval.rune = '\b';
  60                                   return(RUNE); }
  61 '\\f'                           { yylval.rune = '\f';
  62                                   return(RUNE); }
  63 '\\n'                           { yylval.rune = '\n';
  64                                   return(RUNE); }
  65 '\\r'                           { yylval.rune = '\r';
  66                                   return(RUNE); }
  67 '\\t'                           { yylval.rune = '\t';
  68                                   return(RUNE); }
  69 '\\v'                           { yylval.rune = '\v';
  70                                   return(RUNE); }
  71
  72 0x{XDIGIT}+                     { yylval.rune = strtol(yytext, 0, 16);
  73                                   return(RUNE); }
  74 0{ODIGIT}+                      { yylval.rune = strtol(yytext, 0, 8);
  75                                   return(RUNE); }
  76 {DIGIT}+                        { yylval.rune = strtol(yytext, 0, 10);
  77                                   return(RUNE); }
  78
  79
  80 MAPLOWER                        { return(MAPLOWER); }
  81 MAPUPPER                        { return(MAPUPPER); }
  82 TODIGIT                         { return(DIGITMAP); }
  83 INVALID                         { return(INVALID); }
  84
  85 ALPHA                           { yylval.i = _CTYPE_A|_CTYPE_R|_CTYPE_G;
  86                                   return(LIST); }
  87 CONTROL                         { yylval.i = _CTYPE_C;
  88                                   return(LIST); }
  89 DIGIT                           { yylval.i = _CTYPE_D|_CTYPE_R|_CTYPE_G;
  90                                   return(LIST); }
  91 GRAPH                           { yylval.i = _CTYPE_G|_CTYPE_R;
  92                                   return(LIST); }
  93 LOWER                           { yylval.i = _CTYPE_L|_CTYPE_R|_CTYPE_G;
  94                                   return(LIST); }
  95 PUNCT                           { yylval.i = _CTYPE_P|_CTYPE_R|_CTYPE_G;
  96                                   return(LIST); }
  97 SPACE                           { yylval.i = _CTYPE_S;
  98                                   return(LIST); }
  99 UPPER                           { yylval.i = _CTYPE_U|_CTYPE_R|_CTYPE_G;
 100                                   return(LIST); }
 101 XDIGIT                          { yylval.i = _CTYPE_X|_CTYPE_R|_CTYPE_G;
 102                                   return(LIST); }
 103 BLANK                           { yylval.i = _CTYPE_B;
 104                                   return(LIST); }
 105 PRINT                           { yylval.i = _CTYPE_R;
 106                                   return(LIST); }
 107 IDEOGRAM                        { yylval.i = _CTYPE_I|_CTYPE_R|_CTYPE_G;
 108                                   return(LIST); }
 109 SPECIAL                         { yylval.i = _CTYPE_T|_CTYPE_R|_CTYPE_G;
 110                                   return(LIST); }
 111 PHONOGRAM                       { yylval.i = _CTYPE_Q|_CTYPE_R|_CTYPE_G;
 112                                   return(LIST); }
 113 SWIDTH0                         { yylval.i = _CTYPE_SW0; return(LIST); }
 114 SWIDTH1                         { yylval.i = _CTYPE_SW1; return(LIST); }
 115 SWIDTH2                         { yylval.i = _CTYPE_SW2; return(LIST); }
 116 SWIDTH3                         { yylval.i = _CTYPE_SW3; return(LIST); }
 117
 118 VARIABLE[\t ]                   { static char vbuf[1024];
 119                                   char *v = vbuf;
 120                                   while ((*v = input()) && *v != '\n')
 121                                         ++v;
 122                                   if (*v) {
 123                                         unput(*v);
 124                                         *v = 0;
 125                                   }
 126                                   yylval.str = vbuf;
 127                                   return(VARIABLE);
 128                                 }
 129
 130 ENCODING                        { return(ENCODING); }
 131
 132 \".*\"                          { char *e = yytext + 1;
 133                                   yylval.str = e;
 134                                   while (*e && *e != '"')
 135                                         ++e;
 136                                   *e = 0;
 137                                   return(STRING); }
 138
 139 \<|\(|\[                        { return(LBRK); }
 140
 141 \>|\)|\]                        { return(RBRK); }
 142
 143 \-                              { return(THRU); }
 144 \.\.\.                          { return(THRU); }
 145
 146 \:                              { return(':'); }
 147
 148 {W}+                            ;
 149
 150 ^\#.*\n                         ;
 151 \/\*                            { char lc = 0;
 152                                   do {
 153                                     while ((lc) != '*')
 154                                         if ((lc = input()) == 0)
 155                                             break;
 156                                   } while((lc = input()) != '/');
 157                                 }
 158
 159 \\$                             ;
 160 .                               { printf("Lex is skipping '%s'\n", yytext); }
 161 %%
 162
 163 #if     !defined(yywrap)
 164 int
 165 yywrap(void)
 166 {
 167         return(1);
 168 }
 169 #endif