usr.bin/mkesdb/lex.l

   1 /*      $NetBSD: src/usr.bin/mkesdb/lex.l,v 1.2 2003/10/27 00:12:43 lukem Exp $ */
   2
   3 %{
   4 /*-
   5  * Copyright (c)2003 Citrus Project,
   6  * All rights reserved.
   7  *
   8  * Redistribution and use in source and binary forms, with or without
   9  * modification, are permitted provided that the following conditions
  10  * are met:
  11  * 1. Redistributions of source code must retain the above copyright
  12  *    notice, this list of conditions and the following disclaimer.
  13  * 2. Redistributions in binary form must reproduce the above copyright
  14  *    notice, this list of conditions and the following disclaimer in the
  15  *    documentation and/or other materials provided with the distribution.
  16  *
  17  * THIS SOFTWARE IS PROVIDED BY THE AUTHOR AND CONTRIBUTORS ``AS IS'' AND
  18  * ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE
  19  * IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE
  20  * ARE DISCLAIMED.  IN NO EVENT SHALL THE AUTHOR OR CONTRIBUTORS BE LIABLE
  21  * FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL
  22  * DAMAGES (INCLUDING, BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS
  23  * OR SERVICES; LOSS OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION)
  24  * HOWEVER CAUSED AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
  25  * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY
  26  * OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF
  27  * SUCH DAMAGE.
  28  */
  29
  30 #pragma GCC diagnostic ignored "-Wsign-compare"
  31 #include <sys/endian.h>
  32 #include <sys/queue.h>
  33 #include <assert.h>
  34 #include <errno.h>
  35 #include <limits.h>
  36 #include <stdio.h>
  37 #include <stdlib.h>
  38 #include <string.h>
  39
  40 #include "ldef.h"
  41 #include "yacc.h"
  42
  43 int aline_number = 1;
  44 %}
  45
  46 %option noinput
  47 %option nounput
  48
  49 %x      COMMENT
  50
  51 %%
  52
  53 [ \t]+  { }
  54 #.*[\n]|"//".*[\n]|[\n] { aline_number++; return (R_LN); }
  55
  56 "/*"            { BEGIN COMMENT; }
  57 <COMMENT>"*/"   { BEGIN 0; }
  58 <COMMENT>[\n]   { aline_number++; }
  59 <COMMENT>.      { }
  60 <COMMENT><<EOF>>        {
  61                 yyerror("unexpected file end (unterminate comment)\n");
  62                 exit(1);
  63         }
  64
  65 ([1-9][0-9]*)|(0[0-9]*)|(0[xX][0-9A-Fa-f]+)     {
  66                 yylval.i_value = strtoul(yytext, NULL, 0);
  67                 return L_IMM;
  68         }
  69
  70 "NAME"          { return R_NAME; }
  71 "ENCODING"      { return R_ENCODING; }
  72 "VARIABLE"      { return R_VARIABLE; }
  73 "DEFCSID"       { return R_DEFCSID; }
  74 "INVALID"       { return R_INVALID; }
  75
  76 \"([^\"\n]*(\\\")?)*\"|\'([^\'\n]*(\\\')?)*\'   {
  77                 size_t len;
  78                 len = strlen(yytext);
  79                 yylval.s_value = malloc(len-1);
  80                 strlcpy(yylval.s_value, yytext+1, len-1);
  81                 return L_STRING;
  82         }
  83 [^ =/\-0-9\t\n][^ \t\n]*        {
  84                 yylval.s_value = strdup(yytext);
  85                 return L_STRING;
  86         }
  87
  88 %%
  89
  90 #ifndef yywrap
  91 int
  92 yywrap(void)
  93 {
  94         return (1);
  95 }
  96 #endif