lib/libcaps/i386/mplock.S

   1 /*
   2  * $FreeBSD: src/sys/i386/i386/mplock.s,v 1.29.2.2 2000/05/16 06:58:06 dillon Exp $
   3  * $DragonFly: src/lib/libcaps/i386/mplock.S,v 1.2 2003/12/07 04:21:54 dillon Exp $
   4  *
   5  * Copyright (c) 2003 Matthew Dillon <dillon@backplane.com>
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  *
  29  *                              DragonFly MPLOCK operation
  30  *
  31  * Each thread as an MP lock count, td_mpcount, and there is a shared
  32  * global called mp_lock.  mp_lock is the physical MP lock and contains either
  33  * -1 or the cpuid of the cpu owning the lock.  The count is *NOT* integrated
  34  * into mp_lock but instead resides in each thread td_mpcount.
  35  *
  36  * When obtaining or releasing the MP lock the td_mpcount is PREDISPOSED
  37  * to the desired count *PRIOR* to operating on the mp_lock itself.  MP
  38  * lock operations can occur outside a critical section with interrupts
  39  * enabled with the provisio (which the routines below handle) that an
  40  * interrupt may come along and preempt us, racing our cmpxchgl instruction
  41  * to perform the operation we have requested by pre-dispoing td_mpcount.
  42  *
  43  * Additionally, the LWKT threading system manages the MP lock and
  44  * lwkt_switch(), in particular, may be called after pre-dispoing td_mpcount
  45  * to handle 'blocking' on the MP lock.
  46  *
  47  *
  48  * Recoded from the FreeBSD original:
  49  * ----------------------------------------------------------------------------
  50  * "THE BEER-WARE LICENSE" (Revision 42):
  51  * <phk@FreeBSD.org> wrote this file.  As long as you retain this notice you
  52  * can do whatever you want with this stuff. If we meet some day, and you think
  53  * this stuff is worth it, you can buy me a beer in return.   Poul-Henning Kamp
  54  * ----------------------------------------------------------------------------
  55  */
  56
  57 #include "asmacros.h"
  58 #include "asdefs.h"
  59
  60         .data
  61         ALIGN_DATA
  62 #ifdef SMP
  63         .globl  mp_lock
  64 mp_lock:
  65         .long   -1                      /* initialized to not held */
  66 #endif
  67
  68         .text
  69         SUPERALIGN_TEXT
  70
  71         /*
  72          * Note on cmpxchgl... exchanges ecx with mem if mem matches eax.
  73          * Z=1 (jz) on success.   A lock prefix is required for MP.
  74          */
  75 NON_GPROF_ENTRY(cpu_get_initial_mplock)
  76         movl    PCPU(curthread),%ecx
  77         movl    $1,TD_MPCOUNT(%ecx)     /* curthread has mpcount of 1 */
  78         movl    $0,mp_lock              /* owned by cpu 0 */
  79         ret
  80
  81         /*
  82          * cpu_try_mplock() returns non-zero on success, 0 on failure.  It
  83          * only adjusts mp_lock, it does not touch td_mpcount.  Callers
  84          * should always increment td_mpcount *before* trying to acquire
  85          * the actual lock, predisposing td_mpcount to the desired state of
  86          * the lock.
  87          *
  88          * NOTE! Only call cpu_try_mplock() inside a critical section.  If
  89          * you don't an interrupt can come along and get and release
  90          * the lock before our cmpxchgl instruction, causing us to fail
  91          * but resulting in the lock being held by our cpu.
  92          */
  93 NON_GPROF_ENTRY(cpu_try_mplock)
  94         movl    PCPU(cpuid),%ecx
  95         movl    $-1,%eax
  96         lock cmpxchgl %ecx,mp_lock      /* ecx<->mem if eax matches */
  97         jnz     1f
  98 #ifdef PARANOID_INVLTLB
  99         movl    %cr3,%eax; movl %eax,%cr3       /* YYY check and remove */
 100 #endif
 101         movl    $1,%eax
 102         ret
 103 1:
 104         subl    %eax,%eax
 105         ret
 106
 107         /*
 108          * get_mplock() Obtains the MP lock and may switch away if it cannot
 109          * get it.  This routine may be called WITHOUT a critical section
 110          * and with cpu interrupts enabled.
 111          *
 112          * To handle races in a sane fashion we predispose TD_MPCOUNT,
 113          * which prevents us from losing the lock in a race if we already
 114          * have it or happen to get it.  It also means that we might get
 115          * the lock in an interrupt race before we have a chance to execute
 116          * our cmpxchgl instruction, so we have to handle that case.
 117          * Fortunately simply calling lwkt_switch() handles the situation
 118          * for us and also 'blocks' us until the MP lock can be obtained.
 119          */
 120 NON_GPROF_ENTRY(get_mplock)
 121         movl    PCPU(cpuid),%ecx
 122         movl    PCPU(curthread),%edx
 123         incl    TD_MPCOUNT(%edx)        /* predispose */
 124         cmpl    %ecx,mp_lock
 125         jne     1f
 126         ret                             /* success! */
 127
 128         /*
 129          * We don't already own the mp_lock, use cmpxchgl to try to get
 130          * it.
 131          */
 132 1:
 133         movl    $-1,%eax
 134         lock cmpxchgl %ecx,mp_lock
 135         jnz     2f
 136 #ifdef PARANOID_INVLTLB
 137         movl    %cr3,%eax; movl %eax,%cr3 /* YYY check and remove */
 138 #endif
 139         ret                             /* success */
 140
 141         /*
 142          * Failure, but we could end up owning mp_lock anyway due to
 143          * an interrupt race.  lwkt_switch() will clean up the mess
 144          * and 'block' until the mp_lock is obtained.
 145          */
 146 2:
 147         call    lwkt_switch
 148 #ifdef INVARIANTS
 149         movl    PCPU(cpuid),%eax        /* failure */
 150         cmpl    %eax,mp_lock
 151         jne     4f
 152 #endif
 153         ret
 154 #ifdef INVARIANTS
 155 4:
 156         cmpl    $0,panicstr             /* don't double panic */
 157         je      badmp_get2
 158         ret
 159 #endif
 160
 161         /*
 162          * try_mplock() attempts to obtain the MP lock.  1 is returned on
 163          * success, 0 on failure.  We do not have to be in a critical section
 164          * and interrupts are almost certainly enabled.
 165          *
 166          * We must pre-dispose TD_MPCOUNT in order to deal with races in
 167          * a reasonable way.
 168          *
 169          */
 170 NON_GPROF_ENTRY(try_mplock)
 171         movl    PCPU(cpuid),%ecx
 172         movl    PCPU(curthread),%edx
 173         incl    TD_MPCOUNT(%edx)                /* pre-dispose for race */
 174         cmpl    %ecx,mp_lock
 175         je      1f                              /* trivial success */
 176         movl    $-1,%eax
 177         lock cmpxchgl %ecx,mp_lock
 178         jnz     2f
 179         /*
 180          * Success
 181          */
 182 #ifdef PARANOID_INVLTLB
 183         movl    %cr3,%eax; movl %eax,%cr3       /* YYY check and remove */
 184 #endif
 185 1:
 186         movl    $1,%eax                         /* success (cmpxchgl good!) */
 187         ret
 188
 189         /*
 190          * The cmpxchgl failed but we might have raced.  Undo the mess by
 191          * predispoing TD_MPCOUNT and then checking.  If TD_MPCOUNT is
 192          * still non-zero we don't care what state the lock is in (since
 193          * we obviously didn't own it above), just return failure even if
 194          * we won the lock in an interrupt race.  If TD_MPCOUNT is zero
 195          * make sure we don't own the lock in case we did win it in a race.
 196          */
 197 2:
 198         decl    TD_MPCOUNT(%edx)
 199         cmpl    $0,TD_MPCOUNT(%edx)
 200         jne     3f
 201         movl    PCPU(cpuid),%eax
 202         movl    $-1,%ecx
 203         lock cmpxchgl %ecx,mp_lock
 204 3:
 205         subl    %eax,%eax
 206         ret
 207
 208         /*
 209          * rel_mplock() releases a previously obtained MP lock.
 210          *
 211          * In order to release the MP lock we pre-dispose TD_MPCOUNT for
 212          * the release and basically repeat the release portion of try_mplock
 213          * above.
 214          */
 215 NON_GPROF_ENTRY(rel_mplock)
 216         movl    PCPU(curthread),%edx
 217         movl    TD_MPCOUNT(%edx),%eax
 218 #ifdef INVARIANTS
 219         cmpl    $0,%eax
 220         je      badmp_rel
 221 #endif
 222         subl    $1,%eax
 223         movl    %eax,TD_MPCOUNT(%edx)
 224         cmpl    $0,%eax
 225         jne     3f
 226         movl    PCPU(cpuid),%eax
 227         movl    $-1,%ecx
 228         lock cmpxchgl %ecx,mp_lock
 229 3:
 230         ret
 231
 232 #ifdef INVARIANTS
 233
 234 badmp_get:
 235         pushl   $bmpsw1
 236         call    panic
 237 badmp_get2:
 238         pushl   $bmpsw1a
 239         call    panic
 240 badmp_rel:
 241         pushl   $bmpsw2
 242         call    panic
 243
 244         .data
 245
 246 bmpsw1:
 247         .asciz  "try/get_mplock(): already have lock! %d %p"
 248
 249 bmpsw1a:
 250         .asciz  "try/get_mplock(): failed on count or switch %d %p"
 251
 252 bmpsw2:
 253         .asciz  "rel_mplock(): mpcount already 0 @ %p %p %p %p %p %p %p %p!"
 254
 255 #endif
 256