sys/boot/i386/boot2/boot1.s

   1 #
   2 # Copyright (c) 1998 Robert Nordier
   3 # All rights reserved.
   4 #
   5 # Redistribution and use in source and binary forms are freely
   6 # permitted provided that the above copyright notice and this
   7 # paragraph and the following disclaimer are duplicated in all
   8 # such forms.
   9 #
  10 # This software is provided "AS IS" and without any express or
  11 # implied warranties, including, without limitation, the implied
  12 # warranties of merchantability and fitness for a particular
  13 # purpose.
  14 #
  15
  16 # $FreeBSD: src/sys/boot/i386/boot2/boot1.s,v 1.10.2.3 2001/08/14 22:55:29 jhb Exp $
  17
  18 # Memory Locations
  19                 .set MEM_REL,0x700              # Relocation address
  20                 .set MEM_ARG,0x900              # Arguments
  21                 .set MEM_ORG,0x7c00             # Origin
  22                 .set MEM_BUF,0x8c00             # Load area
  23                 .set MEM_BTX,0x9000             # BTX start
  24                 .set MEM_JMP,0x9010             # BTX entry point
  25                 .set MEM_USR,0xa000             # Client start
  26                 .set BDA_BOOT,0x472             # Boot howto flag
  27
  28 # Partition Constants
  29                 .set PRT_OFF,0x1be              # Partition offset
  30                 .set PRT_NUM,0x4                # Partitions
  31                 .set PRT_BSD,0xa5               # Partition type
  32
  33 # Flag Bits
  34                 .set FL_PACKET,0x80             # Packet mode
  35
  36 # Misc. Constants
  37                 .set SIZ_PAG,0x1000             # Page size
  38                 .set SIZ_SEC,0x200              # Sector size
  39
  40                 .globl start
  41                 .globl xread
  42                 .code16
  43
  44 start:          jmp main                        # Start recognizably
  45
  46 # This is the start of a standard BIOS Parameter Block (BPB). Most bootable
  47 # FAT disks have this at the start of their MBR. While normal BIOS's will
  48 # work fine without this section, IBM's El Torito emulation "fixes" up the
  49 # BPB by writing into the memory copy of the MBR. Rather than have data
  50 # written into our xread routine, we'll define a BPB to work around it.
  51 # The data marked with (T) indicates a field required for a ThinkPad to
  52 # recognize the disk and (W) indicates fields written from IBM BIOS code.
  53 # The use of the BPB is based on what OpenBSD and NetBSD implemented in
  54 # their boot code but the required fields were determined by trial and error.
  55 #
  56 # Note: If additional space is needed in boot1, one solution would be to
  57 # move the "prompt" message data (below) to replace the OEM ID.
  58
  59                 .org 0x03, 0x00
  60 oemid:          .space 0x08, 0x00       # OEM ID
  61
  62                 .org 0x0b, 0x00
  63 bpb:            .word   512             # sector size (T)
  64                 .byte   0               # sectors/clustor
  65                 .word   0               # reserved sectors
  66                 .byte   0               # number of FATs
  67                 .word   0               # root entries
  68                 .word   0               # small sectors
  69                 .byte   0               # media type (W)
  70                 .word   0               # sectors/fat
  71                 .word   18              # sectors per track (T)
  72                 .word   2               # number of heads (T)
  73                 .long   0               # hidden sectors (W)
  74                 .long   0               # large sectors
  75
  76                 .org 0x24, 0x00
  77 ebpb:           .byte   0               # BIOS physical drive number (W)
  78
  79                 .org 0x25,0x90
  80 #
  81 # Trampoline used by boot2 to call read to read data from the disk via
  82 # the BIOS.  Call with:
  83 #
  84 # %cx:%ax       - long    - LBA to read in
  85 # %es:(%bx)     - caddr_t - buffer to read data into
  86 # %dl           - byte    - drive to read from
  87 # %dh           - byte    - num sectors to read
  88 #
  89
  90 xread:          push %ss                        # Address
  91                 pop %ds                         #  data
  92 #
  93 # Setup an EDD disk packet and pass it to read
  94 #
  95 xread.1:                                        # Starting
  96                 pushl $0x0                      #  absolute
  97                 push %cx                        #  block
  98                 push %ax                        #  number
  99                 push %es                        # Address of
 100                 push %bx                        #  transfer buffer
 101                 xor %ax,%ax                     # Number of
 102                 movb %dh,%al                    #  blocks to
 103                 push %ax                        #  transfer
 104                 push $0x10                      # Size of packet
 105                 mov %sp,%bp                     # Packet pointer
 106                 callw read                      # Read from disk
 107                 lea 0x10(%bp),%sp               # Clear stack
 108                 lret                            # To far caller
 109 #
 110 # Load the rest of boot2 and BTX up, copy the parts to the right locations,
 111 # and start it all up.
 112 #
 113
 114 #
 115 # Setup the segment registers to flat addressing (segment 0) and setup the
 116 # stack to end just below the start of our code.
 117 #
 118 main:           cld                             # String ops inc
 119                 xor %cx,%cx                     # Zero
 120                 mov %cx,%es                     # Address
 121                 mov %cx,%ds                     #  data
 122                 mov %cx,%ss                     # Set up
 123                 mov $start,%sp                  #  stack
 124 #
 125 # Relocate ourself to MEM_REL.  Since %cx == 0, the inc %ch sets
 126 # %cx == 0x100.
 127 #
 128                 mov %sp,%si                     # Source
 129                 mov $MEM_REL,%di                # Destination
 130                 incb %ch                        # Word count
 131                 rep                             # Copy
 132                 movsw                           #  code
 133 #
 134 # If we are on a hard drive, then load the MBR and look for the first
 135 # FreeBSD slice.  We use the fake partition entry below that points to
 136 # the MBR when we call nread.  The first pass looks for the first active
 137 # FreeBSD slice.  The second pass looks for the first non-active FreeBSD
 138 # slice if the first one fails.
 139 #
 140                 mov $part4,%si                  # Partition
 141                 cmpb $0x80,%dl                  # Hard drive?
 142                 jb main.4                       # No
 143                 movb $0x1,%dh                   # Block count
 144                 callw nread                     # Read MBR
 145                 mov $0x1,%cx                    # Two passes
 146 main.1:         mov $MEM_BUF+PRT_OFF,%si        # Partition table
 147                 movb $0x1,%dh                   # Partition
 148 main.2:         cmpb $PRT_BSD,0x4(%si)          # Our partition type?
 149                 jne main.3                      # No
 150                 jcxz main.5                     # If second pass
 151                 testb $0x80,(%si)               # Active?
 152                 jnz main.5                      # Yes
 153 main.3:         add $0x10,%si                   # Next entry
 154                 incb %dh                        # Partition
 155                 cmpb $0x1+PRT_NUM,%dh           # In table?
 156                 jb main.2                       # Yes
 157                 dec %cx                         # Do two
 158                 jcxz main.1                     #  passes
 159 #
 160 # If we get here, we didn't find any FreeBSD slices at all, so print an
 161 # error message and die.
 162 #
 163                 mov $msg_part,%si               # Message
 164                 jmp error                       # Error
 165 #
 166 # Floppies use partition 0 of drive 0.
 167 #
 168 main.4:         xor %dx,%dx                     # Partition:drive
 169 #
 170 # Ok, we have a slice and drive in %dx now, so use that to locate and load
 171 # boot2.  %si references the start of the slice we are looking for, so go
 172 # ahead and load up the first 16 sectors (boot1 + boot2) from that.  When
 173 # we read it in, we conveniently use 0x8c00 as our transfer buffer.  Thus,
 174 # boot1 ends up at 0x8c00, and boot2 starts at 0x8c00 + 0x200 = 0x8e00.
 175 # The first part of boot2 is the disklabel, which is 0x200 bytes long.
 176 # The second part is BTX, which is thus loaded into 0x9000, which is where
 177 # it also runs from.  The boot2.bin binary starts right after the end of
 178 # BTX, so we have to figure out where the start of it is and then move the
 179 # binary to 0xb000.  Normally, BTX clients start at MEM_USR, or 0xa000, but
 180 # when we use btxld create boot2, we use an entry point of 0x1000.  That
 181 # entry point is relative to MEM_USR; thus boot2.bin starts at 0xb000.
 182 #
 183 main.5:         mov %dx,MEM_ARG                 # Save args
 184                 movb $0x10,%dh                  # Sector count
 185                 callw nread                     # Read disk
 186                 mov $MEM_BTX,%bx                # BTX
 187                 mov 0xa(%bx),%si                # Get BTX length and set
 188                 add %bx,%si                     #  %si to start of boot2.bin
 189                 mov $MEM_USR+SIZ_PAG,%di        # Client page 1
 190                 mov $MEM_BTX+0xe*SIZ_SEC,%cx    # Byte
 191                 sub %si,%cx                     #  count
 192                 rep                             # Relocate
 193                 movsb                           #  client
 194                 sub %di,%cx                     # Byte count
 195                 xorb %al,%al                    # Zero assumed bss from
 196                 rep                             #  the end of boot2.bin
 197                 stosb                           #  up to 0x10000
 198                 callw seta20                    # Enable A20
 199                 jmp start+MEM_JMP-MEM_ORG       # Start BTX
 200 #
 201 # Enable A20 so we can access memory above 1 meg.
 202 #
 203 seta20:         cli                             # Disable interrupts
 204 seta20.1:       inb $0x64,%al                   # Get status
 205                 testb $0x2,%al                  # Busy?
 206                 jnz seta20.1                    # Yes
 207                 movb $0xd1,%al                  # Command: Write
 208                 outb %al,$0x64                  #  output port
 209 seta20.2:       inb $0x64,%al                   # Get status
 210                 testb $0x2,%al                  # Busy?
 211                 jnz seta20.2                    # Yes
 212                 movb $0xdf,%al                  # Enable
 213                 outb %al,$0x60                  #  A20
 214                 sti                             # Enable interrupts
 215                 retw                            # To caller
 216 #
 217 # Trampoline used to call read from within boot1.
 218 #
 219 nread:          mov $MEM_BUF,%bx                # Transfer buffer
 220                 mov 0x8(%si),%ax                # Get
 221                 mov 0xa(%si),%cx                #  LBA
 222                 push %cs                        # Read from
 223                 callw xread.1                   #  disk
 224                 jnc return                      # If success, return
 225                 mov $msg_read,%si               # Otherwise, set the error
 226                                                 #  message and fall through to
 227                                                 #  the error routine
 228 #
 229 # Print out the error message pointed to by %ds:(%si) followed
 230 # by a prompt, wait for a keypress, and then reboot the machine.
 231 #
 232 error:          callw putstr                    # Display message
 233                 mov $prompt,%si                 # Display
 234                 callw putstr                    #  prompt
 235                 xorb %ah,%ah                    # BIOS: Get
 236                 int $0x16                       #  keypress
 237                 movw $0x1234, BDA_BOOT          # Do a warm boot
 238                 ljmp $0xffff,$0x0               # reboot the machine
 239 #
 240 # Display a null-terminated string using the BIOS output.
 241 #
 242 putstr.0:       mov $0x7,%bx                    # Page:attribute
 243                 movb $0xe,%ah                   # BIOS: Display
 244                 int $0x10                       #  character
 245 putstr:         lodsb                           # Get char
 246                 testb %al,%al                   # End of string?
 247                 jne putstr.0                    # No
 248
 249 #
 250 # Overused return code.  ereturn is used to return an error from the
 251 # read function.  Since we assume putstr succeeds, we (ab)use the
 252 # same code when we return from putstr.
 253 #
 254 ereturn:        movb $0x1,%ah                   # Invalid
 255                 stc                             #  argument
 256 return:         retw                            # To caller
 257 #
 258 # Reads sectors from the disk.  If EDD is enabled, then check if it is
 259 # installed and use it if it is.  If it is not installed or not enabled, then
 260 # fall back to using CHS.  Since we use a LBA, if we are using CHS, we have to
 261 # fetch the drive parameters from the BIOS and divide it out ourselves.
 262 # Call with:
 263 #
 264 # %dl   - byte     - drive number
 265 # stack - 10 bytes - EDD Packet
 266 #
 267 read:           push %dx                        # Save
 268                 movb $0x8,%ah                   # BIOS: Get drive
 269                 int $0x13                       #  parameters
 270                 movb %dh,%ch                    # Max head number
 271                 pop %dx                         # Restore
 272                 jc return                       # If error
 273                 andb $0x3f,%cl                  # Sectors per track
 274                 jz ereturn                      # If zero
 275                 cli                             # Disable interrupts
 276                 mov 0x8(%bp),%eax               # Get LBA
 277                 push %dx                        # Save
 278                 movzbl %cl,%ebx                 # Divide by
 279                 xor %edx,%edx                   #  sectors
 280                 div %ebx                        #  per track
 281                 movb %ch,%bl                    # Max head number
 282                 movb %dl,%ch                    # Sector number
 283                 inc %bx                         # Divide by
 284                 xorb %dl,%dl                    #  number
 285                 div %ebx                        #  of heads
 286                 movb %dl,%bh                    # Head number
 287                 pop %dx                         # Restore
 288                 cmpl $0x3ff,%eax                # Cylinder number supportable?
 289                 sti                             # Enable interrupts
 290                 ja read.7                       # No, try EDD
 291                 xchgb %al,%ah                   # Set up cylinder
 292                 rorb $0x2,%al                   #  number
 293                 orb %ch,%al                     # Merge
 294                 inc %ax                         #  sector
 295                 xchg %ax,%cx                    #  number
 296                 movb %bh,%dh                    # Head number
 297                 subb %ah,%al                    # Sectors this track
 298                 mov 0x2(%bp),%ah                # Blocks to read
 299                 cmpb %ah,%al                    # To read
 300                 jb read.2                       #  this
 301                 movb %ah,%al                    #  track
 302 read.2:         mov $0x5,%di                    # Try count
 303 read.3:         les 0x4(%bp),%bx                # Transfer buffer
 304                 push %ax                        # Save
 305                 movb $0x2,%ah                   # BIOS: Read
 306                 int $0x13                       #  from disk
 307                 pop %bx                         # Restore
 308                 jnc read.4                      # If success
 309                 dec %di                         # Retry?
 310                 jz read.6                       # No
 311                 xorb %ah,%ah                    # BIOS: Reset
 312                 int $0x13                       #  disk system
 313                 xchg %bx,%ax                    # Block count
 314                 jmp read.3                      # Continue
 315 read.4:         movzbw %bl,%ax                  # Sectors read
 316                 add %ax,0x8(%bp)                # Adjust
 317                 jnc read.5                      #  LBA,
 318                 incw 0xa(%bp)                   #  transfer
 319 read.5:         shlb %bl                        #  buffer
 320                 add %bl,0x5(%bp)                #  pointer,
 321                 sub %al,0x2(%bp)                #  block count
 322                 ja read                         # If not done
 323 read.6:         retw                            # To caller
 324 read.7:         testb $FL_PACKET,%cs:MEM_REL+flags-start # LBA support enabled?
 325                 jz ereturn                      # No, so return an error
 326                 mov $0x55aa,%bx                 # Magic
 327                 push %dx                        # Save
 328                 movb $0x41,%ah                  # BIOS: Check
 329                 int $0x13                       #  extensions present
 330                 pop %dx                         # Restore
 331                 jc return                       # If error, return an error
 332                 cmp $0xaa55,%bx                 # Magic?
 333                 jne ereturn                     # No, so return an error
 334                 testb $0x1,%cl                  # Packet interface?
 335                 jz ereturn                      # No, so return an error
 336                 mov %bp,%si                     # Disk packet
 337                 movb $0x42,%ah                  # BIOS: Extended
 338                 int $0x13                       #  read
 339                 retw                            # To caller
 340
 341 # Messages
 342
 343 msg_read:       .asciz "Read"
 344 msg_part:       .asciz "Boot"
 345
 346 prompt:         .asciz " error\r\n"
 347
 348 flags:          .byte FLAGS                     # Flags
 349
 350                 .org PRT_OFF,0x90
 351
 352 # Partition table
 353
 354                 .fill 0x30,0x1,0x0
 355 part4:          .byte 0x80, 0x00, 0x01, 0x00
 356                 .byte 0xa5, 0xff, 0xff, 0xff
 357                 .byte 0x00, 0x00, 0x00, 0x00
 358                 .byte 0x50, 0xc3, 0x00, 0x00    # 50000 sectors long, bleh
 359
 360                 .word 0xaa55                    # Magic number