Now that the base issue is fixed, enable -Wsign-compare again in scanners.
[dragonfly.git] / usr.sbin / apmd / apmdlex.l
1 %{
2 /*-
3  * APM (Advanced Power Management) Event Dispatcher
4  *
5  * Copyright (c) 1999 Mitsuru IWASAKI <iwasaki@FreeBSD.org>
6  * Copyright (c) 1999 KOIE Hidetaka <koie@suri.co.jp>
7  * All rights reserved.
8  *
9  * Redistribution and use in source and binary forms, with or without
10  * modification, are permitted provided that the following conditions
11  * are met:
12  * 1. Redistributions of source code must retain the above copyright
13  *    notice, this list of conditions and the following disclaimer.
14  * 2. Redistributions in binary form must reproduce the above copyright
15  *    notice, this list of conditions and the following disclaimer in the
16  *    documentation and/or other materials provided with the distribution.
17  *
18  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
19  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
20  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
21  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
22  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
23  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
24  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
25  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
26  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
27  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
28  * SUCH DAMAGE.
29  *
30  * $FreeBSD: src/usr.sbin/apmd/apmdlex.l,v 1.2.2.1 2001/08/13 17:30:30 nsayer Exp $
31  */
32
33 #include <string.h>
34 #include <syslog.h>
35 #include <bitstring.h>
36 #include "apmd.h"
37 #include "y.tab.h"
38
39 int lineno;
40 int first_time;
41 %}
42
43 %option noinput
44 %option nounput
45
46 %s TOP
47
48 %%
49
50 %{
51         if (first_time) {
52                 BEGIN TOP;
53                 lineno = 1;
54                 first_time = 0;
55         }
56 %}
57
58 <TOP>[ \t]+             ;
59 <TOP>\n                 lineno++;
60 <TOP>,                  { return COMMA; }
61 <TOP>;                  { return SEMICOLON; }
62 <TOP>#.*$               ;
63
64 <TOP>apm_event          { return APMEVENT; }
65
66 <TOP>NOEVENT            { yylval.ev = EVENT_NOEVENT; return EVENT; }
67 <TOP>STANDBYREQ         { yylval.ev = EVENT_STANDBYREQ; return EVENT; }
68 <TOP>SUSPENDREQ         { yylval.ev = EVENT_SUSPENDREQ; return EVENT; }
69 <TOP>NORMRESUME         { yylval.ev = EVENT_NORMRESUME; return EVENT; }
70 <TOP>CRITRESUME         { yylval.ev = EVENT_CRITRESUME; return EVENT; }
71 <TOP>BATTERYLOW         { yylval.ev = EVENT_BATTERYLOW; return EVENT; }
72 <TOP>POWERSTATECHANGE   { yylval.ev = EVENT_POWERSTATECHANGE; return EVENT; }
73 <TOP>UPDATETIME         { yylval.ev = EVENT_UPDATETIME; return EVENT; }
74 <TOP>CRITSUSPEND        { yylval.ev = EVENT_CRITSUSPEND; return EVENT; }
75 <TOP>USERSTANDBYREQ     { yylval.ev = EVENT_USERSTANDBYREQ; return EVENT; }
76 <TOP>USERSUSPENDREQ     { yylval.ev = EVENT_USERSUSPENDREQ; return EVENT; }
77 <TOP>STANDBYRESUME      { yylval.ev = EVENT_STANDBYRESUME; return EVENT; }
78 <TOP>CAPABILITIESCHANGE { yylval.ev = EVENT_CAPABILITIESCHANGE; return EVENT; }
79
80 <TOP>apm_battery        { return APMBATT; }
81
82 <TOP>charging           { return BATTCHARGE; }
83 <TOP>discharging        { return BATTDISCHARGE; }
84 <TOP>[0-9]+%            {
85                                 yylval.i = atoi(yytext);
86                                 return BATTPERCENT;
87                         }
88 <TOP>[0-9]+[Mm]         {
89                                 yylval.i = -atoi(yytext);
90                                 return BATTTIME;
91                         }
92
93 <TOP>exec               { return EXECCMD; }
94 <TOP>reject             { return REJECTCMD; }
95
96 <TOP>\{                 { return BEGINBLOCK; }
97 <TOP>\}                 { return ENDBLOCK; }
98 <TOP>\"[^"]+\"  {
99                                 int len = strlen(yytext) - 2;
100                                 if ((yylval.str = (char *) malloc(len + 1)) == NULL)
101                                         goto out;
102                                 memcpy(yylval.str, yytext + 1, len);
103                                 yylval.str[len] = '\0';
104                         out:
105                                 return STRING;
106                         }
107
108 <TOP>[^"{},;#\n\t ]+    { yylval.str = strdup(yytext); return UNKNOWN; }
109 %%
110
111 void
112 yyerror(const char *s)
113 {
114         syslog(LOG_ERR, "line %d: %s%s %s.\n", lineno, yytext, yytext?":":"", s);
115 }